topic Re: How to do ouput last observation of a SAS data in SAS Programming

How to output last observation of a SAS data set

Steve_Shanghai — Tue, 19 Jul 2016 14:43:28 GMT

AS known to us, _n_ can be used in IF-Then statement for manipulation for any speciifed observation when the observation number is known. How to do the same thing for last observation since we do not know it's obervation number

Re: How to do ouput last observation of a SAS data

Doc_Duke — Tue, 07 Jun 2011 02:38:15 GMT

Check out the END= option on the SET statement. I think that will do what you want.

Re: How to do ouput last observation of a SAS data

RMP — Tue, 07 Jun 2011 08:31:02 GMT

data test;
set sashelp.class end=eof;
if eof then output;
run;

Re: How to do ouput last observation of a SAS data

Steve_Shanghai — Tue, 07 Jun 2011 08:59:10 GMT

I get it, Thanks alot!

Re: How to do ouput last observation of a SAS data

data_null__ — Tue, 07 Jun 2011 11:43:19 GMT

If the purpose of the exercise is to access the last obs "only" then a more direct approach can be used.

[pre]
data class;
set sashelp.class;
run;
proc print;
run;
data class;
modify class end=eof;
*remove;
if eof or ranuni(12344) lt .2 then remove;
run;
proc print;
run;
data last;
if eof then stop;
do _n_ = nobs to 1 by -1 until(_error_ eq 0);
_error_ = 0;
set class point=_n_ nobs=nobs;
_obs_ = _n_;
end;
if _error_ eq 0 then output;
stop;
set class(drop=_all_) end=eof;
run;
proc print;
run;
[/pre] Added code to check for data sets with zero obs.

Message was edited by: data _null_;

Re: How to output last observation of a SAS data set

RMP — Tue, 19 Jul 2016 14:48:08 GMT

Editor's note: this is a very popular question. To help others to find the answer, we have consolidated the most helpful answers into this one reply as an Accepted Solution.

or ...

/* Simple approach */
data last;
    /* get number of records (N) */
    if 0 then
        set sashelp.class nobs=nobs end=eof;
    /* use POINT= to get nth record */
    set sashelp.class point=nobs;
    output;
    stop;
run;

More robust approach from @data_null__:

/* Create sample data */
data class;
    set sashelp.class;
run;
data class;
    modify class end=eof;
    /* uncomment this to create empty set for test */
    *remove;
    if eof or ranuni(12344) lt .2 then
        remove;
run;
/* print all records */
proc print;
run;

/* find last record, handle empty sets */
data last;
    if eof then
        stop;
    do _n_ = nobs to 1 by -1 until(_error_ eq 0);
        _error_ = 0;
        set class point=_n_ nobs=nobs;
        _obs_ = _n_;
    end;
    if _error_ eq 0 then
        output;
    stop;
    set class(drop=_all_) end=eof;
run;

/* print last record */
proc print;
run;

Re: How to do ouput last observation of a SAS data

data_null__ — Tue, 07 Jun 2011 13:12:24 GMT

> or ...
>
> data test;
> if 0 then set sashelp.class nobs=nobs end=eof;
> set sashelp.class point=nobs;
> output;
> stop;
> run;

No, because if the last observation was REMOVEd as in my example, your program won't work.

Re: How to do ouput last observation of a SAS data

RMP — Tue, 07 Jun 2011 13:38:06 GMT

Good point. What you lose in readability/maintainability you gain in robustness.

Re: How to do ouput last observation of a SAS data

Peter_C — Wed, 08 Jun 2011 05:56:50 GMT

have we seen this topic before?

Re: How to do ouput last observation of a SAS data

data_null__ — Wed, 08 Jun 2011 12:33:12 GMT

Do you mean how to find the last obs or the readability/maintainability of simple data steps?

Re: How to do ouput last observation of a SAS data

Peter_C — Wed, 08 Jun 2011 19:24:04 GMT

just the last obs. I'm sure I've read your code before.

Re: How to do ouput last observation of a SAS data

art297 — Thu, 09 Jun 2011 23:41:49 GMT

Peter,

How many questions are "really" new?

Art
> just the last obs. I'm sure I've read your code
> before.

Re: How to do ouput last observation of a SAS data

bpowell — Thu, 07 Apr 2016 11:54:24 GMT

Ever any new questions? Well I asked this one back in 2004...

http://marc.info/?l=sas-l&m=1166250948107016&w=2