topic Re: Date Macros conversion in SAS Programming

Date Macros conversion

Ivy — Wed, 06 Apr 2016 15:43:20 GMT

%let cutdt = '01jan2011'd ;

I would like to get a macro value as 01Jan2011 or Jan 01, 2011 from &cutdt .

Is there any converted function ?

Thank you very much .

Re: Date Macros conversion

cici0017 — Wed, 06 Apr 2016 16:05:22 GMT

Try this -

%let cutdt=01jan2011 ;
proc print data = sashelp.cars (obs=10);
title "%upcase(&cutdt)";
run;

Re: Date Macros conversion

BrunoMueller — Wed, 06 Apr 2016 16:35:43 GMT

I recommend to store just the date as DATE9. value in a macro variable. From there all sorts use uses are possible.

Have a look at the sample code below.

%let cutdt = 01jan2011;

* use as date constant ;
data want;
  somedate = "&cutdt"d;
  format someDate worddate.;
run;

* a new formatted date value as text;
%let newDate = %sysfunc( putn(%sysevalf("&cutdt"d), ddmmyyp10.));
title "Date as of &newDate";
proc print data=want;
run;

Bruno

Re: Date Macros conversion

jklaverstijn — Wed, 06 Apr 2016 16:39:42 GMT

You can do the conversion in a datstep:

%let   cutdt = '01jan2011'd ;

data _null_;
        dt=&cutdt;
        call symput ('date1', put(dt, date9.));
        call symput ('date2', put(dt, worddate12.));
run;

%put &=date1;
%put &=date2;

I believe %SYSFUNC could also be used, bypassing the datastep, but an example doesn't comes to mind.

Hope this helps,

- Jan.

Re: Date Macros conversion

Ivy — Thu, 07 Apr 2016 13:17:48 GMT

Thank you , all, very much, for your help !