topic Re: How to format variable in certain form? in SAS Programming

How to format variable in certain form?

ybz12003 — Wed, 30 Mar 2016 12:54:10 GMT

Good moring, everyone:

I have one SAS data set. One variable is "Value", and it's Characteristic. I would like to change it to numerical. Also, I would like to change two digital decimals. Some of my "Value" are list below. I think it should be used input function, but how to format them?

1. 53.6

2. 100

3. 8

4. 45238962

Thanks.

Re: How to format variable in certain form?

ybz12003 — Wed, 30 Mar 2016 12:55:35 GMT

I forget to say, Row 1-3 are two decimal. But row 4 will be the same, no decimal.

Re: How to format variable in certain form?

Kurt_Bremser — Wed, 30 Mar 2016 13:12:45 GMT

new_value = input(value,W.);

where W corresponds to the length of value; if you want to replace value, do

drop value;
rename new_value = value;

Re: How to format variable in certain form?

data_null__ — Wed, 30 Mar 2016 13:25:15 GMT

I interpret your question as.

data value;
   input value:$16.;
   d = ifn(_n_ in(1:3),2,0);
   length formatted_value $16;
   formatted_value = putn(input(value,f16.),'F',16,d);
   cards;
53.6
100
8
45238962
;;;;
   run;
proc print;
   run;

Re: How to format variable in certain form?

ybz12003 — Wed, 30 Mar 2016 14:24:03 GMT

I have 454 observations in "Values", the format I list are scattered in this "Value" variable.

Re: How to format variable in certain form?

data_null__ — Wed, 30 Mar 2016 14:30:17 GMT

You need a way communicate the FORMAT for each line. Show more data with IDs for the rows.

Re: How to format variable in certain form?

ybz12003 — Wed, 30 Mar 2016 14:36:11 GMT

The numbers from row 1-3 are corrospored to "O" of variable "Type", the number from row 4 are corrospored to "N" of variable "Type".

Re: How to format variable in certain form?

data_null__ — Wed, 30 Mar 2016 14:43:32 GMT

data value;
   input value:$16. type :$1.;
   d = ifn(type eq 'O',2,0);
   length formatted_value $16;
   formatted_value = putn(input(value,f16.),'F',16,d);
   cards;
53.6 O
100 O
8 O
45238962 N
;;;;
   run;
proc print;
   run;

Re: How to format variable in certain form?

ybz12003 — Wed, 30 Mar 2016 18:56:36 GMT

If my data is list below, how could I go from there? I would like to keep two decimal for type "O", "C" and "U", and keep the same for type "N" and "D".

53.6 O 100 C 8 U 45238962 N 618945 D

Re: How to format variable in certain form?

data_null__ — Wed, 30 Mar 2016 19:04:35 GMT

I posted how to do basically that.

data value;
   input value:$16. type :$1.;
   length formatted_value $16;
   select(type);
      when('O','C','U') formatted_value = putn(input(value,f16.),'F',16,2);
      when('N','D')     formatted_value = value;
      otherwise;
      end;
   cards;
53.6 O
100 O
8 O
45238962 N
;;;;
   run;
proc print;
   run;

Re: How to format variable in certain form?

ballardw — Wed, 30 Mar 2016 20:54:02 GMT

A single column in a SAS dataset may only have one SAS display format applied.

If you are going to print these values it may be that you can use a custom format for ranges of values that will make you happy once the values are converted to numeric.

Perhaps something like:

proc format ;

value MixedDecimals

0 - 1000 = [F8.2]

1000 < - high = [best12.];

run;

/* the range I picked is pretty arbitrary as I do not know what your rule for range of value might be to force the decimal appearance

Note: with this format if your large values have decimals they will be displayed. If that is not wanted then replace Best12. with F12.0*/

Then print or other display using MixedDecimals format.

Proc print data=want;

var NumericValue;

format NumericValue MixedDecimals.;

run;

Re: How to format variable in certain form?

ybz12003 — Mon, 04 Apr 2016 19:09:05 GMT

Hi:

Could you explain to me what is the mean for f16. and 'F' standing for? I'm lost for the code of when('O','C','U') formatted_value = putn(input(value,f16.),'F',16,2); ?

Thanks.

Re: How to format variable in certain form?

ybz12003 — Mon, 04 Apr 2016 23:32:45 GMT

Also, the result I run is still in Char., not Num.