topic Re: proc tabulate counts in SAS Programming

proc tabulate counts

archibald — Tue, 22 Mar 2016 04:36:37 GMT

Hi all, I want to determine the number of counts for each case using proc tabulate.

data have;

input gender $ jail count;

datalines;

1 Y 15

1 Y 11

1 N 21

2 Y 67

2 N 31

;

run;

I understand in proc freq using the weight statement allows to get the frequency of the counts in each case.

proc freq data = have;

weight count;

table gender*jail;

run;

any thoughts on getting the frequency counts using proc tabulate?

Thank you.

Re: proc tabulate counts

Reeza — Tue, 22 Mar 2016 05:13:52 GMT

The code is almost identical, just add the two Variables to a class statement and change the weight to freq.

Re: proc tabulate counts

ballardw — Tue, 22 Mar 2016 14:54:46 GMT

Here's a few different ways:

proc tabulate data=have;
   class gender jail;
   freq count;
   table gender*jail*n='count';
   table gender,
         jail*n='count';
   table gender,
         jail=''*n='count';
   table gender,
         jail=''*n='';
run;

with an appropriate format for gender the label for gender probably wouldn't be needed either.

Advantage of Tabulate over freq is control of appearance so might as well use it. Note the comma separates page, row and column dimensions.

Re: proc tabulate counts

archibald — Thu, 24 Mar 2016 00:19:34 GMT

@ballardwThis exactly what Ineeded and some more. Thank you very much!

Re: proc tabulate counts

archibald — Thu, 24 Mar 2016 00:21:04 GMT

ok, thank you!