topic Re: Adding a character to the beginning of a character string in SAS Programming

Adding a character to the beginning of a character string

_maldini_ — Thu, 17 Mar 2016 00:44:58 GMT

I am using an array to extract substrings from a character string. In 4 of the 5 datasets, the string begins w/ a zero (e.g. 010101). In the other dataset, there is no leading zero (e.g. 10101). This causes problems for my array.

How can I add a zero to the beginning of the character string for multiple variables? Another array no doubt...

Thank you!

Re: Adding a character to the beginning of a character string

FriedEgg — Thu, 17 Mar 2016 01:35:29 GMT

Please provide a more clear picture of you problem by sharing the 'array' code you are having issues with along with a set of sample data

Re: Adding a character to the beginning of a character string

PGStats — Thu, 17 Mar 2016 02:22:01 GMT

Just a guess :

data substrings;
/* ... */
set ds1 ds2 ds3(in=special) ds4 ds5;
if special then theString = cats("0", theString);
/* ... Extract substrings */

(untested )

Re: Adding a character to the beginning of a character string

_maldini_ — Thu, 17 Mar 2016 03:49:25 GMT

DATA want_1;
   INPUT var1 $ var2 $;
   DATALINES;
   10101      0 
   10101     100000 
   0         10100 
   10101      0
;
RUN;

DATA want_2;
	SET want_1;

	ARRAY original {2}  
	Var1 Var2;

	ARRAY new {2,3} $ 2 
	var1_part1	-  _var1_part3
	var2_part1	-  _var2_part3;

	DO i=1 to 2;
   	DO j=1 to 3;
      new{i,j} = substr(original{i}, 2*j-1);
   	END;
	
	DROP 
	i j;
RUN;

The character string is supposed to be a maximum of 6 characters. The possible values are: 01 or 00 for each two digit pair. So, 010100 would be parsed into 3 new variables. Var1=01, Var2=01, Var3=00.

In this one dataset, there is no leading zero, so the maximum string is 5 characters long. If the array substrings the first 2 characters, it will take 10, instead of 01.

Thanks for your help @FriedEgg

Re: Adding a character to the beginning of a character string

PGStats — Thu, 17 Mar 2016 03:56:35 GMT

length str $6;
DO i=1 to 2;
	str = put(input(original{i}, best.), z6.);
   	DO j=1 to 3;
		new{i,j} = substr(str, 2*j-1);
		END;   	
	END;

Re: Adding a character to the beginning of a character string

Ksharp — Thu, 17 Mar 2016 09:22:02 GMT

Is it what you are looking for ?

DATA want_1;
   INPUT var1 $ var2 $;
   DATALINES;
   10101      0 
   10101     100000 
   0         10100 
   10101      0
;
RUN;
data want;
 set want_1;
 array v{*} $ var: ;
 length temp $ 6;
 do i=1 to dim(v);
  temp=v{i};
  temp=translate(right(temp),'0',' ');
  v{i}=temp;
 end;
 drop temp i;
 run;

Re: Adding a character to the beginning of a character string

FriedEgg — Thu, 17 Mar 2016 14:29:41 GMT

DATA have;
   INPUT var $ @@;
   DATALINES;
   10101      0 
   10101     100000 
   0         10100 
   10101      0
;
RUN;

DATA want;
   SET have;
   
   ARRAY xfr[3] $2 var_part1 - var_part3;
   
   CALL POKELONG( REPEAT('0',5) , ADDRLONG(xfr[1]) , 6 );
   
   CALL POKELONG( var , PTRLONGADD( ADDRLONG(xfr[1]) , 6 - LENGTHN(var) ) , LENGTHN(var) );
RUN;

Re: Adding a character to the beginning of a character string

_maldini_ — Thu, 17 Mar 2016 16:31:39 GMT

@FriedEgg Thanks for the assistance. A quick clarifying question:

I'm not familiar with this convention. When do the "@" symbols represent?

Also, I'm using SAS University Edition. I received the following error when I ran this code.

DATA a2_pershealth_destring_qwb_2;
   SET a2_pershealth_replace_nulls;
   
   ARRAY xfr[3] $2 _400803_part1	-	_400803_part3;
   
   CALL POKELONG( REPEAT('0',5) , ADDRLONG(xfr[1]) , 6 );
   
   CALL POKELONG( var , PTRLONGADD( ADDRLONG(xfr[1]) , 6 - LENGTHN(_400803) ) , LENGTHN(_400803) );
RUN;

1 OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;
55
56 DATA a2_pershealth_destring_qwb_2;
57 SET a2_pershealth_replace_nulls;
58
59 ARRAY xfr[3] $2 _400803_part1-_400803_part3;
60
61 CALL POKELONG( REPEAT('0',5) , ADDRLONG(xfr[1]) , 6 );
________ ________
251 68
ERROR: The function POKELONG cannot be invoked when SAS is in the lockdown state.
ERROR: The function ADDRLONG cannot be invoked when SAS is in the lockdown state.
ERROR 251-185: The subroutine POKELONG is unknown, or cannot be accessed. Check your spelling.
Either it was not found in the path(s) of executable images, or there was incorrect or missing subroutine descriptor
information.

ERROR 68-185: The function ADDRLONG is unknown, or cannot be accessed.

62
63 CALL POKELONG( var , PTRLONGADD( ADDRLONG(xfr[1]) , 6 - LENGTHN(_400803) ) , LENGTHN(_400803) );
________ ________
251 68
ERROR: The function POKELONG cannot be invoked when SAS is in the lockdown state.
ERROR: The function ADDRLONG cannot be invoked when SAS is in the lockdown state.
ERROR 251-185: The subroutine POKELONG is unknown, or cannot be accessed. Check your spelling.
Either it was not found in the path(s) of executable images, or there was incorrect or missing subroutine descriptor
information.

ERROR 68-185: The function ADDRLONG is unknown, or cannot be accessed.

64 RUN;

Re: Adding a character to the beginning of a character string

_maldini_ — Thu, 17 Mar 2016 16:42:53 GMT

@Ksharp Thanks for this. It does the trick, to some degree.

A value of 10100 is converted to 01010 (i.e. 01 01 0).

How could I adjust this code to produce a 6 digit string? Ideally, 10100 would be converted to 010100.

Also, a value of 10101 is converted to 01010 (i.e. 01 01 0), when it should be 01 01 01.

Thanks again.

Re: Adding a character to the beginning of a character string

_maldini_ — Thu, 17 Mar 2016 16:44:02 GMT

Also, I'm fairly new to SAS and arrays. What is the purpose of the LENGTH statement (length temp $ 6;) in the array?

Re: Adding a character to the beginning of a character string

FriedEgg — Thu, 17 Mar 2016 17:14:33 GMT

@_maldini_, My solution will not work with SAS University Edition. As the ERROR message states, this product ships in a 'lockdown state' which disables the usage of the APP functions I have used.

Re: Adding a character to the beginning of a character string

FriedEgg — Thu, 17 Mar 2016 17:15:45 GMT

The LENGTH statement is there so that the RIGHT function will be able to justify the shorter strings to the proper place and then replace the spaces at the front of the string with '0'

Re: Adding a character to the beginning of a character string

FriedEgg — Thu, 17 Mar 2016 17:17:38 GMT

The @@ instructs SAS to read the input instructions repeatedly for the same line. It is stated more clearly in the INPUT statement documentation.

http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a000146292.htm

Re: Adding a character to the beginning of a character string

Ksharp — Fri, 18 Mar 2016 00:52:43 GMT

Yes. Chang length as LENGTH temp $ 6 ;

If you want 6 digit string.

Re: Adding a character to the beginning of a character string

_maldini_ — Fri, 18 Mar 2016 20:50:16 GMT

@Ksharp The length already set to 6, no?

The current syntax is changing 10101 to 01010, which then becomes _400802_part1=01, _400802_part2=01, _400802_part3=0. _400802_part3 should equal 01.

Here's the data before the syntax:

PatientID	_400802	_400802_part1	_400802_part2	_400802_part3
140	10101	10	10	1

Here's the data after the syntax:

PatientID	_400802	_400802_part1	_400802_part2	_400802_part3
140	01010	01	01	0

I'm sorry I don't understand your syntax well enough to trouble shoot this myself! Thanks again for your help.

Re: Adding a character to the beginning of a character string

Ksharp — Sat, 19 Mar 2016 03:39:52 GMT

OK. Assuming I understand what you mean.

DATA want_1;
   INPUT var1 $ var2 $;
   DATALINES;
   10101      0 
   10101     100000 
   0         10100 
   10101      0
;
RUN;
data want;
 set want_1;
 array v{2} $ var1 var2 ;
 array v1{3} $ 2 var11-var13 ;
 array v2{3} $ 2 var21-var23 ;
 length temp $ 6;
 do i=1 to dim(v);
  temp=v{i};
  temp=translate(right(temp),'0',' ');
  v{i}=temp;

  if i=1 then do;
   k=0;
   do j=1 to 6 by 2;
    k+1;
	v1{k}=substr(v{i},j);
   end;
  end;

  if i=2 then do;
   k=0;
   do j=1 to 6 by 2;
    k+1;
	v2{k}=substr(v{i},j);
   end;
  end;


 end;

 drop temp i j k;
 run;

Re: Adding a character to the beginning of a character string

_maldini_ — Mon, 21 Mar 2016 16:40:28 GMT

@Ksharp Thank you for your time and effort here. This code works great, but I should have been more clear. I have 53 variables. My example only included 2 variables. I was just trying to simplify things. The solution you proposed would require creating 53 arrays, correct?

I was hoping I could simply add a leading 0 to the character strings, so that I could use the code/approach I have been using for the other time periods/data sets.

Here is the array I am using already, for all the other datasets, that already have a leading 0 in front of the character strings:

DATA want;
	* Setting the length of the variables to be 6 characters long;
	LENGTH 
	_400201
	_400202
	_400203
	_400204
	_400205
	_400206
	_400207
	_400208
	_400209
	_400210
        ...
	Up to 53 variables
	$6;

	SET have;

	ARRAY original {53}  
	_400201
	_400202
	_400203
	_400204
	_400205
	_400206
	_400207
	_400208
	_400209
	_400210
	...
        Up to 53 variables
        ;

	ARRAY new {53,3} $ 2 
	_400201_part1	-	_400201_part3
	_400202_part1	-	_400202_part3
	_400203_part1	-	_400203_part3
	_400204_part1	-	_400204_part3
	_400205_part1	-	_400205_part3
	_400206_part1	-	_400206_part3
	_400207_part1	-	_400207_part3
	_400208_part1	-	_400208_part3
	_400209_part1	-	_400209_part3
	_400210_part1	-	_400210_part3
	...
        Up to 53 variables
	;

	DO i=1 to 53;
   	DO j=1 to 3;
      new{i,j} = substr(original{i}, 2*j-1);
   	END;
	END;
	
	DROP 
	i j;
RUN;

Any other ideas would be greatly appreciated.

Re: Adding a character to the beginning of a character string

Ksharp — Tue, 22 Mar 2016 01:23:12 GMT

OK. I would use proc transpose.

DATA want_1;
   INPUT var1 $ var2 $;
   DATALINES;
   10101      0 
   10101     100000 
   0         10100 
   10101      0
;
RUN;
data temp;
 set want_1;
 array v{*} $ var1-var2 ;
 length temp $ 6 vname $ 40 value $ 2;
 n+1;
 do i=1 to dim(v);
  temp=v{i};
  temp=translate(right(temp),'0',' ');  
  vname=vname(v{i});
  k=0;
  do j=1 to 6 by 2;
    k+1;
	value=substr(temp,j,2);
	output;
   end;
 end;
drop i j ;
run;
proc transpose data=temp out=want(drop=_name_);
 by n ;
 var value;
 id vname k;
run;
data want;
 merge want_1 want;
run;

Re: Adding a character to the beginning of a character string

_maldini_ — Tue, 22 Mar 2016 02:43:21 GMT

@Ksharp Thank you again. We are getting there!

3 questions/issues:

1. The character strings in the original variable are of differing lengths. Ideally, the character string is 6 character long, after the leading 0 is added. So, 400203=10101 would become 010101, which would then become 400203_part1=01, 400203_part2=01, 400203_part3_01. This syntax does that! However, if the string is a different length, like 100, for example. The resutls are as follows.

400201	_4002011	__4002012	_4002013
100	00	01	00

It should be:

400201	_4002011	__4002012	_4002013
100	01	00	00 or missing

2. The other problem is w/ a value of 101 (i.e. Refused to respond). The results are as follows:

400203	_4002031	__4002032	_4002033
101	00	01	01

Here, the 3 resulting variables should probably be sett to missing ("").

3. Where in this syntax can I change the vew variable names? I can't quite figure it out. It would be ideal, to sync w/ the code that follows it, if the names could be _400201_part1, _400201_part2 _400201_part3 as opposed to _4002011, _4002012, _4002013.

Thank you again!!

Re: Adding a character to the beginning of a character string

Ksharp — Tue, 22 Mar 2016 03:03:17 GMT

So you don't want padding zero before it all the time ?

DATA want_1;
   INPUT var1 $ var2 $;
   DATALINES;
   10101      0 
   10101     100000 
   0         10100 
   10101      0
   100   101
;
RUN;
data temp;
 set want_1;
 array v{*} $ var1-var2 ;
 length temp $ 6 vname $ 40 value $ 2 kname $ 40;
 n+1;
 do i=1 to dim(v);
  temp=v{i};
  if temp not in ('100' '101') then temp=translate(right(temp),'0',' '); 
   else if temp='100' then temp=translate(temp,'0',' '); 
     else if temp='101' then call missing(temp); 
  vname=vname(v{i});
  k=0;
  do j=1 to 6 by 2;
    k+1;
    kname=cats('Part',k);
	value=substr(temp,j,2);
	output;
   end;
 end;
drop i j ;
run;
proc transpose data=temp out=want(drop=_name_) delimiter=_;
 by n ;
 var value;
 id vname kname;
run;
data want;
 merge want_1 want;
run;