topic Re: the contents of SAS data _null_ in SAS Programming

the contents of SAS data _null_

LineMoon — Fri, 11 Mar 2016 22:08:29 GMT

Hello,

What is the sas option about the using x command -with unix- and data inside data _null_ likes this :

data _null_;

x " cd ";

data toto;

.....

run;

It works, but is it correct ?

Thank you

Re: the contents of SAS data _null_

LinusH — Fri, 11 Mar 2016 23:32:53 GMT

X is a global statement which means that it executes outside the data step.
The similar call system executes inside the data step.

Re: the contents of SAS data _null_

ballardw — Fri, 11 Mar 2016 23:35:58 GMT

You want to check OS specific bits but X is a global statement inside a data step like Format, Label, informat, drop and such. It executes as a data step is compiled.

If you need this conditionally executed then use CALL SYSTEM instead.

Re: the contents of SAS data _null_

LineMoon — Sat, 12 Mar 2016 09:56:35 GMT

For every thing run ok.

But is it correct to run

data _null_;

......................

..................

data toto;

......

run;

Re: the contents of SAS data _null_

LinusH — Sat, 12 Mar 2016 13:47:19 GMT

New question = new thread.
This question is very basic and can be found in the documentation. And why so you ask, what's problem?

Re: the contents of SAS data _null_

LineMoon — Sat, 12 Mar 2016 19:11:52 GMT

Because, I have seen two opinions some says that is correct, some says , it is not correct.

Do you have any documentation for that ?

Re: the contents of SAS data _null_

Tom — Sat, 12 Mar 2016 20:17:25 GMT

It is easier for the humans that need to read your programs to explicitely end your steps. But if you don't SAS will end them when it sees that you want to start a new one.

So if you code:

data step1;
  <some data step statements>
run;
data _null_;
  x <some OS statement>
  <some data step statements>
data step3;
  <some data step statements>
run;
run;

The SAS will run the first data step, then the X command, then the second (data _null_) step and then the third data step. The extra run statement at the end does nothing.

To make it clearer to humans you should code it this way.

data step1;
  <some data step statements>
run;
x <some OS statement>
data _null_;
  <some data step statements>
run;
data step3;
  <some data step statements>
run;

Re: the contents of SAS data _null_

Reeza — Sat, 12 Mar 2016 22:36:43 GMT

The data _null_ does not add any value to your process. If it doesn't add value why include it in your code?

Keep it clean.

Re: the contents of SAS data _null_

LineMoon — Sat, 12 Mar 2016 22:55:45 GMT

Thank you for answer, that's quiet well.

I observe that ,if I want to do action by sas and unix command( copy : cp....), for exemple, if I want to copy a file and to stock thiers names in sas table, I must have to do :

data _null_;

x "cd rep";

filename fle pipe "cp -R V1 V2";

data check_files;

length file_name $300;

infile fle truncover;

input fle 1-300;

run;

Thank for your comments, any documentation are welcomed

Re: the contents of SAS data _null_

LineMoon — Sat, 12 Mar 2016 22:53:50 GMT

Thank you for your answer.

As I said before, I observe that, when I use data _null_ ; x....; data t; run run;

I can keep the files names in data

Re: the contents of SAS data _null_

Tom — Sat, 12 Mar 2016 23:10:26 GMT

I think you might be under the impression that you can nest steps the same way you might nest DO loops. That doesn't work.

As to your sample program what are you trying to read into the dataset? What output do you expect the cp command to generate?

Perhaps you meant to use the ls command instead.

Note that you can just put the command(s) into the INFILE statement.

data check_files;
  infile "cd  rep ; ls  -R   V1  V2" pipe truncover;
  length file dname $255 ;
  retain dname ;
  input file $255. ;
  if file=' ' then delete;
  if substr(file,length(file))=':' then do;
      dname=file;
      delete;
  end;
run;

Re: the contents of SAS data _null_

LineMoon — Sun, 13 Mar 2016 00:14:45 GMT

@Tom : Thank for your answer again.

I want to copie a directory( D1) into an other directory(D2)

I know with the command "ls", I do not need my synthax " Data _null_; x ...; data chech; run; run;

For some commands, to work my command " CP and others commands " to keep the files, I need my synthax "" Data _null_; x ...; data chech; run; run; " but my method does the job well, that's why I ask the question ?

Re: the contents of SAS data _null_

Tom — Sun, 13 Mar 2016 00:36:52 GMT

@LineMoon wrote:

@Tom : Thank for your answer again.

I want to copie a directory( D1) into an other directory(D2)

I know with the command "ls", I do not need my synthax " Data _null_; x ...; data chech; run; run;

For some commands, to work my command " CP and others commands " to keep the files, I need my synthax "" Data _null_; x ...; data chech; run; run; " but my method does the job well, that's why I ask the question ?

Not sure what you mean by "does the job well". If you want to execute the copy command you can either just run the command using one of the many methods to run the command.

x "cd top_level_directory; cp -R d1 d2" ;

/* OR */

%sysexec "cd top_level_directory; cp -R d1 d2" ;

/*  OR */

data _null_;
  call system("cd top_level_directory; cp -R d1 d2" );
run;

Or you can use the PIPE option on a FILENAME or an INFILE statement. But for that to make the command actually run you need attempt to read from the pipe.

data _null_;
  infile  "cd top_level_directory; cp -R d1 d2"  pipe;
  input;
  put _infile_;
run;

/* OR */

filename cmd pipe "cd top_level_directory; cp -R d1 d2" ;
data _null_;
  infile cmd ;
  input;
  put _infile_;
run;

In no case is it necessary to add an extra 'data _null_;' before everything or and extra 'run;' after everything.

Re: the contents of SAS data _null_

Tom — Sun, 13 Mar 2016 00:49:40 GMT

@LineMoon wrote:

Thank you for your answer.

As I said before, I observe that, when I use data _null_ ; x....; data t; run run;

I can keep the files names in data

What do you mean by "keep the files names in data"? Unless your Unix system works differenly than most the cp command will not output any file names for you to read into a data set.

Perhaps you mean that you want to generate the command to run using data that you have in an existing SAS dataset.

For example let's say that the directory names that you want to copy are available as the values of variables in a dataset.

data example;
   source='D1';
   target='D2';
run;

Now you can use this data step to generate the proper copy command ('cp -R D1 D2') and execute it.

data _null_;
   set example;
   length cmd $1000;
   cmd = catx(' ','cp -R',source,target);
   infile cmd pipe filevar=cmd ;
   input;
   put _infile_;
run;

Re: the contents of SAS data _null_

LineMoon — Sun, 13 Mar 2016 00:44:35 GMT

Thank you so much , tom.

I want to say by "deos the job well", I get the right the results, I think, when I do not use my methode , I can not keep the files name in data steps

Re: the contents of SAS data _null_

LineMoon — Sun, 13 Mar 2016 00:53:52 GMT

@Tom: what's i mean by "keep the files names in data"?

So , I the ddirectory

D1/file1.txt

/ffile2.txt

/file2.xls

I want to copy D1 in D2

After the "copy" , I want to check the files name have been copied from D1 to D2 in data set check likes this:

Files

file1

file2

filen

As I said, my method give me the right result for copy, ...

Re: the contents of SAS data _null_

Tom — Sun, 13 Mar 2016 00:58:35 GMT

If you want to check whether the copy succeeded it is probably easiest to just read the list of files and compare them.

Did you try using the unix command diff. diff -rq D1 D2 will compare directory D1 with directory D2 and report the differences.

Or just read the output of the ls (or ls -R) command into datasets and compare the datasets.

Re: the contents of SAS data _null_

LineMoon — Sun, 13 Mar 2016 10:28:06 GMT

that's correct..We can do that, I have used it before

But the difference is that, with my method, in one action, I can copy and check the files names..

In other methos, I think, I need two actions : action1 : copy( with cp) and action2 : listing the contents(with ls)

Re: the contents of SAS data _null_

Tom — Sun, 13 Mar 2016 12:09:47 GMT

Where are you getting the file names now? The cp command you are running will not list the file names. So the data step you are running that is reading form the output of the cp command will read nothing and so have 0 observations.

You could try adding the -v option to the copy command. THen the data step that runs the cp command could read the output and parse it.

To see how that might work let's create a couple and directories with some files and try to copy from one directory to the other.

>mkdir dir1
>mkdir dir2
>touch dir1/file1
>touch dir1/file2
>touch dir1/file3
>touch dir2/file2
>chmod -w dir2/file2

Notice how there should be a problem copying file2 since the target file alread exists and is readonly. Now lets try to copy and see what messages the -v option generates.

>cp -vR dir1/* dir2 
`dir1/file1' -> `dir2/file1'
`dir1/file2' -> `dir2/file2'
cp: cannot create regular file `dir2/file2': Permission denied
`dir1/file3' -> `dir2/file3'

So now you could make yourself a data step that reads that output and generates a SAS dataset with the messages.

data files ;
  infile 'cp -vR dir1/* dir2' pipe dsd dlm=' ' truncover end=eof;
  length success 8 from to $255 dummy $5 ;
  drop dummy;
  input from dummy to ;
  if eof then success=1 ;
  else do;
    input @@;
    success = (_infile_ ^=: 'cp:') ;
    if not success then input;
  end;
run;

Re: the contents of SAS data _null_

LineMoon — Sun, 13 Mar 2016 14:51:32 GMT

Thank tou Tom