topic CALL EXECUTE example in SAS Programming

CALL EXECUTE example

SAS_inquisitive — Mon, 07 Mar 2016 14:44:54 GMT

Here I have an example of using CALL EXECUTE. I wonder why the second code does not work when I omit the concatenation oeprator.

data test;
input a $;
cards;
1
2
3
;

data _null_;
	set test end=last;
    call execute('proc print data=sashelp.class (obs='||a||'); run;');
run;

data test;
input a $;
cards;
1
2
3
;

data _null_;
	set test end=last;
    call execute('proc print data=sashelp.class (obs='a'); run;');
run;

Re: CALL EXECUTE example

Kurt_Bremser — Mon, 07 Mar 2016 14:41:35 GMT

This message:

ERROR 253-185: The EXECUTE subroutine call has too many arguments.

provides the answer.

CALL EXECUTE expects ONE argument of type character. You are supplying three: a string constant, a variable of type character, and another string constant.

Re: CALL EXECUTE example

Reeza — Mon, 07 Mar 2016 14:42:51 GMT

Because it isn't valid SAS code. The string isn't being created, there's no default concatenation.

Re: CALL EXECUTE example

RW9 — Mon, 07 Mar 2016 14:46:32 GMT

The call execute function requires a string to be passed to it as its only parameter. This

'proc print data=sashelp.class (obs='a'); run;'

is not a string, it is two strings:

'proc print data=sashelp.class (obs='

'); run;'

and something undefined.

Function form:

call execute(<string>);

By using the concatenate symbols you are creating one string out of the two given strings and the value held in the variable a.

One other thing, as a string in the dataset is given a length of 8 (as you didn't define it!) you may want to use cats:

data _null_;
  set test end=last;
  call execute(cats('proc print data=sashelp.class (obs=',a,'); run;'));
run;

This should remove any blanks around a.

Re: CALL EXECUTE example

SAS_inquisitive — Mon, 07 Mar 2016 14:54:00 GMT

Thank you, all. I was assuming I was creating a string by enclosing variable a in quotation marks.