topic Re: Creating a list of indexed names in SAS Programming

Creating a list of indexed names

braverju — Mon, 25 Jan 2016 21:43:59 GMT

May somebody help me with SAS syntax.

I would like to create a list

%let listVars = a1|a2|a3|a4|a5;

OR a dataset

dataset myListVars;

input item $32.;

dataline;

;

How can I do it without listing ALL names. Is it possible to do something like:

%let listVars = a1 – a5;

dataset myListVars;

input item $32.;

dataline;

a1 - a5

;

Thank you

Julia

Re: Creating a list of indexed names

Reeza — Mon, 25 Jan 2016 21:47:54 GMT

What are you planning to use this for down the line?

You could use a loop, but there's probably better ways to do whatever you're trying to do is my guess.

data want;
     do i=1 to 99;
          Item=catt("A", put(i, z2.));
          output;
     end;
run;

Re: Creating a list of indexed names

DanZ — Mon, 25 Jan 2016 21:49:35 GMT

Are you trying to put a list of variable names from a table that already exists into a macro variable? Or, are you trying to create a table with a list of variable names?

Re: Creating a list of indexed names

FreelanceReinh — Mon, 25 Jan 2016 21:56:42 GMT

Once you have the dataset, creating the macro variable is easy, too:

data myListVars;
length item $32;
do _n_=1 to 5;
  item=cats('a',_n_);
  output;
end;
run;

proc sql noprint;
select *
into :listvars separated by '|'
from myListVars;
quit;

Re: Creating a list of indexed names

braverju — Mon, 25 Jan 2016 22:08:21 GMT

Thank you very much. This is exactly what I need. I just didn't know the first part.

Re: Creating a list of indexed names

FreelanceReinh — Mon, 25 Jan 2016 22:12:25 GMT

You're welcome. But if you only need the macro variable, you can get it even more easily:

data _null_;
array x[5] (1:5);
call symputx('listvars', 'a'||catx('|a', of x:));
run;

Re: Creating a list of indexed names

braverju — Mon, 25 Jan 2016 22:51:22 GMT

Thank you! Even better!