topic Re: multiple variables use the same condition, how to write them in the same if statement? in SAS Programming

multiple variables use the same condition, how to write them in the same if statement?

ZRick — Thu, 08 Mar 2012 19:23:16 GMT

Two variables accrual_1, accrual_2 share the same condition, but I don't know how to write them into the same if statement.

data tmp;

input accrual_1 accrual_2;

cards;

1 2

12 4

3 5

;

data tmp2 tmp3;

set tmp;

if (accrual_1 or accrual_2) not in (1, 2, 3, 4, 5, 6) then output tmp3;

else output tmp2;

run;

Re: multiple variables use the same condition, how to write them in the if statement?

Linlin — Thu, 08 Mar 2012 19:27:29 GMT

data tmp;

input accrual_1 accrual_2;

cards;

1 2

12 4

3 5

;

data tmp2 tmp3;

set tmp;

if accrual_1 not in (1, 2, 3, 4, 5, 6) or accrual_2 not in (1, 2, 3, 4, 5, 6) then output tmp3;

else output tmp2;

run;

/*or */

data tmp2 tmp3;

set tmp;

if accrual_1 in (1, 2, 3, 4, 5, 6) and accrual_2 in (1, 2, 3, 4, 5, 6) then output tmp2;

else output tmp3;

run;

Linlin

multiple variables use the same condition, how to write them in the same if statement?

ZRick — Thu, 08 Mar 2012 19:44:28 GMT

sidebar question:

how did you get the color coding in the post?

I tried to do that in base sas and copy / paste, it does not work for me.

multiple variables use the same condition, how to write them in the same if statement?

ZRick — Thu, 08 Mar 2012 19:50:00 GMT

Is there a way to group variables together and just write the condition once?

I have many variables share the same condition.

multiple variables use the same condition, how to write them in the same if statement?

Linlin — Thu, 08 Mar 2012 20:02:49 GMT

to get color coding:

copy from SAS editor ,paste to word, copy from word, paste to here.

multiple variables use the same condition, how to write them in the same if statement?

Haikuo — Thu, 08 Mar 2012 20:15:20 GMT

For your specific condition, you could try array():

data tmp3 tmp2 ;

set tmp;

n=0;

array acc(*) acc:;

do _n_=1 to dim(acc);

if acc(_n_) not in (1,2,3,4,5,6) then do;

output tmp3;

n+1;

return;

end;

if n=0 then output tmp2;

drop n;

run;

Regards,

Haikuo

multiple variables use the same condition, how to write them in the same if statement?

Linlin — Thu, 08 Mar 2012 20:25:49 GMT

using array maybe helpful:

data tmp;

input accrual_1 accrual_2 accrual_3 accrual_4;

cards;

1 2 1 2

12 4 12 4

3 5 3 5

;

data tmp2 tmp3;

set tmp;

array acc(*) accrual_1 accrual_2 accrual_3 accrual_4;

count=0;

do _n_=1 to dim(acc);

if acc(_n_) in (1,2,3,4,5,6) then count+1;

end;

/* count is the number of variables that have same condition */

if count=4 then output tmp2;

else output tmp3;

run;

multiple variables use the same condition, how to write them in the same if statement?

Ksharp — Fri, 09 Mar 2012 06:04:42 GMT

I think you should add a LEAVE statement in the do loop.

Ksharp

multiple variables use the same condition, how to write them in the same if statement?

Haikuo — Fri, 09 Mar 2012 12:37:08 GMT

Thanks, Ksharp. I thought about it. I have a 'return' inside the do-loop, will that lead to 'leave' action in the context of this code?

Haikuo

multiple variables use the same condition, how to write them in the same if statement?

ZRick — Fri, 09 Mar 2012 16:33:44 GMT

I think _n_ is the count of the variable, right?

Because it is set from 1 to dim(acc).

I think dim(acc) means the column of the table, not the row,

Am I right?

Re: multiple variables use the same condition, how to write them in the same if statement?

Linlin — Fri, 09 Mar 2012 17:12:39 GMT

_n_ is the index-variable of the do loop. it is the same as "i" in "do i=1 to 20". the advantage to use "_n_ " is that "_n_" will be dropped automatically from the output datasets. if you replace "_n_" with "i" in my example then "i" will be in datasets tmp2 and tmp3 as a variable.

dim(acc) is the number of elements in array "acc". in my example dim(acc)=4 because they are four elements (accrual_1 accrual_2 accrual_3 accrual_4) in the array.

multiple variables use the same condition, how to write them in the same if statement?

ZRick — Fri, 09 Mar 2012 18:34:27 GMT

It looks like your saying echos my point.

Then why do you use count as a counter, we should use _n_, right? So, count is not used at all, code should look like this:

data tmp2 tmp3;

set tmp;

array acc(*) accrual_1 accrual_2 accrual_3 accrual_4;

do _n_=1 to dim(acc);

if acc(_n_) in (1,2,3,4,5,6) then count+1;

end;

/* count is the number of variables that have same condition */

if _n_=4 then output tmp2;

else output tmp3;

run;

Am I right?

multiple variables use the same condition, how to write them in the same if statement?

Linlin — Fri, 09 Mar 2012 19:15:04 GMT

You can't replace count with _n_ in the sample code. count is used to calculate how many variables meet your condition (in (1,2,3,4,5,6)). In my sample code, if all the four variables are in (1,2,3,4,5,6) then output to tmp2(count will be 4) , if one or more variables are not in (1,2,3,4,5,6) then output to tmp3 (count will be less then 4).

Re: multiple variables use the same condition, how to write them in the same if statement?

FriedEgg — Fri, 09 Mar 2012 19:28:38 GMT

%macro multiVin(vars= ,incond= ,link=or ,output= ,elsout=);
  %if %str(&link)=%str(or) %then %let ocond=%str(>1);
   %else %let ocond=dim(acc&sysindex);
  array acc&sysindex
 &vars;
  array cnt&sysindex[1] _temporary_;
  cnt&sysindex[1]=0;
  do _n_=1 to dim(acc&sysindex);
   if acc&sysindex[_n_] in (&incond) then cnt&sysindex[1]+1;
  end;
  if cnt&sysindex[1]=&ocond then output &output;
  %if &elsout>. %then %do;
   else output &elsout;
  %end;
%mend;
data foo;
 input accrual_1-accrual_4;
 cards;
1 2 1 2
12 4 12 4
3 5 3 5
9 9 9 9
;
run;
data bar;
 set foo;
 %multiVin(vars=accrual_1-accrual_4 ,incond=%str(1,2,3,4,5,6) ,link=and);
run;
   accrual_1       accrual_2       accrual_3       accrual_4
           1               2               1               2
           3               5               3               5
data bar;
 set foo;
 %multiVin(vars=accrual_1-accrual_4 ,incond=%str(1,2,3,4,5,6) ,link=or);
run;
   accrual_1       accrual_2       accrual_3       accrual_4
           1               2               1               2
          12               4              12               4
           3               5               3               5

Re: multiple variables use the same condition, how to write them in the same if statement?

Ksharp — Mon, 12 Mar 2012 06:37:57 GMT

Opps. missing that. My bad.

multiple variables use the same condition, how to write them in the same if statement?

ZRick — Sun, 18 Mar 2012 18:32:07 GMT

can you help explain "return" and "leave" inside the Do loop? appreciate it!

multiple variables use the same condition, how to write them in the same if statement?

ZRick — Sun, 18 Mar 2012 18:48:10 GMT

I don't quite understand your "n"

before the loop, n=0;

during the loop, n+1;

and after the loop: if n=0 then output tmp2;

multiple variables use the same condition, how to write them in the same if statement?

Ksharp — Mon, 19 Mar 2012 08:12:47 GMT

RETURN will return the top of data step immediately, and will not execute the following code.

LEAVE will leave the current loop and will not execute the following code in the loop, but will also execute the code after loop.

Ksharp