topic Re: Output dataset for multiple chi squared test for association in SAS Programming

Output dataset for multiple chi squared test for association

Luigim — Wed, 13 Jan 2016 19:26:05 GMT

Hi everybody,
I have a data set containing 35 categorical variable that I want to test with other 33 dichotomous variables using chi squred test. If I run
Proc freq data=mydata;
Table = c_: * d_: / chisq;
Run;
It works but i was struggling how to create a simple output data set with just three information: the two variables used in every test and the pchi.

Thanks everybody in advance

Re: Output dataset for multiple chi squared test for association

PGStats — Thu, 14 Jan 2016 03:29:15 GMT

Use ODS OUTPUT to get the table :

ods listing select none;
proc freq data=sashelp.heart;
table (status sex) * (chol_status bp_status weight_status) / chisq;
ods output ChiSq=outChiSq;
run;
ods listing;

proc sql;
create table myChiSq as
select 
    scan(Table,2) as v1 length=32, 
    scan(Table,3) as v2 length=32, 
    df, 
    value, 
    prob
from outChiSq
where statistic="Chi-Square"
order by v1, v2;
select * from myChiSq;
quit;

Note : You need parentheses around the variable lists in the TABLES statement.

Re: Output dataset for multiple chi squared test for association

Luigim — Thu, 14 Jan 2016 11:36:07 GMT

This is great! Thank you so much!

Re: Output dataset for multiple chi squared test for association

PGStats — Thu, 14 Jan 2016 15:35:46 GMT

You are welcome. Please mark answer as accepted solution.