topic Re: Element of hash object in SAS Programming

Element of hash object

SAS_inquisitive — Tue, 05 Jan 2016 22:43:55 GMT

How to retrieve the particular element of hash object , let's say 10th element from hash object of sashelp.class?

data work.test;
	if 0 then
		set sashelp.class;

	if _n_=1 then
		do;
			dcl hash h(dataset:'sashelp.class',ordered:'A',multidata&colon;'yes');
  		    dcl hiter hi('h');
			h.definekey('Name');
	        h.definedata(all:'y');
			h.definedone();
		end;
      /*rc=h.output(dataset:'work.out');*/
      rc=hi.first();
	  rc1=hi.next();
	  put rc;
	  put rc1;
run;

Re: Element of hash object

Haikuo — Wed, 06 Jan 2016 00:34:24 GMT

You will need to count yourself in this case, unless you have embedded a counter when loading into the Hash.

data work.test;
	if 0 then
		set sashelp.class;

	if _n_=1 then
		do;
			dcl hash h(dataset:'sashelp.class',ordered:'A',multidata&colon;'yes');
			dcl hiter hi('h');
			h.definekey('Name');
	h.definedata(all:
			'y');
			h.definedone();
		end;

	do rc=hi.first() by 0 while (rc=0);
		n+1;

		if n=10 then
			do;
				output;
				stop;
			end;

		rc=hi.next();
	end;
run;

Re: Element of hash object

SAS_inquisitive — Wed, 06 Jan 2016 02:48:17 GMT

@Haikuo Thanks. I was trying if I could use "h.num_items" method to get the desired result.

data work.test;
	if 0 then
		set sashelp.class;

	if _n_=1 then
		do;
			dcl hash h(dataset:'sashelp.class',ordered:'A',multidata&colon;'yes');
			dcl hiter hi('h');
			h.definekey('Name');
	h.definedata(all:
			'y');
			h.definedone();
		end;
num=h.num_items;
rc=hi.first();
  do  i= 1 to num;
   if i=10 then output;
      stop;
  rc=hi.next();
end;

run;

Re: Element of hash object

Haikuo — Wed, 06 Jan 2016 01:42:36 GMT

Yes, you CAN use h.num_items. Fix your buggy code first before you can see it.

Re: Element of hash object

Ksharp — Wed, 06 Jan 2016 02:32:22 GMT

Check SETCUR() method. But you need a index variable for it .

data class;
 set sashelp.class;
 n+1;
run;
data work.test;
	if _n_=1 then do;
	if 0 then set class;
			declare hash h(dataset:'class',ordered:'A');
  		    declare hiter hi('h');
			h.definekey('n');
	        h.definedata(all:'y');
			h.definedone();
	end;
 rc=hi.setcur(key:10);
 do while(rc=0);
  output;
  rc=hi.next();
 end;
run;

Re: Element of hash object

Haikuo — Wed, 06 Jan 2016 02:56:08 GMT

You have fixed a typo, which is good, but that was not what I meant. Now challenge yourself, why your code does not give you any output? if you check 'num', it has the value of 19.

Re: Element of hash object

SAS_inquisitive — Wed, 06 Jan 2016 02:59:46 GMT

Thanks, Haikuo. I will try to figure it out.

Re: Element of hash object

SAS_inquisitive — Wed, 06 Jan 2016 03:06:07 GMT

Thanks, Ksharp. It gives 10 elements of hash table. Was looking for only 10th element.

Re: Element of hash object

Ksharp — Wed, 06 Jan 2016 03:39:37 GMT

data class;
 set sashelp.class;
 n+1;
run;
data work.test;
	if _n_=1 then do;
	if 0 then set class;
			declare hash h(dataset:'class',ordered:'A');
  		    declare hiter hi('h');
			h.definekey('n');
	        h.definedata(all:'y');
			h.definedone();
	end;
 rc=hi.setcur(key:10);

  output;
stop;
run;

Re: Element of hash object

Haikuo — Wed, 06 Jan 2016 15:16:46 GMT

@Ksharp, If you already have the index loaded, you don't need hiter at all. Just 'rc=h.find(key:10)' will be sufficient.