topic Re: IF/Then Statement tying multiple rows together in SAS Programming

IF/Then Statement tying multiple rows together

UMAnalyst — Fri, 18 Dec 2015 12:11:57 GMT

I transposed data from long to wide and now I need to compare multiple strings (up to four string vars) to determine similitude. I need to concatenate only the unequal strings.

example:

ID comment1 comment2 comment3 Comment4 RESULT

1001 This is some text This is some text This is some text

1002 More text like this More text like this Not the same More text like this More text like this Not the same

Currently, only my first if-then is holding, which is "if comment1=comment2 then COMMENT=comment1". I'll spare you the rest, because it's not pretty.

Thanks in advance.

Re: IF/Then Statement tying multiple rows together

Astounding — Fri, 18 Dec 2015 13:06:50 GMT

SImplest would be to change the variables to eliminate duplicates:

array comment {4};

do I=1 to 3;

do J=i+1 to 4;

if comment{I} = comment{J} then comment{J}=' ';

end;

Then combine them:

result = catx(' ', of comment1-comment4);

If it's not acceptable to replace the original COMMENT variables, copy them to new variables first and work on the new variables to get RESULT.

Re: IF/Then Statement tying multiple rows together

UMAnalyst — Fri, 18 Dec 2015 13:30:27 GMT

Thank you. It's scary to delete stuff, but that's why we have backups.

Re: IF/Then Statement tying multiple rows together

RW9 — Fri, 18 Dec 2015 13:39:49 GMT

Why transpose the data in the first place to to this, then code around the fact that its transposed? Just do your logic on the normalised data.

Re: IF/Then Statement tying multiple rows together

pearsoninst — Fri, 18 Dec 2015 13:45:27 GMT

you can continue comment1=comment2 and
comment3=comment4 and so on.. as you have only 4 Variables and if you do not understand Do Loops.How ever DL is actually a permanent solution

Re: IF/Then Statement tying multiple rows together

UMAnalyst — Fri, 18 Dec 2015 13:52:02 GMT

I transposed because I need to get from multiple rows per respondent to one row per respondent.

Re: IF/Then Statement tying multiple rows together

RW9 — Fri, 18 Dec 2015 14:57:34 GMT

Perhaps you misunderstand, you can process the data either in long or wide format, it makes no difference. Personally I would use transposed data only for reporting purposes (apart from a few times). Its just simpler working with normalised data&colon;

data have;
  length comment $50;
  id=1; 
  comment="This is some text"; output;
  comment="This is some text"; output;
  comment=""; output;
  comment="This is some text"; output;
  id=2; 
  comment="More text like this"; output;
  comment="More text like this"; output;
  comment="Not the same"; output;
  comment="More text like this"; output;
run;

proc sort data=have nodupkey;
  by id comment;
run;

data want (keep=id result);
  set have;
  by id;
  retain result;
  length result $2000;
  if first.id then result="";
  result=catx(" ",result,comment);
  if last.id then output;
run;

Re: IF/Then Statement tying multiple rows together

UMAnalyst — Fri, 18 Dec 2015 17:15:42 GMT

Great idea. Thanks again.