topic Re: Do loop question in SAS Programming

Do loop question

dunga — Thu, 17 Dec 2015 21:15:40 GMT

Hi SAS Forum,

Below code works well but could you please help me to convert this to a code saving do loop like thing.

data want;

set have;

If Time1 = 'CURRENT' or

Time2 = 'CURRENT' or

Time3 = 'CURRENT' or

Time4 = 'CURRENT'or

Time5 = 'CURRENT' or

Time6 = 'CURRENT' or

Time7 = 'CURRENT' or

Time8 = 'CURRENT' or

Time9 = 'CURRENT' or

Time10 = 'CURRENT' or

Time11 = 'CURRENT' or

Time12 = 'CURRENT'

then flag=1;

Else flag=0;

run;

Thanks

Mirisa

Re: Do loop question

Astounding — Thu, 17 Dec 2015 22:31:43 GMT

Try it this way:

if whichc('CURRENT', of time1-time12) then flag=1;

else flag=0;

Re: Do loop question

Reeza — Thu, 17 Dec 2015 22:37:11 GMT

You don't need a do loop you need the whichc function.

If whichc('Current', of time1-time12)>0 then flag=1;

Re: Do loop question

Reeza — Thu, 17 Dec 2015 22:37:30 GMT

Make sure the case matches...

Re: Do loop question

mohamed_zaki — Thu, 17 Dec 2015 23:05:12 GMT

data want (drop=i);
set have;
array Time(*) Time1-Time12;
flag=0;
do i = 1 to 12;
   if Time(i) = "CURRENT" then do ;
   		flag=1;
   		LEAVE;
   end;
end;
run;

Re: Do loop question

PGStats — Thu, 17 Dec 2015 23:24:13 GMT

If you don't want to worry about the number of Time variables or the case of the strings use:

data want;
set have;
array T(*) Time:;
do i = 1 to dim(T) until(flag);
   flag = flag or upcase(T{i}) = "CURRENT";
   end;
drop i;
run;

Re: Do loop question

Ksharp — Fri, 18 Dec 2015 01:46:27 GMT

data want;
 set have;
 array x{*} time1-time12;
 flag='CURRENT' in x;
run;

Re: Do loop question

dunga — Fri, 18 Dec 2015 04:33:43 GMT

Hi Astounding, Reeza, Zaki, PGStats and Ksharp,

Many thanks to veryone of you.

Reponses are great!

Dunga

Re: Do loop question

mlogan — Fri, 18 Mar 2016 19:20:52 GMT

Hi Xia, your code is very helpful, but it is pointing only to one variable and exact text (CURRENT in this case). Can you please tell me the code for Two variable ('Current' and 'Past' in this case) with UPCASE option? I mean flag it when either Current or Past exist regardless of upper or lower case. Thanks.

data have;
input ID (Time1 Time2 Time3) ( & $10.);
cards;
1234 CURRENT Current Current
5678 Current Current3 Current
3456 Current Past Current
2345 Current CURRENT Current2
;
run;

data want1;
set have;
array x{*} time1-time3;
flag='CURRENT' in x;
run;

Re: Do loop question

mlogan — Fri, 18 Mar 2016 19:27:42 GMT

Hi PG, Your code working perfect. Would you please show me the code when there are two variable I am comparing with?
I mean flag the observation when:
a) 'Current' AND 'Past' exist and
b) 'Current' OR 'Past' exist.
(using upcase in both cases)
Thanks,

data have;
input ID (Time1 Time2 Time3) ( & $10.);
cards;
1234 CURRENT Current Current
5678 Current Current3 Current
3456 Current Past Current
2345 Current CURRENT Current2
;
run;

Re: Do loop question

Ksharp — Sat, 19 Mar 2016 04:04:56 GMT

Opps. Missing something.

data have;
input ID (Time1 Time2 Time3) ( & $10.);
cards; 
1234 CURRENT Current Current
5678 Current Current3 Current
3456 Current Past Current
2345 Currernt CURRENrT Current2
;
run;

data want1;
set have;
array x{*} $ time1-time3;
flag=0;
do i=1 to dim(x);
 if prxmatch('/^(current|past)$/i',strip(x{i})) then do;flag=1;leave;end;
end;
drop i;
run;

Re: Do loop question

mlogan — Sun, 20 Mar 2016 01:58:54 GMT

Thanks Xia, It worked for me perfect!!!