topic Re: Do loop in SAS Programming

Do loop

DartRodrigo — Thu, 26 Nov 2015 16:09:40 GMT

Hi,

I have the following code sent to me by Reeza:

data random;
    array s(60) s1-s60 (60*0);
    array p(6) p1-p6;
    do i=1 to 6;
        do while(p(i)=.);
            p(i)=floor(rand('uniform')*60+1);
            if s(p(i))=0 then s(p(i))=1;
            else p(i)=.;
         end;
     end;
keep p1-p6;
call sortn(of p(*));
run;

This code create six random numbers from 1 to 60 without duplicating them.

Now i need a loop to create 60 lines with diferente possibilities, the sequence (can't,may not) duplicate

What i mean: if the sequence is: 1,2,3,4,5,6 the next line may not duplicate, so it can be any other sequence,

1,2,3,4,5,7 or 13,24, 25,30,57,58

Thanks in advance,

Rodrigo

Re: Do loop

Reeza — Thu, 26 Nov 2015 16:12:31 GMT

Does order matter?

Re: Do loop

DartRodrigo — Thu, 26 Nov 2015 16:14:18 GMT

No, order doesn't metter but what metter is: if one sequence exists, it can not be duplicated.

That's all, thanks

Re: Do loop

FreelanceReinh — Thu, 26 Nov 2015 16:26:06 GMT

I'm not sure that you understood Reeza's question the same way as I did: Would you regard the two sequences 1,2,3,4,5,6 and 1,2,3,4,6,5 as duplicates (because they contain the same numbers and "order doesn't matter")?

Re: Do loop

DartRodrigo — Thu, 26 Nov 2015 16:30:47 GMT

Oh yes, this can't happen.

Thanks

Re: Do loop

Reeza — Thu, 26 Nov 2015 16:32:42 GMT

I'm not sure I see an easy clear way to do this. I'd generate a large sample, ie if I need 60, generate 100. Remove duplicates and then take the top 60.

Re: Do loop

DartRodrigo — Thu, 26 Nov 2015 16:37:11 GMT

Hum, it's ok but what i need is sixty different possibilities of sequences.

Thanks

Re: Do loop

FreelanceReinh — Thu, 26 Nov 2015 16:40:34 GMT

No problem: As Reeza wrote, you create 100 sequences and then remove (possible) duplicates and then select 60 of these. I am just writing a code example for you.

Re: Do loop

FreelanceReinh — Thu, 26 Nov 2015 16:54:24 GMT

Here is the code:

data temp(keep=r x1-x6);
array x[60];
seed=3141592653;
do i=1 to 60;
  x[i]=i;
end;
do n=1 to 100;
  call rancomb(seed, 6, of x[*]);
  r=ranuni(577215);
  output;
end;
drop i n;
run;

proc sort data=temp nodupkey;
by x1-x6;
run;

proc sort data=temp;
by r;
run;

data want;
set temp(obs=60 drop=r);
run;

Re: Do loop

Reeza — Thu, 26 Nov 2015 16:58:37 GMT

Nice!
One small suggestion, you can initialize the array in the array statement, and remove the first loop.

array x[60] (1:60);

Re: Do loop

FreelanceReinh — Thu, 26 Nov 2015 17:03:20 GMT

Thanks, Reeza. I was looking at Example 1 in the online help for CALL RANCOMB, where they initialize their array the inelegant way: array x x1-x5 (1 2 3 4 5);

Re: Do loop

DartRodrigo — Thu, 26 Nov 2015 17:17:00 GMT

Amazing man, that't exactly what i need, but if i would need 50.063.860 ()

just asking !

How much should i need to create to get the top 50.063.860 ?

Re: Do loop

FreelanceReinh — Thu, 26 Nov 2015 17:23:44 GMT

Just a mathematical side note: The probability that the NODUPKEY sort step will have to eliminate any duplicates is less than 1 in 10000 (at least in theory). So, the probability that the algorithm fails because of more than 40 duplicates must be minuscule.

Re: Do loop

Reeza — Thu, 26 Nov 2015 17:27:12 GMT

Is that 50 million?

EDIT: That's 60 choose 6 - ie all possible combinations.

If you want that, there's other, faster ways to obtain it than this method.

Re: Do loop

DartRodrigo — Thu, 26 Nov 2015 17:26:30 GMT

Yes

Re: Do loop

DartRodrigo — Thu, 26 Nov 2015 17:27:44 GMT

That's the number of possibilities of a Raffle game.

Re: Do loop

DartRodrigo — Thu, 26 Nov 2015 17:29:12 GMT

The exactly number is 50.063.860

Re: Do loop

FreelanceReinh — Thu, 26 Nov 2015 17:29:19 GMT

It's exactly the number of possible combinations of 6 out of 60 (binomial coefficient).

If you need all, you wouldn't create random combinations, but just all, systematically.

Re: Do loop

Reeza — Thu, 26 Nov 2015 17:32:20 GMT

Ok....so do you have a question?

Re: Do loop

DartRodrigo — Thu, 26 Nov 2015 17:34:43 GMT

No Reeza,

Thanks again guys, amazing answers.

Thanks