topic Re: how to split the below word in SAS Programming

how to split the below word

vraj1 — Fri, 13 Nov 2015 12:12:11 GMT

i have a variable called tm. It has character values like "DGM_HIGH_IG_DUR24_10_0" and "CGM_HIGH_IG_DUR24_12_0" and "CGM_LOW_IG_DUR24_3_5".

I want to extract _10_0 from first and _12_0 and _3_5 from second and third and calculate 10.0*34 and 12.0*34 and 3.5*34 and replace the value with the ealier ones.

Can anyone help me in this please

Betreff: how to split the below word

andreas_lds — Fri, 13 Nov 2015 12:47:32 GMT

Using the functions scan and input:

data work.have;
   length tm $ 30;
   input tm;
   datalines;
DGM_HIGH_IG_DUR24_10_0
CGM_HIGH_IG_DUR24_12_0
CGM_LOW_IG_DUR24_3_5
run;


data work.want;
   set work.have;

   length result 8;

   result = 34 * (input(scan(tm, 2, '_', 'b'), best32.) + input(scan(tm, 1, '_', 'b'), best32.) / 10);
run;

Re: how to split the below word

Jagadishkatam — Fri, 13 Nov 2015 12:46:31 GMT

Please try

data want;
set have;
len=length(tm);
ex=input(tranwrd(substr(tm,len-3),'_','.'),best.)*34;
run;

Betreff: how to split the below word

vraj1 — Fri, 13 Nov 2015 12:50:41 GMT

Thanks a lot 🙂

Can i replace the new values i.e result values with the old ones for example if i get 180.2 i need to replace it

DGM_HIGH_IG_DUR24_180_2

How can i do that please?

Re: how to split the below word

RW9 — Fri, 13 Nov 2015 13:03:43 GMT

Why are you keeping all your data in one variable to start with? A dataset which looks like this:

TM TEST FLAG GROUP DURATION TIME
DGM_HIGH_IG_DUR24_10_0 DMG H IG 24 10:00

I.e. keep your variable, but split it up into relevant variables, this would be far easier for you to work with. You can split it up simply by a do loop and a scan based of the index variable.

Re: how to split the below word

Jagadishkatam — Fri, 13 Nov 2015 13:13:14 GMT

Please try the below which will work

data want; set have; len=length(tm); ex=input(tranwrd(prxchange('s/^\_//',1,substr(x,len-3)),'_','.'),best.)*34; run;

Re: how to split the below word

vraj1 — Fri, 13 Nov 2015 13:16:43 GMT

it is not working.

Variable x is uninitialized.
NOTE: Invalid second argument to function SUBSTR at line 1

Re: how to split the below word

Jagadishkatam — Fri, 13 Nov 2015 13:29:58 GMT

Sorry

try this

data want; 
set have; 
len=length(tm); 
ex=input(tranwrd(prxchange('s/^\_//',1,substr(tm,len-3)),'_','.'),best.)*34; 
run;

Re: how to split the below word

slchen — Fri, 13 Nov 2015 13:32:09 GMT

data have;
   length tm $ 30;
   input tm;
   val=34*(input(prxchange('s/.*_(\d+)_(\d)$/$1.$2/',-1,strip(tm)),best12.));
   datalines;
DGM_HIGH_IG_DUR24_10_0
CGM_HIGH_IG_DUR24_12_0
CGM_LOW_IG_DUR24_3_5
DGM_HIGH_IG_DUR24_180_2
run;
proc print;
run;

Re: how to split the below word

vraj1 — Fri, 13 Nov 2015 13:36:23 GMT

Thanks. This is coming for me but i want to replace the new values with the old one.

for ex: CGM_HIGH_IG_DUR24_10_0 and ex value for this is 180.2 then it needs to be CGM_HIGH_IG_DUR24_180_2

Re: how to split the below word

Jagadishkatam — Fri, 13 Nov 2015 13:41:56 GMT

Could you please explain what you mean by the earliest value like if you see the earliest values from 10*34, 12*34 and 3.5*34 is 119 which is from 3.5*34. There is a confusion here to understand the earliest value

Re: how to split the below word

vraj1 — Fri, 13 Nov 2015 13:42:09 GMT

Thanks, But i want to replace the values coming from val to the tm.

Re: how to split the below word

vraj1 — Fri, 13 Nov 2015 13:45:44 GMT

yes for example i have a value in tmp called CGM_HIGH_IG_DUR24_10_0 and after calculation i.e 10.0*18=180.0 then i need to replace CGM_HIGH_IG_DUR24_10_0 to CGM_HIGH_IG_DUR24_180_0.

Hope you got it

Re: how to split the below word

Jagadishkatam — Fri, 13 Nov 2015 13:50:12 GMT

data have;
length ex2 $50;
tm="CGM_HIGH_IG_DUR24_182_0";
len=length(tm);
ex='_'||strip(put(input(tranwrd(substr(tm,prxmatch('m/\_\d/',tm)+1),'_','.'),best.)*34,best.))||'_0';
ex2=cats(prxchange('s/\_\d*\_\d//',1,tm),ex);
run;

Re: how to split the below word

Jagadishkatam — Fri, 13 Nov 2015 13:51:27 GMT

yes thank you i tried the same, hope it will help you

Re: how to split the below word

vraj1 — Fri, 13 Nov 2015 13:55:33 GMT

Here there is a small catch. if the value is 132.6 then it should come as 132_6 but we are getting CGM_LOW_IG_DUR24_132.6_0

Re: how to split the below word

Jagadishkatam — Fri, 13 Nov 2015 14:04:15 GMT

ok i understood, please try

data have;
length ex2 $50;
tm="CGM_HIGH_IG_DUR24_182_8";
len=length(tm);
dec=scan(put(input(tranwrd(substr(tm,prxmatch('m/\_\d/',tm)+1),'_','.'),best.)*34,best.),2,'.');
if dec=. then ex='_'||strip(put(input(tranwrd(substr(tm,prxmatch('m/\_\d/',tm)+1),'_','.'),best.)*34,best.))||'_0';
else if dec^=. then ex='_'||tranwrd(strip(put(input(tranwrd(substr(tm,prxmatch('m/\_\d/',tm)+1),'_','.'),best.)*34,best.)),'.','_');
ex2=cats(prxchange('s/\_\d*\_\d//',1,tm),ex);
run;

Re: how to split the below word

Steelers_In_DC — Fri, 13 Nov 2015 14:14:43 GMT

Here is a solution:

data have;
input variable $25.;
cards;
DGM_HIGH_IG_DUR24_10_0
CGM_HIGH_IG_DUR24_12_0
CGM_LOW_IG_DUR24_3_5
;

data want;
set have;
variable = catx('.',scan(variable,5,'_'),scan(variable,6,'_')) * 34;
run;

Re: how to split the below word

vraj1 — Fri, 13 Nov 2015 14:35:19 GMT

Thanks a lot

Re: how to split the below word

slchen — Fri, 13 Nov 2015 14:52:23 GMT

data have;
   length tm $ 30;
   input tm;
   val=prxchange('s/.*_(\d+?.?\d?)_(\d)$/$1.$2/',-1,strip(tm));
   if count(val,'.')>1 then val=prxchange('s/(.*).(\d)$/$1$2/',-1,strip(val));
   val=34*(input(val,best12.));
   datalines;
DGM_HIGH_IG_DUR24_10_0
CGM_HIGH_IG_DUR24_12_0
CGM_LOW_IG_DUR24_3_5
DGM_HIGH_IG_DUR24_180_2
CGM_LOW_IG_DUR24_132.6_0
;
run;
proc print;
run;

with CGM_LOW_IG_DUR24_132.6_0 in data set.