topic Re: Numeric Concatination with Leading zeros in SAS Programming

Numeric Concatination with Leading zeros

maseffa82 — Sat, 07 Nov 2015 01:48:02 GMT

Hi Everyone!

I was working on this data that has two numeric data fields with leading zeros. I wanted to concatinate without dropping the leading zeros to create a unique key. Can you guys help me please?

Field1=0001234

Field2=0005678

New Data Field will be: New_Field=00012340005678

I tried this, but keeps dropping the leading zeros from both data fields before it concatinates

DATA want;

SET have

New_Field=((LEFT(Field1)) || (LEFT(Field2));

RUN;

Thanks Guys!

Luke.

Re: Numeric Concatination with Leading zeros

Patrick — Sat, 07 Nov 2015 01:56:07 GMT

I would also add a delimiter between the two columns when concatenating as done in below code for "key2"

data have;
  Field1=0001234;
  Field2=0005678;
  output;
run;

data want;
  set have;
  length key1 $14 key2 $15;
  key1=put(field1,z7.)||put(field2,z7.);
  key2=catx('|',put(field1,z7.),put(field2,z7.));
run;

Re: Numeric Concatination with Leading zeros

Reeza — Sat, 07 Nov 2015 02:47:57 GMT

@Patrick's answer is correct. The fields probably have a format applied, but when you concatenate them it's using the unformatted value.

catx or catt are two good options to concatenate variables.

Re: Numeric Concatination with Leading zeros

Tom — Sat, 07 Nov 2015 03:02:53 GMT

@maseffa82 wrote:

Hi Everyone!

I was working on this data that has two numeric data fields with leading zeros. I wanted to concatinate without dropping the leading zeros to create a unique key. Can you guys help me please?

Field1=0001234

Field2=0005678

New Data Field will be: New_Field=00012340005678

I tried this, but keeps dropping the leading zeros from both data fields before it concatinates

DATA want;

SET have

New_Field=((LEFT(Field1)) || (LEFT(Field2));

RUN;

Thanks Guys!

Luke.

Numbers cannot store eading zeros. If they are displayed that way then it is because they have a format attached to them.

If you concatenate them you will create a character variable, which could store the leading zeros. So this statement will create a character variable with 14 digits (characters).

charid = put(field1,Z7.)||put(field2,Z7.);

Now if you want to create a new numeric variable then just use multiply one value by a power of 10 and add the other one. You can then attach a format to have the leading zeros appear.

numid = field1*10**7 + field2 ;
format numid Z14. ;

Re: Numeric Concatination with Leading zeros

slchen — Sat, 07 Nov 2015 03:09:46 GMT

It makes no sense for numeric field with leading zero in actual data. Numeric field with leading zero you see is due to format, when you concatenate, you could not get what you want. If you need to keep new field with leading zero, you have to convert numeric field to char field.
data have;
Field1=1234;
Field2=5678;
new_field1=cats(put(field1,z7.),put(field2,z7.));
new_field2=input(new_field1,14.);
format field1 z7. field2 z7. new_field2 z14.;
output;
run;

proc contents data=have;
run;

Re: Numeric Concatination with Leading zeros

maseffa82 — Sat, 07 Nov 2015 09:32:10 GMT

Thanks guys! It worked!