topic Names of datasets in a library to write into a dataset in SAS Programming

Names of datasets in a library to write into a dataset

FK — Fri, 06 Nov 2015 10:52:34 GMT

Hello Everyone,

I do have a question regarding the folowing subject:

Assume you have the following datasets in your work library: "customers" , "costs" , "revenues" and "transactions".

How can I efficiently   write a macro which generates one dataset called "overview" with a variable named "datasetnames" in which the corresponding name of each of the dataset in my work library is written into.

So in the described case above the "overview" dataset should look like this:

    datasetnames
1   customers
2   costs
3   revenues
4   transactions

Thank you in advance for any help in this topic.

Re: Names of datasets in a library to write into a dataset

pearsoninst — Fri, 06 Nov 2015 11:49:05 GMT

I think you dont have to write macro..try the below codes;

Proc contents data = work._ALL_ nods out= abc;
run;

Re: Names of datasets in a library to write into a dataset

RW9 — Fri, 06 Nov 2015 11:50:03 GMT

For what purpose? SAS has a set of metadata tables in SASHELP library which tell it what libraries, datasets, columns etc. are used. Just query that:

data want;

set sashelp.vtable (where=(libname="WORK") keep=memname);

run;

Re: Names of datasets in a library to write into a dataset

slchen — Fri, 06 Nov 2015 12:15:06 GMT

proc sql;
create table dataname as
select memname as datasetnames from dictionary.columns
where libname='WORK';
quit;

Re: Names of datasets in a library to write into a dataset

FreelanceReinh — Fri, 06 Nov 2015 12:25:41 GMT

If you really want a macro to perform this task, you could try something like this:

%macro listds(lib=work, out=overview, namevar=datasetnames, order=memname);
  proc sql;
  create table &out as
  select memname as &namevar
  from dictionary.tables
  where libname="%upcase(&lib)" & memtype='DATA'
  order by &order;
  quit;
%mend listds;

Here you have the flexibility of specifying

the library you're interested in (parameter lib, default: work)
the name of the output dataset (parameter out, default: overview)
the name of the variable containing the dataset names (parameter namevar, default: datasetnames)
the characteristic by which the dataset names are ordered (parameter order, default: memname [i.e. the dataset name]; other options include crdate [i.e. creation date], modate [i.e. last modification date], or filesize).

Sample calls:

%listds;  /* gives what you have described, however sorted alphabetically by dataset name */
%listds(lib=mylib, out=newlib.dslist, namevar=dsname, order=crdate) /* assuming that libraries mylib and newlib exist */

For more options regarding parameter order see the description of dictionary.tables:

proc sql;
describe table dictionary.tables;
quit;

Re: Names of datasets in a library to write into a dataset

FK — Sun, 15 Nov 2015 18:15:57 GMT

Thank's guys for helping me out!