topic Re: Why doesn't this macro work? in SAS Programming

Why doesn't this macro work?

BruceBrad — Wed, 01 Apr 2015 02:31:25 GMT

%macro test(n);

%if &n=1 %then a;

%if &n=2 %then b;

%mend test;

%put %test(1)zz; /* produces azz */

data;

azz=0;

v1 = %test(1)zz; /* produces error */

run;

Re: Why doesn't this macro work?

Reeza — Wed, 01 Apr 2015 03:36:12 GMT

%then a;

What are you expecting that portion of your code to do?

Re: Why doesn't this macro work?

BruceBrad — Wed, 01 Apr 2015 03:44:56 GMT

In the data step, I want to execute the line

v1 = azz;

So with

%then a;

I'm expecting the macro to return the text 'a'. It does this when I use the macro in the %put statement.

Re: Why doesn't this macro work?

Reeza — Wed, 01 Apr 2015 04:52:27 GMT

I cant test anything now, but would guess that it revolves with spaces so what you actually you see is

a zz.

You can look into the vvaluex function regardless because I think that's close to what you're looking for.

Re: Why doesn't this macro work?

Kurt_Bremser — Wed, 01 Apr 2015 07:10:46 GMT

I alos would have expected this to work.

This method works:

%macro test(n);

%global varname;

%if &n=1 %then %let varname=a;

%if &n=2 %then %let varname=b;

%mend test;

data test;

azz = 0;

bzz = 1;

%test(1);

v1 = &varname.zz;

%test(2);

v2 = &varname.zz;

run;

Re: Why doesn't this macro work?

jakarman — Wed, 01 Apr 2015 07:39:06 GMT

Back to the basics of tokens....SAS(R) 9.4 Macro Language: Reference, Third Edition

As the compiler runs you have those words/tokens. the %test(1) is a nice token and gets resolved. Than what you have caused is a change in the token of the datastep.. expecting azz as the next one token for the datastep. that is moving the pointer back to the beginning where the macro started.

It looks like that pointer for the next token is positioned AFTER the text insertion. We could see this as unwanted unexpected behavior. Should be easy to be solved by SAS. The only hurdle will be accepting this as a failure/defect/problem by SAS TS. Did you made a call to those?

The most easily answer of them is getting "works as designed"..... (sighhh)

Re: Why doesn't this macro work?

Fraktalnisse — Wed, 01 Apr 2015 12:58:33 GMT

Hi!

It seems that when you build names like this, with macros, the result is not considered as one name by sas. Instead it's considered as two names that are concatenated. But if we put the expression inside of some macro function, we can put the parts together again. For example:

data;

azz=0;

v1 = %unquote(%test(1)zz);

run;

Re: Why doesn't this macro work?

Ksharp — Wed, 01 Apr 2015 13:14:51 GMT

You need put quote around it .

%macro test(n);

%if &n=1 %then a ;

%if &n=2 %then b ;

%mend test;

%put %test(1)zz; /* produces azz */

data x;

azz=0;

v1 ="%test(1)zz"; /* produces error */

run;

Message was edited by: xia keshan

Re: Why doesn't this macro work?

jakarman — Wed, 01 Apr 2015 13:36:14 GMT

SAS UE

1 OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;

42 ;

44 %macro test(n);

45 %if &n=1 %then %do; a %end;

46 %if &n=2 %then %do; b %end;

47 %mend test;

49 %put %test(1)zz; /* produces azz */

azz

51 data;

52 azz=0;

53 v1 = %test(1)zz; /* produces error */

ERROR 22-322: Syntax error, expecting one of the following: !, !!, &, *, **, +, -, /, <, <=, <>, =, >, ><, >=, AND, EQ, GE, GT, IN,

LE, LT, MAX, MIN, NE, NG, NL, NOTIN, OR, ^=, |, ||, ~=.

54 run;

The error message is seeming the (1) being seen by the datastep not removed by macro-processing. Changing the code into:

1 OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;

42 ;

44 %macro test(n);

45 %if "&n"="" %then %do; a %end;

46 %if "&n"="1" %then %do; a %end;

47 %if "&n"="2" %then %do; b %end;

48 %mend test;

50 %put %test(1)zz; /* produces azz */

azz

52 data;

53 azz=0;

54 v1 = %test.zz; /* produces error */

388

ERROR 388-185: Expecting an arithmetic operator.

200

ERROR 200-322: The symbol is not recognized and will be ignored.

You cannot leave the () away as it will fail to recognize the macro-name a dot as separation isn't valid syntax as the macro call is not a macro variable.

Re: Why doesn't this macro work?

Ksharp — Wed, 01 Apr 2015 13:42:10 GMT

Sorry. I just push my code too quickly. See the code updated.

Re: Why doesn't this macro work?

Kurt_Bremser — Wed, 01 Apr 2015 14:01:25 GMT

Xia, he wants to parametrize the name of the variable whose value should go into v1. So v1 should be numeric and have 0 (the value of azz) as value.

Re: Why doesn't this macro work?

Ksharp — Wed, 01 Apr 2015 14:21:39 GMT

Oh. I never realize why OP would want do this . It is so weird .

%macro test(n);

%if &n=1 %then a ;

%if &n=2 %then b ;

%mend test;

%put %test(1)zz; /* produces azz */

data x;

azz=0;

v1 =%nrbquote(%test(1)zz); /* produces error */

run;

Re: Why doesn't this macro work?

jakarman — Wed, 01 Apr 2015 14:28:24 GMT

Xia, indeed it is weird to parameterize a variables names. There are many more ways (arrays?) to do something smart.
That is bringing us to the question why would BruceBad want to do this. It is some part of his mind probably doing something in many many steps.

Re: Why doesn't this macro work?

Ksharp — Thu, 02 Apr 2015 11:45:35 GMT

I like Kurt's code that should be OK too and more elegant ..

Re: Why doesn't this macro work?

jwillis — Thu, 02 Apr 2015 12:22:53 GMT

What output values are you expecting to see in variable V1? Does V1 need to contain a character value representing the name of a variable or does V1 need to contain the value of a variable name?

Kurts code:

%macro test(n);

%global varname;

%if &n=1 %then %let varname=a;

%if &n=2 %then %let varname=b;

%mend test;

data test;

azz = 0;

bzz = 1;

%test(1);

v1 = &varname.zz;

%test(2);

v2 = &varname.zz;

run;

proc print data=test(obs=7);

run;

Obs azz bzz v1 v2

1 0 1 0 1

XIA's code:

%macro test(n);

%if &n=1 %then a ;

%if &n=2 %then b ;

%mend test;

%put %test(1)zz; /* produces azz */

data x;

azz=0;

v1 ="%test(1)zz";

run;

proc print data=x(obs=7);

run;

Obs azz v1

1 0 azz

%macro test(n);

%if &n=1 %then a;

%if &n=2 %then b;

%mend test;

%put %test(1)zz; /* produces azz */

data data4;

azz=0;

v1 = %unquote(%test(1)zz); /*does not produce an error. V1 contains the value of variable AZZ */

run;

proc print data=data4;run;

Obs azz v1

1 0 0

Re: Why doesn't this macro work?

jwillis — Thu, 02 Apr 2015 15:06:53 GMT

Bruce, thank you for posting! All the responders, Thank you for educating me!

%macro test(n);

%if &n=QTR %then MSRP;

%if &n=MONTH %then INVOICE;

%mend test;

%LET version = QTR; *%LET version=MONTH;

proc sql;

create table cars_total as

select distinct sum(%unquote(%test(&VERSION.))) as &version._%unquote(%test(&VERSION.))_total, Make

from sashelp.cars

group by make

;

quit;

proc print data=cars_total(obs=9);run;

Re: Why doesn't this macro work?

BruceBrad — Thu, 02 Apr 2015 23:04:20 GMT

Thanks for all your suggestions. jwillis' use of the %unquote statement does what I want. (And yes, I probably could do this with arrays, but my original problem get very unwieldy using array statements).

Now, can anyone explain why it works like this? Presumably there is some automatic quoting going on, but I can't see why.

Re: Why doesn't this macro work?

Fraktalnisse — Fri, 03 Apr 2015 04:38:53 GMT

I thought that i gave the %unquote answer in reply 6.

Re: Why doesn't this macro work?

jakarman — Fri, 03 Apr 2015 10:13:04 GMT

Yes fraktalnisse Unquoting (or othere macro func) as having te string resolved by the macro-processor seem easier to me too.
All is about understanding the timing with macro-s http://blogs.sas.com/content/publishing/2015/04/01/sas-authors-tip-macro-language-timing-is-everything/

And if it is a real coding problem needing a bypass. Than knowing the token as root cause you can avoid that in many ways.
My approach:
- Code the fixed value part in the macro so it can return to variable as one token for the datastep compiler.

44 %macro test(n,var=zz);

45 %if &n=1 %then a&var;

46 %if &n=2 %then b&var;

47 %mend test;

50 data sim ;

51 azz=0;

52 v1 = %test(1) ; /* produces no error */

53 run;

Re: Why doesn't this macro work?

BruceBrad — Sat, 04 Apr 2015 04:32:42 GMT

So you did. I missed that. Credit now duly assigned 🙂

Thanks again.