topic Re: how to read character data that has quotation. in SAS Programming

how to read character data that has quotation.

nbonda — Wed, 24 Jun 2015 23:29:31 GMT

I have a code that read a text file, with delimiter pipe (|)

data sample;

Infile 'C:\mydata\test.txt' DSD DLM='|' LRECL=1024 MISSOVER FIRSTOBS=1 TERMSTR=LF;

Input fname :$CHAR20.

lname :$CHAR30.

city :$CHAR40.

run;

sample text file:

Jen|Turner|'Chicago'

David||'New York'

Michael|ybarra|Detroit

If I use DSD option ,SAS not reading single quotes and consecutive delimiters reading as missing value...., Without DSD option SAS reads single quotes, but consecutive delimiters are not reading as missed value.

Is there any infile options or a statement that reads single quotations in data and consider missing value for consecutive delimiter.? Thank you

Re: how to read character data that has quotation.

PGStats — Thu, 25 Jun 2015 04:54:01 GMT

Use the tilde format modifier :

data sample;

length fname $20 lname $30 city $40;

Infile datalines dsd DLM='|' MISSOVER;

Input fname ~ lname ~ city ~;

datalines;

Jen|Turner|'Chicago'

David||'New York'

Michael|ybarra|Detroit

;

proc print data=sample; run;

Re: how to read character data that has quotation.

nbonda — Thu, 25 Jun 2015 13:21:07 GMT

Is there any other option without changing my entire code . Because I have 30 similar code with lot of variables in input statement.

Re: how to read character data that has quotation.

Ksharp — Thu, 25 Jun 2015 13:32:17 GMT

Code: Program

data sample;

Infile datalines dsd DLM='|' MISSOVER;
Input fname ~ : $20. lname ~ :$20. city ~ : $20.;
datalines;
Jen|Turner|'Chicago'
David||'New York'
Michael|ybarra|Detroit
;
run;