topic Re: Automate IF-ELSE statement inside a macro. in SAS Programming

Automate IF-ELSE statement inside a macro.

KP12 — Mon, 11 May 2015 07:29:20 GMT

Hello Everyone,

I have a following code snippet, in which we keep adding an ELSE-IF statement whenever a new month starts.

For example: once the month of June will start, a new ELSE-IF condition will be added as follows:

ELSE IF &YYYYMMDD=20150531 THEN FILEDD=20150601;

where: YYYYMMDD will be the previous month's end date & FILEDD is the new month (here June) start date.

I want to automate it & avoid adding the ELSE IF statement manually every month. Any suggestions are welcome. Thanks in advance

data _null_;

call symputx('tt1',put(intnx('day',today(),-2),yymmddn8.),G);

run;

%macro DAILY_(YYYYMMDD);

data ORCL.BASE1&YYYYMMDD;

set MY_DIR.Daily_&YYYYMMDD.;

IF &YYYYMMDD='20141231'd THEN FILEDD='20150101'd;

else IF &YYYYMMDD='20150131'd THEN FILEDD='20150201'd;

else IF &YYYYMMDD='20150228'd THEN FILEDD='20150301'd;

else IF &YYYYMMDD='20150331'd THEN FILEDD='20150401'd;

else IF &YYYYMMDD='20150430'd THEN FILEDD='20150501'd;

ELSE FILEDD=FILEDD;

%mend;

%DAILY_(&tt1);

Re: Automate IF-ELSE statement inside a macro.

Kurt_Bremser — Mon, 11 May 2015 07:51:43 GMT

So you want to set any date that is the last of a month to the first of the following month?

And the dates are stored as numbers in the way you posted, but not as SAS date values?

Re: Automate IF-ELSE statement inside a macro.

MichaelLarsen — Mon, 11 May 2015 07:56:31 GMT

Try and change your macro to this:

%macro DAILY_(YYYYMMDD);

data ORCL.BASE1&YYYYMMDD;

set MY_DIR.Daily_&YYYYMMDD.;

FILEDD=PUT( INPUT("&YYMMDD", YYMMDD8.) + 1,YYMMDDN8.);

%mend;

Regards,

Michael

Re: Automate IF-ELSE statement inside a macro.

KP12 — Mon, 11 May 2015 08:23:54 GMT

Hi KurtBremser,

My requirement is, suppose today is 1st June 2015 so whenever a new month will start, I'll add an else if statement like

ELSE IF &YYYYMMDD=20150531 THEN FILEDD=20150601;

& yes the numbers are stored in the format I have posted, these are not SAS date values.

Re: Automate IF-ELSE statement inside a macro.

KP12 — Mon, 11 May 2015 08:33:34 GMT

Hi Michael,

Thank you, I will try with the code & update you.

Re: Automate IF-ELSE statement inside a macro.

RW9 — Mon, 11 May 2015 08:41:18 GMT

Hi,

Not sure why you even need a macro for that, seems to be pretty straight forward base SAS code, example:

data have;

format filedd yymmdd8.;

filedd="01JAN2014"d; output;

filedd="06JUN2014"d; output;

run;

data daily_%sysfunc(today(),date9.);

set have;

format filedd_new yymmdd8.;

filedd_new=put(intnx('month',filedd,-1,"END"),yymmddn8.); /* Replace today() with your date value */

run;

Re: Automate IF-ELSE statement inside a macro.

Kurt_Bremser — Mon, 11 May 2015 08:45:58 GMT

How about this in the data step:

int_date = intnx('month',input(put(filedd,8.),yymmdd8.),0,'end');

if input(put(int_date,yymmddn8.),8.) = filedd then filedd = input(put(int_date+1,yymmddn8.),8.);

drop int_date;

The code snippet will find any date stored in your format that is the last of a month and replace it with the first of the following month. No need for dynamic code creation.

Of course, the whole operation would be much easier if dates were stored as SAS date values:

if filedd = intnx('month',filedd,0,'end') then filedd = filedd + 1;

Re: Automate IF-ELSE statement inside a macro.

bharathtuppad — Mon, 11 May 2015 10:27:43 GMT

%let YYYYMMDD="11MAY2015"d;

data need;

if &YYYYMMDD=intnx("month",today(),0,"e") then

need=input(put(intnx("month",&YYYYMMDD,1,"b"),yymmddn8.),8.);

run;

proc print;

run;

Re: Automate IF-ELSE statement inside a macro.

Babloo — Mon, 11 May 2015 10:51:04 GMT

Your code produces following values when I ran your code without any change. Is it correct?

filedd	filedd_new
14-01-01	********
14-06-06	********

Re: Automate IF-ELSE statement inside a macro.

RW9 — Mon, 11 May 2015 10:57:09 GMT

Are you running the exact code I provided and looking at the dataset as I see:

filedd filedd_new

14-01-01 20131231

14-06-06 20140531

It looks to me like you are print the result somehow (**** means its too long for the print column).

Re: Automate IF-ELSE statement inside a macro.

Kurt_Bremser — Mon, 11 May 2015 11:03:02 GMT

babloo is right. The statement

format filedd_new yymmdd8.;

caused filedd_new to be defined numeric, which caused an improper conversion in the assignment. When the format is omitted, filedd_new is implicitly defined as character and holds the correct value.

Re: Automate IF-ELSE statement inside a macro.

RW9 — Mon, 11 May 2015 12:08:47 GMT

Ah yes. Should have looked like this:

data have;

format filedd yymmdd8.;

filedd="01JAN2014"d; output;

filedd="06JUN2014"d; output;

run;

data daily_%sysfunc(today(),date9.);

set have;

format filedd_new date9.;

filedd_new=intnx('month',filedd,-1,"END");

run;

Re: Automate IF-ELSE statement inside a macro.

KP12 — Tue, 12 May 2015 01:10:44 GMT

Hello Everyone,

Thanks for your responses, please feel free to change the date format. I'm editiing it in the question itself.

Re: Automate IF-ELSE statement inside a macro.

Kurt_Bremser — Tue, 12 May 2015 06:39:46 GMT

data _null_;

refdate = intnx('day',today(),-2);

call symput('YYYYMMDD',put(refdate,yymmddn8.));

call symput('refdate',put(refdate,best6.);

run;

data ORCL.BASE1&YYYYMMDD;

set MY_DIR.Daily_&YYYYMMDD.;

if &refdate = intnx('month',&refdate,0,'end')

then filedd = &refdate + 1;

run;

Re: Automate IF-ELSE statement inside a macro.

naveen20jan — Thu, 14 May 2015 13:22:29 GMT

Hi All ,

I have a question can anybody explain what the below part is doing and its requirement and why we have taken (-2 ).

call symputx('tt1',put(intnx('day',today(),-2),yymmddn8.),G);

Thanks

Re: Automate IF-ELSE statement inside a macro.

Kurt_Bremser — Fri, 15 May 2015 06:17:15 GMT

I have no idea why you wanted the date of the day before yesterday, you posted that bit of code

call symputx with G forces the creation of the macro variable in the global symbol table. To learn the difference between global and local symbol tables (and where variables are created per default), read the documentation of the SAS macro language.

PS intnx('day',today(),-2) is eqivalent to today()-2

Re: Automate IF-ELSE statement inside a macro.

naveen20jan — Fri, 15 May 2015 09:02:11 GMT

Hi Kurt ,

Thanks for the explaination.