topic Re: proc sgscatter display issues (for 18 variables) in SAS Programming

proc sgscatter display issues (for 18 variables)

SASdevAnneMarie — Fri, 20 Feb 2026 13:33:32 GMT

Hello Experts,

To displya the result of proc sgscatter (for 18 variables), I use ods graphics on/width=1000in height=1000in but I still have the display issues : the image is too small. Could you help me?

Thank you!

Re: proc sgscatter display issues (for 18 variables)

PaigeMiller — Fri, 20 Feb 2026 15:40:02 GMT

Can you show us a screen capture of the problem?

Re: proc sgscatter display issues (for 18 variables)

SASdevAnneMarie — Fri, 20 Feb 2026 16:54:55 GMT

I attached the output.

Re: proc sgscatter display issues (for 18 variables)

Rick_SAS — Fri, 20 Feb 2026 16:55:40 GMT

Assuming that you want at least 200 pixels for each graph, a 1000x1000 plot can only hold 5 plots in each dimension. If you are trying to create a matrix that shows the pairwise scatter plot of 18 variables, you are only getting 55 pixels per plot, which is very small.

What are you hoping to see in this display, which is going to have 153 scatter plots? Depending upon your goals it might be better to plot subsets of your data instead of trying to see it all at once. For example, there are 10 numeric variables in the SASHELP.CARS data set. If I want to see how all variables are related to the MPG_CITY variable, I can create a big panel, but sometimes it is better to display multiple panels that each have 5-6 graphs, like this:

ods graphics / height=640px width=480px;
title "First group of vars";
proc sgscatter data=sashelp.cars;
  compare y=(MSRP Invoice EngineSize Cylinders Horsepower)
          x=(mpg_city);
run;

title "Second group of vars";
proc sgscatter data=sashelp.cars;
  compare y=(MPG_Highway Weight Wheelbase Length)
          x=(mpg_city);
run;

Re: proc sgscatter display issues (for 18 variables)

SASdevAnneMarie — Fri, 20 Feb 2026 17:41:40 GMT

Thank you, Rick,
I would like to examine the relationship shown by the scatter plot.

Re: proc sgscatter display issues (for 18 variables)

PaigeMiller — Fri, 20 Feb 2026 19:17:19 GMT

@SASdevAnneMarie wrote:

I would like to examine the relationship shown by the scatter plot.

As I mentioned in your earlier thread, perhaps Principal Components Analysis might be a better approach than 153 scatterplots.

Re: proc sgscatter display issues (for 18 variables)

Ksharp — Sat, 21 Feb 2026 03:02:58 GMT

If you want to output a PDF file ,you can use "options papersize=" to make this PDF bigger to fit this big graph.

data have;
call streaminit(123);
array x{*} var1-var20;
do obs=1 to 20;
  do i=1 to dim(x);
    x{i}=rand('normal');output;
  end;
end;
run;

ods _all_ close;
options papersize=(70cm 70cm);
ods pdf file='c:\temp\temp.pdf';
ods graphics /reset=all height=2500px width=2500px outputfmt=png;
proc sgscatter data=have;
  matrix var:/ diagonal=(histogram);
run;
ods pdf close;