topic Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10) in SAS Programming

modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

antor82 — Tue, 02 Dec 2025 15:01:50 GMT

Hi all

I attach the code and the resulting figure

proc sgplot data=aha.forest noautolegend nocycleattrs;
  styleattrs datasymbols=(squarefilled);
  scatter y=predictors x=or / xerrorupper=ucl xerrorlower=lcl group=grp;
  yaxistable or lcl ucl p / y=predictors location=inside position=right;
  refline 1 / axis=x noclip;
  xaxis type=log max=10 minor display=(nolabel)  valueattrs=(size=7) valuesformat=f2.0;
  yaxis display=(noticks nolabel)  fitpolicy=none reverse valueshalign=left
        colorbands=even colorbandsattrs=Graphdatadefault(transparency=0.8)  valueattrs=(size=7);
run;

I need to amplify the x axis around 1 (let's say from 1.01 to 1.1) and then restart with a log scale.

Can you help me please?

Tks in advance

Antonio

Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

quickbluefish — Tue, 02 Dec 2025 16:33:31 GMT

Are you saying you want the range 1.01 to 1.1 to be on a linear scale?

Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

FreelanceReinh — Tue, 02 Dec 2025 20:10:20 GMT

Hi @antor82,

Would it help to create a broken x-axis? Last week, @BrunoMueller posted a nice solution demonstrating how this can be done. Here's my attempt to adapt his code to your requirements:

/* Store repetitive code elements in macro variables */

%let plot=scatterplot x=or y=predictors / subpixel=off primary=true group=grp
          xerrorupper=ucl xerrorlower=lcl legendlabel="predictors" name="scatter";
%let xopts=type=log griddisplay=on display=(ticks tickvalues) tickvalueattrs=(size=7);
%let yopts=reverse=true labelfitpolicy=split tickvalueattrs=(size=7) tickvaluehalign=left type=discrete 
           discreteopts=(tickvaluefitpolicy=none colorbands=even
                         colorbandsattrs=graphdatadefault(transparency=0.8));

/* Create the GTL template with a manually broken x-axis */

proc template;
  define statgraph forest_break;
    begingraph / datasymbols=(squarefilled);
      /* the column weights determine the space available */
      layout lattice / columns=3 rowdatarange=union columnweights=(0.35 0.25 0.4) ;
        layout overlay / 
          xaxisopts=(&xopts logopts=(viewmin=0.6 viewmax=0.8
                                     minorticks=true tickvaluelist=(0.6 0.7 0.8)))
          yaxisopts=(display=(tickvalues line) &yopts)
          y2axisopts=(labelFitPolicy=Split);
          &plot;
        endlayout;
        layout overlay / 
          xaxisopts=(&xopts logopts=(viewmin=0.9 viewmax=1.11
                                     minorticks=true tickvaluelist=(0.9 0.95 1 1.05 1.1))
                     offsetmin=0.02)
          yaxisopts=(display=none &yopts);
          &plot;
          ReferenceLine x=1 / clip=false;
        endlayout;
        layout overlay / 
          xaxisopts=(&xopts logopts=(viewmin=1.16 viewmax=10
                                     minorticks=true tickvaluelist=(1.2 2 3 4 5 6 7 8 9 10))
                     offsetmin=0.0075)
          yaxisopts=(display=none &yopts);
          &plot;
          innermargin / align=right;
            axistable value=or  y=predictors / labelposition=min display=(label);
            axistable value=lcl y=predictors / labelposition=min display=(label);
            axistable value=ucl y=predictors / labelposition=min display=(label);
            axistable value=p   y=predictors / labelposition=min display=(label);
          endinnermargin;
        endlayout;
      endlayout;
    endgraph;
  end;
run;

/* Use the template to create the graph */

ods graphics / reset=all;

proc sgrender data=aha.forest template=forest_break;
run;

Result (omitting the titles for brevity):

(Note the spelling of the word "length".)

Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

quickbluefish — Tue, 02 Dec 2025 20:18:56 GMT

Wow, that's impressive.

Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

antor82 — Tue, 02 Dec 2025 20:47:00 GMT

Maybe on a linear scale I will need a very large image to account for a clear visibility…. A double scale (linear at the beginning and log thereafter) could be more effective but I've read that this is not possible. I’ve tried a linear scale with broken axes but that gave me a very narrowed first part of the graph without any increase in visibility

Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

antor82 — Wed, 03 Dec 2025 22:18:45 GMT

Thank You so much. This is an impressive improvement!!!

I've corrected the spelling in the original dataset (tks for Your attention!!!)

Unfortunately, I'm not able to:

1) keep the x-asix values in the format You posted (please refer to the attached figure for my mistake=too much decimals! and some values missing compared to Your figure)

2) put three titles inside the full image (as it was in my previously attached file).

Would You mind help me, please?

Sincerely

Antonio

Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

antor82 — Wed, 03 Dec 2025 22:49:58 GMT

I've put in the three titles (remembered how to do...😅). The problem of the x-axis values still stays inn...

Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

FreelanceReinh — Thu, 04 Dec 2025 08:29:21 GMT

You can specify a format for the tick values by adding the TICKVALUEFORMAT= option to the LOGOPTS= list of options. In my test dataset I had associated format 5.3 to variables OR, LCL and UCL. Therefore, had I specified tickvalueformat=data (which I did not), I would have got the unwanted three decimals that you see. In the absence of a permanent format, SAS would have used BEST6. as the default.

So, try to enforce that default:

/* Store repetitive code elements in macro variables */

%let plot=scatterplot x=or y=predictors / subpixel=off primary=true group=grp
          xerrorupper=ucl xerrorlower=lcl legendlabel="predictors" name="scatter";
%let xopts=type=log griddisplay=on display=(ticks tickvalues) tickvalueattrs=(size=7);
%let yopts=reverse=true labelfitpolicy=split tickvalueattrs=(size=7) tickvaluehalign=left type=discrete 
           discreteopts=(tickvaluefitpolicy=none colorbands=even
                         colorbandsattrs=graphdatadefault(transparency=0.8));

/* Create the GTL template with a manually broken x-axis */

proc template;
  define statgraph forest_break;
    begingraph / datasymbols=(squarefilled);
      /* the column weights determine the space available */
      layout lattice / columns=3 rowdatarange=union columnweights=(0.35 0.25 0.4) ;
        layout overlay / 
          xaxisopts=(&xopts logopts=(viewmin=0.6 viewmax=0.8
                                     minorticks=true tickvaluelist=(0.6 0.7 0.8)
                                     tickvalueformat=best6.))
          yaxisopts=(display=(tickvalues line) &yopts)
          y2axisopts=(labelFitPolicy=Split);
          &plot;
        endlayout;
        layout overlay / 
          xaxisopts=(&xopts logopts=(viewmin=0.9 viewmax=1.11
                                     minorticks=true tickvaluelist=(0.9 0.95 1 1.05 1.1)
                                     tickvalueformat=best6.)
                     offsetmin=0.02)
          yaxisopts=(display=none &yopts);
          &plot;
          ReferenceLine x=1 / clip=false;
        endlayout;
        layout overlay / 
          xaxisopts=(&xopts logopts=(viewmin=1.16 viewmax=10
                                     minorticks=true tickvaluelist=(1.2 2 3 4 5 6 7 8 9 10)
                                     tickvalueformat=best6.)
                     offsetmin=0.0075)
          yaxisopts=(display=none &yopts);
          &plot;
          innermargin / align=right;
            axistable value=or  y=predictors / labelposition=min display=(label);
            axistable value=lcl y=predictors / labelposition=min display=(label);
            axistable value=ucl y=predictors / labelposition=min display=(label);
            axistable value=p   y=predictors / labelposition=min display=(label);
          endinnermargin;
        endlayout;
      endlayout;
    endgraph;
  end;
run;

/* Use the template to create the graph */

ods graphics / reset=all;

proc sgrender data=aha.forest template=forest_break;
run;

Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

antor82 — Fri, 05 Dec 2025 09:44:52 GMT

Tks so much!!!!

Everything is working now!!!

Re: modify xaxis with different ranges (some very close to 1.xx and others from 1.5 to 10)

Quentin — Fri, 05 Dec 2025 13:18:33 GMT

Glad you got it working. Please mark @FreelanceReinh as the correct / accepted answer, to close out this question.