topic Re: Date format in SAS Programming

Date format

Mscarboncopy — Wed, 27 Aug 2025 20:56:47 GMT

Hello,

Is there a way to apply this date format without having multiple rows of the same statement below? I will have hundreds of different dates and I need them to have this format so that I can further work with them .

DATE ='27AUG25:09:00:00'dt;

ID DATE

1 27JUL25:09:00:00

2 05AUG25:10:00:00

3 15AUG25:08:00:00

4 20AUG25:11:30:00

...

Thanks!

Re: Date format

Cynthia_sas — Wed, 27 Aug 2025 21:45:23 GMT

Hi:

I'm not sure what you want. Remember that a SAS date value is stored internally as a number and a SAS date/time value is also stored internally as a number. The format that you show is only how the variable is displayed in output, such as reports. Without any format being applied, you can prove this to yourself by running this program:

That very large number that is stored internally represents the number of seconds between midnight on Jan 1 1960 and your date/time value. If you already have date/time variables stored in your data, then your assignment statement is NOT applying a format. If you want to apply a format to change the way your variable is displayed, you would use a FORMAT statement or for the PUTLOG statement, you can specify the format after the variable to be displayed in the log. Note the difference between a format with a width of 20 and the format with a width of 18 -- that will give you the 2 digit year you seem to want. Just remember that your assignment statement is NOT storing your date/time value in a readable format --your numeric date/time value is ALWAYS stored as a number.

Perhaps if you could explain a bit more about your data and what you need to do, it would be easier to understand why you think the assignment statement is necessary.

Cynthia

Re: Date format

Tom — Wed, 27 Aug 2025 23:16:42 GMT

There are two ways to produce that type of a listing.

If your variable named DATE has DATETIME values with the DATETIME format attached to it with a width between 16 and 18. NOTE: the DATETIME format has a bug and you must specify at width of at least 19 for it to actually print the 18 characters needed to display datetime value with 4 digit years.

data have;
  input id date :datetime.;
  format date datetime16.;
cards;
1 27JUL25:09:00:00 
2 05AUG25:10:00:00
3 15AUG25:08:00:00
4 20AUG25:11:30:00
;

But then I do not know what you are asking for help with since you already have the value as a datetime. If the variable is datetime already what is your actual question?

But perhaps instead you have the DATE variable defined as CHARACTER instead.

data have;
  input id date :$16.;
cards;
1 27JUL25:09:00:00 
2 05AUG25:10:00:00
3 15AUG25:08:00:00
4 20AUG25:11:30:00
;

Both of those will print the same way:

In that case to work with those values as actual datetime values you will need to first convert them. And you will need to make a new variable since the variable DATE is already defined as a character variable.

data want;
  set have;
  datetime = input(date,datetime24.);
  format datetime datetime19.;
run;

Result:

Note it does not matter if you have 4 observations or hundreds or millions the code is the same.

Re: Date format

Mscarboncopy — Thu, 28 Aug 2025 01:03:12 GMT

@Tom @Cynthia_sas Sorry, I should have added what I want to do with it.

I want to break the date var into several other vars (See outcome below).

It looks like I need the Date var to be formatted the way I asked in my previous message for this next part of my code to work.

proc format;

value dayofweek

1 = 'Sunday'

2 = 'Monday'

3 = 'Tuesday'

4 = 'Wednesday'

5 = 'Thursday'

6 = 'Friday'

7 = 'Saturday';

run;

data final;

set test;

dated = datepart(Date);

time = timepart(Date);

day_of_week = weekday(dated);

month = month(dated);

day = day(dated);

year = year(dated);

hour = hour(time);

minute = minute(time);

second = second(time);

format date date9.;

format time timeampm.;

format day_of_week dayofweek.;

run;

Result of this (showing only one obs)

dated time day_of_week month day year hour minute

27AUG2025

9:00:00 AM

Wednesday

2025

The idea here is to use these variables elsewhere to show the following:

Wednesday, August 27, 2025 9:00 AM

Aside from figuring out how to apply that format to hundreds of dates, I still need to:

1. label the Month to display the string not the numeric value 8 like I did for day_of_week.

2. remove the extra 00 in my time variable.

3. I do not need the hour and the minute vars but I created them just in case.

I do not know another way to achieve this output unless I format my Date var the way I showed.

My date variable is the long SAS number which I am converting to a date format (the one you see in my cards)

Thank you!

Re: Date format

Tom — Thu, 28 Aug 2025 01:26:52 GMT

Why do you need to make so many new variables?

Why not just apply different formats for different levels of granularity?

You can get very close to that desired output using a PICTURE format.

data have;
  input id date :datetime.;
  format date datetime16.;
cards;
1 27JUL25:09:00:00
2 05AUG25:10:00:00
3 15AUG25:08:00:00
4 20AUG25:21:30:00
;

/*
Wednesday, August 27, 2025 9:00 AM  
*/
proc format ;
 picture mydt (default=40)
 low-high= '%F, %C %d, %Y %H:%0M %p' (datatype=datetime);
;
run;

proc print data=have;
 format date mydt.;
run;

Result:

Obs    id                     date

 1      1     Sunday   , July      27, 2025 9:00 AM
 2      2     Tuesday  , August    5, 2025 10:00 AM
 3      3     Friday   , August    15, 2025 8:00 AM
 4      4    Wednesday, August    20, 2025 21:30 PM

You might want to run it though the COMPBL() function however.

data want;
  set have;
  string = left(compbl(put(date,mydt.)));
run;

Result

Obs    id                date                  string

 1      1    27JUL25:09:00:00    Sunday , July 27, 2025 9:00 AM
 2      2    05AUG25:10:00:00    Tuesday , August 5, 2025 10:00 AM
 3      3    15AUG25:08:00:00    Friday , August 15, 2025 8:00 AM
 4      4    20AUG25:21:30:00    Wednesday, August 20, 2025 21:30 PM

Might need to add a TRANWRD() function call also.

  string = tranwrd(left(compbl(put(date,mydt.))),' ,',',');

Re: Date format

Tom — Thu, 28 Aug 2025 01:55:01 GMT

Perhaps this is what you are trying to do?

First let's name you variable that has DATETIME values as DATETIME instead of DATE to avoid confusion in our example. And display it with 4 digit years for the same reason.

data have;
  input id datetime :datetime.;
  format datetime datetime19.;
cards;
1 27JUL25:09:00:00
2 05AUG25:10:00:00
3 15AUG25:08:00:00
4 20AUG25:21:30:00
;

Now we can make that complex string using the CATX() and PUT functions. It does make the code simpler to first make a variable with just the DATE (number of days since 1960).

data want;
  set have;
  length string $50;
  date=datepart(datetime);
  format date date9.;
  string = catx(', '
           ,put(date,downame.)
           ,catx(' ',put(date,monname.),day(date))
           ,put(datetime,timeampm.));
run;

Result

Obs    id               datetime                 string                      date

 1      1     27JUL2025:09:00:00    Sunday, July 27, 9:00:00 AM         27JUL2025
 2      2     05AUG2025:10:00:00    Tuesday, August 5, 10:00:00 AM      05AUG2025
 3      3     15AUG2025:08:00:00    Friday, August 15, 8:00:00 AM       15AUG2025
 4      4     20AUG2025:21:30:00    Wednesday, August 20, 9:30:00 PM    20AUG2025

Re: Date format

Ksharp — Thu, 28 Aug 2025 02:09:49 GMT

Tom,

There is a problem in your output, was it right ?

 1      1    27JUL25:09:00:00    Sunday , July 27, 2025 9:00 AM
 2      2    05AUG25:10:00:00    Tuesday , August 5, 2025 10:00 AM
 3      3    15AUG25:08:00:00    Friday , August 15, 2025 8:00 AM
 4      4    20AUG25:21:30:00    Wednesday, August 20, 2025 21:30 PM

Anyway , there is another way to get this format.


proc fcmp outlib=work.math.func;
function fmt(datetime) $;
length fmt $ 60;
fmt=catx(' ',put(datepart(datetime),weekdate32.),put(timepart(datetime),timeampm8.));
return (fmt);
endsub;
run;
options cmplib=work.math;
proc format;
value fmt(default=60)
other=[fmt()]
;
run;

data have;
  input id date :datetime.;
  format date fmt.;
cards;
1 27JUL25:09:00:00
2 05AUG25:10:00:00
3 15AUG25:08:00:00
4 20AUG25:21:30:00
;

proc print data=have;
run;

Re: Date format

Tom — Thu, 28 Aug 2025 11:08:55 GMT

Moved to new thread

Re: Date format

dxiao2017 — Wed, 03 Sep 2025 14:57:11 GMT

Hi @Mscarboncopy , maybe you already figured out the answer base on others' reply, but here is my version of code (mainly base on @Tom 's reply), and I think these are effective and efficient solution according to your request.

data dtfmt1;
   input ID DATE datetime16.;
   datedt16=date;
   format datedt16 datetime16.;
   datalines;
1 27JUL25:09:00:00 
2 05AUG25:10:00:00
3 15AUG25:08:00:00
4 20AUG25:11:30:00
;
run;
proc print data=dtfmt;run;
data dtfmt2(drop=date datedt16);
   set dtfmt1;
   dated=datepart(date);
   time=timepart(date);
   day_of_week=weekday(dated);
   month=month(dated);
   day=day(dated);
   year=year(dated);
   format dated date9.
          time timeampm8.
          day_of_week downame.
          month monname.;
run;
proc print data=dtfmt2;run;
proc format;
   picture mydt(default=40)
           low-high='%F,%c %d,%Y %H:%0M %p'
           (datatype=datetime);
run;
data dtfmt3;
   set dtfmt1;
   format date mydt.;
   datechar=put(date,mydt.);
run;
proc print data=dtfmt3;run;

And @Mscarboncopy , several techniques perhaps you would like to know: 1)if one wants to display a month's number in character month name, monname. format works, similarly, weekday() function returns a number, if one want to display the character weekday, downame. format works (and you do not need to use proc format 1='Monday' etc.), and I just learnt it from @Tom 's reply, 2) use timeampm8. format to reduce the 00:00:00 time format to 00:00, 3)if one would like to display date/time in a specific format, use picture format (and I copied this from @Tom 's reply), and if one would like to further convert it to character string, put(date/time, picfmt.) is the efficient way, and catx() is not a good way to do it because nested functions such as catx(catx()) is a bit too complicated and cost a lot of eyesight.

Re: Date format

Mscarboncopy — Mon, 06 Oct 2025 15:38:42 GMT

Hi @Tom Sorry it took me so long to get back to this. I used your suggestion and it worked. Thank you!!!

Now I am trying to find out how to use the same variable and create a date like this:

7/27/2025 9:00:00 AM

I think someone mentioned I could do this but using this part of the code what would I change to get 7/27/2025 9:00:00 AM using my first observation as an example: Thank you!!

length string $50;
  date=datepart(datetime);
  format date date9.;
  string = catx(', '
           ,put(date,downame.)
           ,catx(' ',put(date,monname.),day(date))
           ,put(datetime,timeampm.));

Re: Date format

Mscarboncopy — Mon, 06 Oct 2025 16:49:02 GMT

Thanks @dxiao2017 ! I did use Tom's suggestion.

I am now trying to use the same part of the code to create a string variable that shows the date as 7/27/2025 9:00:00 AM

It is probably a simple tweak but I am unsure how to make it work. See my question to Tom above.

Truly appreciate the help.

Re: Date format

Tom — Mon, 06 Oct 2025 17:47:11 GMT

It is not clear what you want to do as the code you posted does not match the example string you say you want to create. Why are you adding the month name if you don't want that?

Also do you really want to suppress the leading zeros in month number and day number?

If not then use the MMDDYY format to make the date string.

1    data test;
2      datetime=datetime();
3      format datetime datetime19. ;
4      length string $50;
5      string = catx(' ',put(datepart(datetime),mmddyys10.),put(datetime,timeampm.));
6      put (_all_) (=/);
7    run;


datetime=06OCT2025:13:41:54
string=10/06/2025 1:41:54 PM

If you do want to suppress the leading zeros then perhaps just use use the MONTH,DAY and YEAR functions?

data test;
  datetime=datetime();
  format datetime datetime19. ;
  length string $50;
  date=datepart(datetime);
  format date date9.;
  string = catx(' ',catx('/',month(date),day(date),year(date)),put(datetime,timeampm.));
  put (_all_) (=/);
run;

If you really want AM and PM in lowercase you could add the LOWCASE() function.

  string = catx(' ',catx('/',month(date),day(date),year(date)),lowcase(put(datetime,timeampm.)));

Results

string=10/6/2025 1:46:33 pm

Re: Date format

Mscarboncopy — Mon, 06 Oct 2025 18:59:35 GMT

Thank you @Tom The string is exactly what I needed - first example you gave me.

Much appreciated.