How to SGPLOT with varied line colors?!

hellohere — Tue, 09 Sep 2025 15:15:43 GMT

I need generate 3-by-2 plots, which the code below does. BUT also need let the lines are with varied colors.

There are GROUPLC= and styleattrs datacontrastcolors=(red green black orange blue cyan); BUT only for multiple lines within a single plot.

How to get 3-by-2 plots with controlled/varied colors?

Any other PROC is fine.

Thanks,

data _test;
do grp=1 to 6;
	do ind=1 to 100;
		yvalue=sin(ind/10)+grp;
		gx=grp;
		output;
	end;
end;
run;quit;

	ods layout gridded columns=3 rows=2 advance=bygroup;
	proc sgplot data=_test noautolegend uniform=xscale; 
	by grp;
	series x=ind y=yvalue / group=grp lineattrs=( thickness=2 pattern=solid) grouplc=grp ;     
	refline  30/axis=x lineattrs=(color=red thickness=2 pattern=solid); 
	run;
	ods layout end;

Re: How to SGPLOT with varied line colors?!

Ksharp — Wed, 10 Sep 2025 06:57:32 GMT

data _test;
do grp=1 to 6;
	do ind=1 to 100;
		yvalue=sin(ind/10)+grp;
		gx=grp;
		output;
	end;
end;
run;quit;



data dattrmap;
infile cards truncover;
input id $ value :$20. linecolor $  ;
datalines;
x  1  red 
x  2  blue 
x  3  green 
x  4  yellow 
x  5  purple 
x  6  black 
;
run;


	ods layout gridded columns=3 rows=2 advance=bygroup;
	proc sgplot data=_test noautolegend uniform=xscale dattrmap=dattrmap; 
	by grp;
	series x=ind y=yvalue / group=grp lineattrs=( thickness=2 pattern=solid) attrid=x  ;     
	refline  30/axis=x lineattrs=(color=red thickness=2 pattern=solid); 
	run;
	ods layout end;

topic Re: How to SGPLOT with varied line colors?! in SAS Programming

How to SGPLOT with varied line colors?!

Re: How to SGPLOT with varied line colors?!