topic change entrytitle inside model output in SAS Programming

change entrytitle inside model output

TimurShangareev — Mon, 01 Sep 2025 14:26:34 GMT

I used proc mixed to produce Studentized Residuals with model CHG =... CHG variable has label Change. But in output png file inner title (which placed in position, where usually template's entrytitle statement applied). So how I can change this entrytitle to Studentized Residuals for Change from Baseline?

Re: change entrytitle inside model output

FreelanceReinh — Mon, 01 Sep 2025 15:35:24 GMT

Hello @TimurShangareev,

Following Example 25.8 Changing Titles by Using the %GrTitle Macro from the SAS documentation I accomplished the change by inserting these two statements before the PROC MIXED step:

%grtitle(path=Stat.Mixed.Graphics.ResidualPanel)
%let Mixed_ResidualPanel = Studentized Residuals for Change from Baseline;

By deleting the above macro variable using

%symdel Mixed_ResidualPanel;

you can revert to the default title.

Re: change entrytitle inside model output

TimurShangareev — Tue, 02 Sep 2025 09:24:04 GMT

Can I set or customize proctitle for PROC SGRENDER/SGPLOT with this macro?

Re: change entrytitle inside model output

Ksharp — Thu, 04 Sep 2025 06:16:19 GMT

1)Try this:

CODE EDITED(try to make only one bookmarker).

ods document name=testAW(write);
proc sgplot data=sashelp.class;
scatter x=weight y=height/group=sex datalabel=name;
run;
ods document close;

proc document name=testAW;
list/ levels=all; run;
quit;


proc document name=testAW2(write);
setlabel \work.testAW\SGPlot#1\SGPlot#1 "Can I set or customize proctitle for PROC SGRENDER/SGPLOT";
copy \work.testAW\SGPlot#1\SGPlot#1 to ^;
run;

list/ levels=all; run;
quit;

title;
proc document name=work.testAW2;
ods pdf file="c:\temp\twolevels.pdf"  startpage=no ; * Save this graphic into a PDF file named twolevels.pdf;
replay ;
run;
ods pdf close;
quit;

2)Or try this:

ods pdf file='c:\temp\temp.pdf';
ods  proclabel='Can I set or customize proctitle for PROC SGRENDER/SGPLOT ';
proc sgplot data=sashelp.class;
scatter x=weight y=height/group=sex datalabel=name;
run;
ods pdf close;

Re: change entrytitle inside model output

FreelanceReinh — Wed, 03 Sep 2025 09:01:57 GMT

@TimurShangareev wrote:

Can I set or customize proctitle for PROC SGRENDER/SGPLOT with this macro?

I don't think so. Use Ksharp's suggestions for that purpose.