topic Re: sort datasets in SAS Programming

sort datasets

pavank — Thu, 28 Aug 2025 15:14:23 GMT

Hi Guys,

Good Evening

How to get sorted datasets and notsorted datasets list in a library

Re: sort datasets

Kathryn_SAS — Thu, 28 Aug 2025 15:58:56 GMT

I am not sure if this is what you are asking, but in the output data set from PROC CONTENTS there is a SORTED variable. It will have a value of 1 if the data set is sorted or missing (.) if it is not. Here is a simple example.

proc sort data=sashelp.class out=class;
by age;
run;

proc sort data=sashelp.cars out=cars;
by type;
run;

data test;
x=1;
run;

proc contents data=work._all_ noprint out=allds(keep=libname memname sorted);
run;

data allds;
set allds;
by libname memname;
if first.memname then output;
run;

proc print data=allds;
run;

Re: sort datasets

Quentin — Thu, 28 Aug 2025 16:02:05 GMT

Looks like you can pull this from dictionary.tables:

proc sql ;
  select memname, sortname, sorttype, sortchar
  from dictionary.tables 
  where libname="WORK" 
  ;
quit ;

See also this thread, which uses dictionary.columns :
https://communities.sas.com/t5/SAS-Programming/Keeping-the-defined-sortedby-values-in-the-metadata/td-p/823697