topic The ELSE statement in my Array overwriting original If statement in SAS Programming

The ELSE statement in my Array overwriting original If statement

aberkowitz — Wed, 27 Aug 2025 20:04:56 GMT

I am having an issue when using if-then-else in an array.

This is the code I want to use, but when it runs it seems to ignore the original if statement as you can see in the image there are individuals who have "Achieved" selected and the AchievedGoal variable is listed as "No".

data DSMESY2_test;

set DSMESY2;

array Ace ProblemSolving ReducingRisk BeingActive HealthyCoping HealthyEating Monitoring TakingMeds;

do over Ace;

if Ace = "Achieved" then AchievedGoal="Yes";

else AchievedGoal="No";

end;

run;

When I removed the "Else AchievedGoal="No"; statement, the array seems to work properly though.

data DSMESY2_test;

set DSMESY2;

array Ace ProblemSolving ReducingRisk BeingActive HealthyCoping HealthyEating Monitoring TakingMeds;

do over Ace;

if Ace = "Achieved" then AchievedGoal="Yes";

end;

run;

I have tried to trouble shoot this so many times and I can't figure out what is going on. I can do a work around for my reporting by doing a proc freq/missing, for the second code, but it is driving me crazy not knowing why the top code isn't working especially because I know I have used it with other datasets with now issue.

Re: The ELSE statement in my Array overwriting original If statement

Kurt_Bremser — Wed, 27 Aug 2025 20:16:02 GMT

The way you write your code, only the evaluation of the last array element will make it through.

Restructure your code:

AchievedGoal = "No";
do over Ace;
  if Ace = "Achieved" then AchievedGoal = "Yes";
end;

Re: The ELSE statement in my Array overwriting original If statement

Tom — Wed, 27 Aug 2025 20:17:46 GMT

You were almost there.

The pattern you want is something like:

AchievedGoal="No ";
do over Ace;
  if Ace = "Achieved" then AchievedGoal="Yes";
end;

You set the result to false before the loop. Then in the loop set it to true when the condition is met.

Re: The ELSE statement in my Array overwriting original If statement

aberkowitz — Wed, 27 Aug 2025 20:26:12 GMT

Thank you! That makes so much sense.

Re: The ELSE statement in my Array overwriting original If statement

FreelanceReinh — Wed, 27 Aug 2025 20:54:48 GMT

Another option would be to avoid the DO loop and just use the IN operator:

data DSMESY2_test;
set DSMESY2;
array Ace ProblemSolving ReducingRisk BeingActive HealthyCoping HealthyEating Monitoring TakingMeds;
if "Achieved" in Ace then AchievedGoal="Yes";
else AchievedGoal="No";
run;

Personally, I would prefer a numeric 0-1 coded variable AchievedGoal, which would also avoid the IF-THEN/ELSE statement:

AchievedGoal="Achieved" in Ace;

A format with labels "Yes", "No" could be attached if needed.

Re: The ELSE statement in my Array overwriting original If statement

Tom — Thu, 28 Aug 2025 14:47:45 GMT

Another way to deal with this is to use an iterative DO loop (instead of using the DO OVER syntax that SAS has been trying to eliminate). Then you can take advantage of the fact you can combine the iterative DO with an UNTIL() clause.

data DSMESY2_test;
  set DSMESY2;
  array Ace ProblemSolving ReducingRisk BeingActive HealthyCoping 
            HealthyEating Monitoring TakingMeds
  ;
  do index=1 to dim(Ace) until (AchievedGoal);
    AchievedGoal = (Ace[index]="Achieved");
  end;
  drop index;
run;