topic Re: ods output OneWayFreqs(match_all) in SAS Programming

ods output OneWayFreqs(match_all)

xxformat_com — Tue, 19 Aug 2025 09:53:28 GMT

Hi,

The table outputted by proc freq do not have the same structure i.e.

We have the variable NAME in the first table, SEX inthe second table, AGE in he third table...
We do not have two common variables in each table such as VARNAME and VARVALUE.

What would you suggest to have exactly the same variables in all the output datasets before appending them?

ods output OneWayFreqs(match_all)=demo;

proc freq data=sashelp.class nlevels;
    table _all_;
run;

data freq_all;
    set demo:;
run;

proc print data=freq_all;
run;

Thanks

Re: ods output OneWayFreqs(match_all)

FreelanceReinh — Tue, 19 Aug 2025 10:43:41 GMT

Hi @xxformat_com,

A common variable VARVALUE containing NAME and AGE values must be a character variable. This is what PROC TRANSPOSE creates when transposing from wide to long. Then you can apply PROC FREQ to the "long" dataset.

Example:

data tmp / view=tmp;
seqno=_n_;
set sashelp.class;
run;

proc transpose data=tmp name=varname out=long(drop=seqno rename=(col1=varvalue));
by seqno;
var name--weight;
run;

proc sort data=long;
by varname;
run;

proc freq data=long noprint;
by varname;
tables varvalue / out=want;
run;

Re: ods output OneWayFreqs(match_all)

Kathryn_SAS — Tue, 19 Aug 2025 11:10:11 GMT

PROC FREQ does not require that you use MATCH_ALL any more. I would suggest the following SAS Sample which creates one output data set and then reshapes it into a more readable format.

https://support.sas.com/kb/37/780.html

Re: ods output OneWayFreqs(match_all)

FreelanceReinh — Tue, 19 Aug 2025 13:41:55 GMT

One of the advantages of @Kathryn_SAS's solution is that (by virtue of the VVALUEX function) it would honor formats that are permanently associated with variables in the input dataset. My PROC TRANSPOSE approach would do so only for numeric variables (and it creates an additional dataset, albeit with optimized lengths of variables VARNAME and VARVALUE).