topic Re: Is there a simple way to add a prefix to all variables in a SAS dataset? in SAS Programming

Is there a simple way to add a prefix to all variables in a SAS dataset?

aamoen — Wed, 23 Jul 2025 15:30:02 GMT

Re: Is there a simple way to add a prefix to all variables in a SAS dataset?

Tom — Wed, 23 Jul 2025 15:44:25 GMT

Use the RENAME statement or RENAME= dataset option.

To get the list of old=new name pairs you will need to do some code generation.

If the number of variables is small enough you could build a single macro variable. For example by querying the DICTIONARY.COLUMNS metadata. Remember that LIBNAME and MEMNAME values are always in uppercase in that metadata.

proc sql noprint;
select catx('=',nliteral(name),nliteral(cats('prefix',name)))
  into :renames separated by ' '
  from dictionary.columns
  where libname='MYLIB' and memname='MYDS'
;
quit;

Then you could use this RENAMES macro variable to generate the RENAME statement.

For example by using PROC DATASETS to modify the existing dataset.

proc datasets lib=mylib nolist;
modify myds ;
  rename &renames;
run;
quit;

Or use it in a data step. Where you could also try using the RENAME= dataset option instead.

data want;
  set mylib.myds(rename=(&renames));
run;

Re: Is there a simple way to add a prefix to all variables in a SAS dataset?

ballardw — Wed, 23 Jul 2025 16:36:17 GMT

Why do you want a prefix added?

If you describe the use case we may come up with alternatives that may not require such.

Hint: if the purpose is to then add these variables to another data set and the prefix identifies a different set quite often that is not an optimal choice.

Re: Is there a simple way to add a prefix to all variables in a SAS dataset?

PaigeMiller — Wed, 23 Jul 2025 16:49:46 GMT

Your extremely brief problem description leaves me wondering if you want to add the prefix to the variable NAMES, or a prefix to the variable VALUES. You don't tell us. Which is it?

Also, if you are talking about variable NAMES, this could be a symptom of poor data layout or poor data arrangements, and it might be that re-arranging your data will eliminate the need to change variable names. Specifically, people create wide data sets with lots of somewhat repetitive variable names, except for a prefix or suffix; while a long data set eliminates the need for lots of variable names and eliminates the need for bulk renaming.

Which brings us to the main point I want to make. We need you to help us, which in turn helps you. We need much more detailed problem statement, and we need to know WHY you are doing this; once we know this we can come up with (possibly) a better approach that is easier to program, and get you to your final destination a lot faster than renaming would get you there. Please also take a few minutes and read up on the XY Problem as I think this is important and relevant in this case, and really in all cases; we need to know what you are doing and WHY you are doing it in all future posts as well.

Re: Is there a simple way to add a prefix to all variables in a SAS dataset?

aamoen — Wed, 23 Jul 2025 17:04:35 GMT

The goal is to add a prefix to the field names itself. Not to alter the values of any given field.

Re: Is there a simple way to add a prefix to all variables in a SAS dataset?

PaigeMiller — Wed, 23 Jul 2025 17:11:16 GMT

@aamoen wrote:

The goal is to add a prefix to the field names itself. Not to alter the values of any given field.

WHY? What is the ultimate goal of this project/analysis/data manipulation? Please describe the project.

Re: Is there a simple way to add a prefix to all variables in a SAS dataset?

data_null__ — Wed, 23 Jul 2025 17:19:59 GMT

The macro in this thread will allow you add a prefix to each name and much more.

https://communities.sas.com/t5/SAS-Programming/Rename-all-variables-in-a-dataset-at-once/m-p/722622#M224093