topic Re: add space between consecutive code in SAS Programming

add space between consecutive code

ballakaay — Sat, 14 Jun 2025 16:03:30 GMT

Hello,

I have a variable named "fac_code" which contains code delimited by space. However, there are some errors in code where there is no delimiter between code. The code starts with a letter and followed by some digits. I would like to fix it by adding space between codes. For example,

fac_code

K111I001 C01

A01B001

I want it to be

K111 I001 C01

A01 B001

I did something like

data a;

set a;

if prxmatch('/[A-Z](\d+)[A-Z](\d+)/)', fac_code)>0 then

fac_code_clean = catx(' ', char(fac_code,2)) but it does not work

Any help is appreciated! Thanks in advance

Re: add space between consecutive code

Kurt_Bremser — Sat, 14 Jun 2025 17:55:56 GMT

What is the plain language rule for adding blanks?

Re: add space between consecutive code

AhmedAl_Attar — Sat, 14 Jun 2025 19:21:25 GMT

Hi @ballakaay

Try this

data have;
length fac_code $20; /* Declare a length that allows adding spaces */
fac_code='K111I001 C01'; output;
fac_code='A01B001'; output;
run;

data want;
set have;
fac_code=compress(fac_code); /* Remove existing spaces */
RegularExpressionId = prxparse('s/\w\d{2,}/ $0/');
call prxchange(RegularExpressionId, -1, fac_code); /* Insert delimiting space */
fac_code=strip(fac_code);
put fac_code=;
run;

Re: add space between consecutive code

Ksharp — Sun, 15 Jun 2025 00:39:33 GMT

data have;
input x $80.;
cards;
K111I001 C01
A01B001
;

data want;
 set have;
 want=compbl(prxchange('s/([a-z]\d+)/\1 /i',-1,x));
run;

Re: add space between consecutive code

ChrisNZ — Sun, 15 Jun 2025 03:11:36 GMT

One way:

data HAVE;
  CODE='K111I001 C01 '; output;
  CODE='A01B001      '; output;
run;

data WANT;
  set HAVE;
  CODE = prxchange('s/(\d)([A-Z]\d*)/\1 \2/', -1, CODE); 
  putlog CODE=;
run;

CODE=K111 I001 C01

CODE=A01 B001

Re: add space between consecutive code

Amir — Sun, 15 Jun 2025 15:38:43 GMT

Hi,

Whilst you have already been provided with a number of solutions, I have tried to break down each part of the regular expression in the comments in the below data step:

data have;
  infile datalines truncover;
  input fac_code $char50.;
  datalines;
K111I001 C01
A01B001
;


data want(drop = substitute);
  /* define perl regular expression for substitution (assigned once in data step) */
  substitute = cat(
                   's/'      /* substitution specification start:       */
                  ,'(\d)'    /* replace any digit                       */
                  ,'([A-Z])' /* that is followed by an uppercase letter */
                  ,'/'       /* with                                    */
                  ,'$1'      /* the digit that was found                */
                  ,' '       /* followed by a new space character       */
                  ,'$2'      /* and the uppercase letter that was found */
                  ,'/'       /* substitution specification end          */
                  ,'o'       /* compile-once (i.e., not every obs)      */
                  );
  
  /* use Do-Whitlock to loop through obs */
  do until(last_obs);
    set have end = last_obs;
  
    fac_code_clean = prxchange(substitute, -1, fac_code);
    
    output;
  end;
  
  /* prevent unnecessary return to start of data step */
  stop;
run;

Thanks & kind regards,

Amir.

Re: add space between consecutive code

ballakaay — Fri, 11 Jul 2025 16:12:31 GMT

Thank you so much! That is exactly what I want