topic Re: transpose char vars in SAS Programming

transpose char vars

Ronein — Mon, 09 Jun 2025 06:31:22 GMT

Hello

Why data set want2 is empty?

I want to transpose char vars



proc sql noprint;
  select name into :Char_varlist separated by ' '
  from dictionary.columns
  where libname='SASHELP'
    and memname='CARS'
	and type='char'
  ;
quit;
%put  Char_varlist=&Char_varlist;

proc sql  noprint;
  select name into :num_varlist separated by ' '
  from dictionary.columns
  where libname='SASHELP'
    and memname='CARS'
	and type='num'
  ;
quit;
%put  num_varlist=&num_varlist;



data cars;
set SASHELP.CARS;
seq=_n_;
Run;

proc transpose data=cars (KEEP=seq  &num_varlist.) out=want1(drop=_label_ rename=(_name_=Var_name COL1=value));
by seq;
run;

proc transpose data=cars (KEEP=seq  &Char_varlist.) out=want2(drop=_label_ rename=(_name_=Var_name COL1=value));
by seq;
run;

Re: transpose char vars

Ronein — Mon, 09 Jun 2025 06:41:57 GMT

I found the answer!

Without a VAR statement only numeric variables are transposed.



proc sql noprint;
  select name into :Char_varlist separated by ' '
  from dictionary.columns
  where libname='SASHELP'
    and memname='CARS'
	and type='char'
  ;
quit;
%put  Char_varlist=&Char_varlist;

proc sql  noprint;
  select name into :num_varlist separated by ' '
  from dictionary.columns
  where libname='SASHELP'
    and memname='CARS'
	and type='num'
  ;
quit;
%put  num_varlist=&num_varlist;



data cars;
set SASHELP.CARS;
seq=_n_;
Run;

proc transpose data=cars (KEEP=seq  &num_varlist.) out=want1(drop=_label_ rename=(_name_=Var_name COL1=value));
by seq;
run;

proc transpose data=cars (KEEP=seq  &Char_varlist.) out=want2(drop=_label_ rename=(_name_=Var_name COL1=value));
by seq;
var &Char_varlist.;
run;

Re: transpose char vars

Tom — Mon, 09 Jun 2025 19:07:40 GMT

Without VAR statement PROC TRANSPOSE only transposes the NUMERIC variables.

Note that there are special variable list keywords you can use to list all of the character or numeric variables.

proc transpose data=cars name=Var_name
 out=char_vars(drop=_label_ rename=(COL1=char_value))
;
  by seq;
  var _character_ ;
run;
proc transpose data=cars name=Var_name
  out=num_vars(drop=_label_ rename=(COL1=num_value)
                where=(upcase(var_name) ne 'SEQ')
               )
;
  by seq;
  var _numeric_;
run;