topic Re: Thoughts and questions: why this kind of macro is so difficult to debug. in SAS Programming

Thoughts and questions: why this kind of macro is so difficult to debug.

dxiao2017 — Thu, 01 May 2025 16:18:56 GMT

The correct code is as follows. But I used almost an hour to figure it out and still have questions about it. (ps: I made these mistakes while doing the practice questions on page 285 in Macro1: essentials course notes pdf, that was a complex question.)

1) The correct code and results

%macro ctrylist(ctry1)/minoperator;
%let list1=AT AU CA CH;
%put &list1;
%if &ctry1 in &list1 %then %do;
   %put &ctry1;
%end;
%else %do;
   %put ERROR: &ctry1 is an invalid country code.;
   %put ERROR: Valid country codes include &list1.;
%end;
%mend ctrylist;
%ctrylist(AU);
%ctrylist(zz);

2) How I used almost an hour to make mistakes and correct it. At first I wrote something like this (I did not know what's wrong with my mind then and forgot to write the semicolon ; behind the two %put statements in the %else %do statement, also when debugging I kept ignore this obvious mistake and costed me a lot of time to figure out the problem):

%macro ctrylist(ctry1);
%let list1=AT AU CA CH;
%put &list1;
%if &ctry1 in &list1 %then %do;
   %put &ctry1;
%end;
%else %do;
   %put ERROR: &ctry1 is an invalid country code.
   %put ERROR: Valid country codes include &list1.
%end;
%mend ctrylist;
%ctrylist(AU);
%ctrylist(zz);

And I got error message like this:

I am not good at using error message to help debug, also did not pay attention to where did the error occur. The possible mistakes came into my mind were: 1) maybe the %if &ctry1 in &list1 statement has problem, maybe I should try a &list with commas that separate the values, and 2) maybe the first %put in the first %if %then statement is not necessary. Then I tried something like this:

%macro ctrylist2(ctry2);
%let list2='AT','AU','CA','CH';
%if &ctry2 in (&list2) %then %do;
   &ctry2;
%end;
%else %do;
   %put ERROR: &ctry2 is an invalid country code.
   %put ERROR: Valid country codes include &list2.
%end;
%mend ctrylist2;
%ctrylist(AU);
%ctrylist(zz);

And I got the same error message:

Then I did not know what to do. The only thing came into my mind was, maybe an option minoperator should be added (because in that section in the material there was content of minoperator), then I tried something like this:

%macro ctrylist2(ctry2)/minoperator;
%let list2='AT','AU','CA','CH';
%if &ctry2 in (&list2) %then %do;
   %put &ctry2;
%end;
%else %do;
   %put ERROR: &ctry2 is an invalid country code.
   %put ERROR: Valid country codes include &list2.
%end;
%mend ctrylist2;
%ctrylist(AU);
%ctrylist(zz);

And I got the exact same error message. I did not know why I kept ignore the obvious mistake that there was no semicolon ; after the two %put statements, I even did not put my eyesight at the two statements, like I kept ignore an obvious, major mistake intentionally. Then I think I cannot figure it out and was going to post the problem into this community. But right before I post the problem my attention and eyesight somehow switched to and see the mistake: I did not write semicolon ; after the two statements. And I corrected it.

3) What I learnt from the experience: a) do not in a hurry and too eager to find out what is wrong, just look into every details of the code, b)look at the error message, especially where does the error message occur, c) when writing complex macros, keep relax and keep attention focused and enjoy, do not rush. d) When writing macro, it is easy for me to forget the semicolon, or sometimes added unnecessary semicolon or put semicolon at wrong place, I made this mistake twice before, the scenario is like(I forget another example which use a %if %then and where statement in a data step, which has the similar usage of the semicolon, could anyone come up with a similar example, many thanks) this, for this incorrect code I should put the semicolon after the &&b&i right before run; statement and after the %end; statement:

data a;
   set %do i=1 to &sqlobs;
         &&b&i;
       %end;
run;

4) I still have questions about the codes:

a) do %if &ctry1 in &list1 and %if &ctry2 in (&list2) work the same way? I mean the syntax of the %if in statement, the first one does not need the brackets and the second one does need the brackets, isn't it?

%let list1=AT AU CA CH;
%put &list1;
%if &ctry1 in &list1 %then %do;
   %put &ctry1;
%end;

%let list2='AT','AU','CA','CH';
%if &ctry2 in (&list2) %then %do;
   %put &ctry2;
%end;

b) what does the minoperator options do? why do I need it after the macro name? Without it I got a similar error message (only without the error message about %put).

%macro ctrylist2(ctry2);
%let list2='AT','AU','CA','CH';
%if &ctry2 in (&list2) %then %do;
   %put &ctry2;
%end;
%else %do;
   %put ERROR: &ctry2 is an invalid country code.;
   %put ERROR: Valid country codes include &list2.;
%end;
%mend ctrylist2;
%ctrylist(AU);
%ctrylist(zz);

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

dxiao2017 — Thu, 01 May 2025 16:56:19 GMT

I forgot to say with this code (if I use %if &ctry1 in &list1 statement, with blank as the delimiter in the &list), I got different error message when I do not use minoperator option, does this mean whenever I use such a &list in my macro I have to add the minoperator option?

%macro ctrylist(ctry1);
%let list1=AT AU CA CH;
%put &list1;
%if &ctry1 in &list1 %then %do;
   %put &ctry1;
%end;
%else %do;
   %put ERROR: &ctry1 is an invalid country code.;
   %put ERROR: Valid country codes include &list1.;
%end;
%mend ctrylist;
%ctrylist(AU);
%ctrylist(zz);

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

svh — Thu, 01 May 2025 16:59:09 GMT

You need MINOPERATOR in order use IN with the macro language. Otherwise, the macro processor does not know what to do with it.

And in this case, you are calling a macro %ctrylist right after storing the macro %ctrylist2, so that will lead to an error:

%macro ctrylist2(ctry2);
%let list2='AT','AU','CA','CH';
%if &ctry2 in (&list2) %then %do;
   &ctry2;
%end;
%else %do;
   %put ERROR: &ctry2 is an invalid country code.
   %put ERROR: Valid country codes include &list2.
%end;
%mend ctrylist2;
%ctrylist(AU);
%ctrylist(zz);

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

PaigeMiller — Thu, 01 May 2025 17:36:40 GMT

A minor issue, however

%macro ctrylist2(ctry2);
%let list2='AT','AU','CA','CH';

it is unnecessary and potentially harmful to the proper operation of the code to put quotes around the country abbreviations. The commas are also unnecessary. I doubt your %ctrylist2 macro will work with the quotes there.

P.S.: Better to include the log as text in the window that appears when you click on the </> icon

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

Kurt_Bremser — Thu, 01 May 2025 21:10:39 GMT

You define a macro ctrylist2, but try to invoke ctrylist (no 2).

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

ballardw — Fri, 02 May 2025 04:00:45 GMT

@dxiao2017 wrote:

The correct code is as follows. But I used almost an hour to figure it out and still have questions about it. (ps: I made these mistakes while doing the practice questions on page 285 in Macro1: essentials course notes pdf, that was a complex question.)

I would say that stating "correct code" without any description of what the code is supposed to do does not help at all in why "debugging" might be difficult.

I would also add that quite often the biggest issue is unfamiliarity with the basic code needed to perform something. We get a fair number of questions on this forum asking to debug macro code only to find that the poster never had basic code working that would accomplish the desired task(s). The macro processor generates code. If you do not know what the code to generate should look like then macros are extremely difficult to program.

And a fair number of things asked about macros can be accomplished with no macro programming at all. Many of the "loop" type questions about macros can be solved with By group processing for example.

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

svh — Fri, 02 May 2025 14:07:35 GMT

And you can also do a lot of things in open code rather than with macros if you build a data step with CALL EXECUTE. Though I did not find that routine until AFTER I learned the macro language...

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

Tom — Fri, 02 May 2025 15:03:31 GMT

Message was too long for me, but I have a quick answer for the first thing.

@dxiao2017 wrote:

The correct code is as follows. But I used almost an hour to figure it out and still have questions about it. (ps: I made these mistakes while doing the practice questions on page 285 in Macro1: essentials course notes pdf, that was a complex question.)

1) The correct code and results
%macro ctrylist(ctry1)/minoperator;
%let list1=AT AU CA CH;
%put &list1;
%if &ctry1 in &list1 %then %do;
   %put &ctry1;
%end;
%else %do;
   %put ERROR: &ctry1 is an invalid country code.;
   %put ERROR: Valid country codes include &list1.;
%end;
%mend ctrylist;
%ctrylist(AU);
%ctrylist(zz);

You could use a pre-debugged macro for testing if values are valid, like this one:

https://github.com/sasutils/macros/blob/master/parmv.sas

Then developing your new macro is going to be easier.

%macro ctrylist(ctry1) ;
  %local parmerr;
  %parmv(ctry1,_val=AT AU CA CH)
  %if (&parmerr) %then %do;
      ... code to handle user entry errors ...
  %end;
  %else %do;
     ... code to actually do what you want ...
  %end;
%mend ctrylist;

Example:

 73         %macro ctrylist(ctry1) ;
 74           %local parmerr;
 75           %parmv(ctry1,_val=AT AU CA CH)
 76           %if (&parmerr) %then %do;
 77               %put ... code to handle user entry errors ... ;
 78           %end;
 79           %else %do;
 80              %put &=ctry1 ;
 81              %put ... code to actually do what you want ...;
 82           %end;
 83         %mend ctrylist;
 84         
 85         %ctrylist(AT)
 CTRY1=AT
 ... code to actually do what you want ...
 86         %ctrylist(ca)
 CTRY1=CA
 ... code to actually do what you want ...
 87         %ctrylist(zz)
  
 ERROR: Macro CTRYLIST user error.
 ERROR: ZZ is not a valid value for the CTRY1 parameter.
 ERROR: Allowable values are: AT AU CA CH.
 ... code to handle user entry errors ...
 88         %ctrylist(or)
  
 ERROR: Macro CTRYLIST user error.
 ERROR: OR is not a valid value for the CTRY1 parameter.
 ERROR: Allowable values are: AT AU CA CH.
 ... code to handle user entry errors ...

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

dxiao2017 — Sat, 03 May 2025 13:06:50 GMT

Hi Paige thanks a lot for reply! It's not a minor issue for me, it is where I make mistakes, thanks a lot for telling me this! The code in my previous thread was a little messed up because while debugging, I messed up the three macros %ctrylist, %ctrylist1, %ctrylist2 when test them. Today I tried both (with commas and quotes and without), the code and results are as follows:

%macro ctrylist2(ctry2)/minoperator;
%let list2='AT','AU','CA','CH';
%if &ctry2 in (&list2) %then %do;
   %put &ctry2;
%end;
%else %do;
   %put ERROR: &ctry2 is an invalid country code.;
   %put ERROR: Valid country codes include &list2.;
%end;
%mend ctrylist2;
%ctrylist2(AU);
%ctrylist2(zz);

69         %macro ctrylist2(ctry2)/minoperator;
 70         %let list2='AT','AU','CA','CH';
 71         %if &ctry2 in (&list2) %then %do;
 72            %put &ctry2;
 73         %end;
 74         %else %do;
 75            %put ERROR: &ctry2 is an invalid country code.;
 76            %put ERROR: Valid country codes include &list2.;
 77         %end;
 78         %mend ctrylist2;
 79         %ctrylist2(AU);
 ERROR: AU is an invalid country code.
 ERROR: Valid country codes include 'AT','AU','CA','CH'
 80         %ctrylist2(zz);
 ERROR: zz is an invalid country code.
 ERROR: Valid country codes include 'AT','AU','CA','CH'

%macro ctrylist1(ctry1)/minoperator;
%let list1=AT AU CA CH;
%put &list1;
%if &ctry1 in &list1 %then %do;
   %put &ctry1;
%end;
%else %do;
   %put ERROR: &ctry1 is an invalid country code.;
   %put ERROR: Valid country codes include &list1..;
%end;
%mend ctrylist1;
%ctrylist1(AU);
%ctrylist1(zz);

 69         %macro ctrylist1(ctry1)/minoperator;
 70         %let list1=AT AU CA CH;
 71         %put &list1;
 72         %if &ctry1 in &list1 %then %do;
 73            %put &ctry1;
 74         %end;
 75         %else %do;
 76            %put ERROR: &ctry1 is an invalid country code.;
 77            %put ERROR: Valid country codes include &list1..;
 78         %end;
 79         %mend ctrylist1;
 80         %ctrylist1(AU);
 AT AU CA CH
 AU
 81         %ctrylist1(zz);
 AT AU CA CH
 ERROR: zz is an invalid country code.
 ERROR: Valid country codes include AT AU CA CH.

You are right about that the one with commas and quotes actually did not work. So this answers my question of the correct syntax of creating a &list to be used in a macro in a %if %then statement, that is, do not include any commas and quotes in the &list (i.e, use blank as delimiter among the values), and when resolve it in a %if %then statement, write it this way (do not need brackets here): %if &name in &list %then %do;. @PaigeMiller , am I right about this? Thank you!

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

dxiao2017 — Sat, 03 May 2025 13:47:28 GMT

Hi @svh thanks a lot for reply! Through the link you provide I have downloaded the material about macro for further learning. However, for the explanations about minoperator, I still do not understand. In the materials I can find so far, the descriptions are similar:

1) descriptions in SAS 9.4 guide (built in documentation): "specifies that the macro processor recognizes and evaluates the mnemonic IN and the special character # as logical operators when evaluating arithmetic or logical expressions during the execution of the macro".

2) descriptions in SAS Macro1: essentials course notes: "A null value cannot be provided in the list of values after the macro IN operator. Null values must be processed first with a separate %if condition. to enable the macro IN operator, add the MINOPERATOR options".

3) descriptions in SAS(R) 9.2 Macro Language Reference (the material on the link you provide): "causes the macro processor to recognize the evaluate both the mnemonic operator In or the special character # as a logical operator in expressions".

So far my understanding is like this: whenever I use a macro &list or do some arithmetic calculation inside a macro, if my macro does not run through and other syntax is correct, I need to add this minoperator to see if it solves problem. @svh am I right about this, thanks a lot!

And you are right about I was "calling a macro %ctrylist right after storing the macro %ctrylist2", I messed up the two macros myself while debugging and test them😅.

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

dxiao2017 — Sat, 03 May 2025 13:55:54 GMT

Hi @Kurt_Bremser thanks a lot for reply! You are right😃, I made several mistakes(also without knowing what were the mistakes) when writing macro ctrylist, and then I wrote ctrylist1 and ctrylist2 to help debug and find out what's wrong, and then I messed up the three macros when test them 😃.

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

Tom — Sat, 03 May 2025 15:15:01 GMT

First point. MINOPERATOR and MINDELIMITER are the system options to control WHETHER you can use IN as an operator in macro code and if you do WHAT character is used to delimit the items in the list.

When writing a macro you would normally want to use the MINOPERATOR and MINDELIMITER options of the %MACRO statement to enable the IN operator and set the delimiter your macro expects. Otherwise the macro will behave differently depending on the setting of the system options with those same names.

Your point number 2 is explaining about what constitutes a valid use of the IN operator. Basically it is just saying you cannot test if something is in nothing and you cannot test if nothing is in a list.

 1          options minoperator mindelimiter=' ';
 2          %put %eval(x in a b c);
 0
 3          %put %eval(a in a b c);
 1
 4          %put %eval(x in );
 ERROR: Operand missing for IN operator in argument to %EVAL function.
  
 5          %put %eval( in a b c);
 ERROR: Operand missing for IN operator in argument to %EVAL function.

Just because you have list of values does not imply that you NEED to use the IN operator. Just like with other things there are other ways to do things. You could use FINDW() function for example. (Note it is hard to use %SYSFUNC() to call the FINDW() function and use only space as the delimiter.)

 6          %put %eval(0<%sysfunc(findw(a b c,x,/,st)));
 0
 7          %put %eval(0<%sysfunc(findw(a b c,a,/,st)));
 1

Note that the FINDW() function does not mind empty arguments. The result is FALSE.

 8          %put %eval(0<%sysfunc(findw(,x,|,st)));
 0
 9          %put %eval(0<%sysfunc(findw(a b c,,|,st)));
 0

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

PaigeMiller — Sat, 03 May 2025 15:49:53 GMT

In general, you do not use quotes to surround text in the macro variable value. In general, quotes here are problematic and can make the logic fail.

%let list=AU CH AT UR;

is the proper way to do this. If the macro is fed an argument which is AU, then this matches the first "word" of &LIST; in other words, AU (which is the argument of the macro) is an exact match to AU (the first "word" in &LIST).

If you use quotes

%let list='AU' 'CH' 'AT' 'UR';

and the macro is fed an argument such as AU without the quotes, then there is no match. Why? Because the text string AU does not match the text in &LIST which is 'AU' in quotes.

AU (a 2 character text string) does not match 'AU' (a four character text string).

So leave the quotes out of the macro variable value in almost all situations.

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

Astounding — Sun, 04 May 2025 16:48:49 GMT

Does the original question insist on using the IN operator? It would be mildly simpler to use %INDEX:

%macro ctrylist(ctry1);
%let list1=AT AU CA CH;
%put &list1;
%if %index(&list1, &ctry1) %then %do;
   %put &ctry1;
%end;
%else %do;
   %put ERROR: &ctry1 is an invalid country code.;
   %put ERROR: Valid country codes include &list1..;
%end;
%mend ctrylist;
%ctrylist(AU)
%ctrylist(zz)

In general, if you start with simpler tools, adding the complexity of macro language can produce a simpler result.

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

PaigeMiller — Mon, 05 May 2025 12:00:40 GMT

Related to the original question, there is also the %INM macro which may be of use, and is a lot less typing than creating your own macro to find matches in a text string.

%macro inm(slist,s);
    /* SAS Macro %inm to see if &s is contained in a string or list &slist                 */
    /* Borrowed from https://groups.google.com/forum/#!topic/comp.soft-sys.sas/fWcSDgg11tE */
    %if %sysfunc(indexw(&slist,&s)) gt 0 %then 1 ;
    %else 0;
%mend;

The output of the macro is a 1 indicating a match, or a zero indicates no match.

Example of use:

%let countrylist=AU AT CH;
%let thiscountry=AT;
%if %inm(&countrylist,&thiscountry) %then %do;
    %put This country is &thiscountry, Match found;
%end;
%let thiscountry=RP;
%if not %inm(&countrylist,&thiscountry) %then %do;
    %put This country is &thiscountry, Match not found;
%end;

Sometimes (most times?) asking here in the forum if there is a macro to perform your task is a good first step, rather than just going ahead and trying to write the macro yourself.

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

dxiao2017 — Tue, 06 May 2025 16:49:16 GMT

Hi @ballardw thanks very much for your comments, it's a very good question which makes me explore and learn more.

Part of the purpose of the macro in the practice question I mentioned on page 285, Macro Essential1: course note pdf, is like this: 1) using proc sql to generate a country code &list from a dataset, and 2) if the macro parameter value (i.e., the country code) is among the &list then produce a plot, otherwise put an error message. The first time I did that question I made several mistakes and the macro did not work. Then I simplified the code by create a macro through %let list=; instead of using proc sql and made it worked (as you can see from this post). However, today, I run that part of code using the &list produced through proc sql, it did not work again, the code I tried is as follows:

%macro customerlist(ctry)/minoperator;
proc sql noprint;
select distinct country
   into :ctrylist separated by " "
   from mc1.customers;
quit;
%if &ctry in &ctrylist %then %do;
   title "customers from &ctry";
   proc sgplot data=mc1.customers;
      vbar group;
      yaxis grid;
      where country="&ctry";
   run;
%end;
%else %do;
   %put ERROR: &ctry is an invalid country code.;
   %put ERROR: Valid country codes include &ctrylist..;
%end;
%mend customerlist;
%customerlist(AU);
%customerlist(zz);

The %customerlist(AU) worked well, which produced a plot, but the %customerlist(zz) did not work and there was no error message in the log:

 69         %macro customerlist(ctry)/minoperator;
 70         proc sql noprint;
 71         select distinct country
 72            into :ctrylist separated by " "
 73            from mc1.customers;
 74         quit;
 75         %if &ctry in &ctrylist %then %do;
 76            title "customers from &ctry";
 77            proc sgplot data=mc1.customers;
 78               vbar group;
 79               yaxis grid;
 80               where country="&ctry";
 81            run;
 82         %end;
 83         %else %do;
 84            %put ERROR: &ctry is an invalid country code.;
 85            %put ERROR: Valid country codes include &ctrylist..;
 86         %end;
 87         %mend customerlist;
 88         %customerlist(AU);
NOTE: PROCEDURE SGPLOT used (Total process time):
NOTE: There were 90 observations read from the data set MC1.CUSTOMERS.
       WHERE country='AU';
 89         %customerlist(zz);
 NOTE: PROCEDURE SQL used (Total process time):
NOTE: PROCEDURE SGPLOT used (Total process time):

I did not know why the &list created through %let list=; statement worked but the &list created through proc sql did not work. And in fact another technique that practice question to introduce is the usage of %superq(). I omitted that part because I thought it was too advanced for me and will leave it later. Then I think the reason the macro did not work was I did not use %superq(). After I added it the macro worked, the code and log is as follows:

%macro customerlist(ctry)/minoperator;
proc sql noprint;
select distinct country
   into :ctrylist separated by " "
   from mc1.customers;
quit;
%if %superq(ctry) in %superq(ctrylist) %then %do;
   title "customers from &ctry";
   proc sgplot data=mc1.customers;
      vbar group;
      yaxis grid;
      where country="&ctry";
   run;
%end;
%else %do;
   %put ERROR: &ctry is an invalid country code.;
   %put ERROR: Valid country codes include &ctrylist..;
%end;
%mend customerlist;
%customerlist(AU);
%customerlist(zz);

 69         %macro customerlist(ctry)/minoperator;
 70         proc sql noprint;
 71         select distinct country
 72            into :ctrylist separated by " "
 73            from mc1.customers;
 74         quit;
 75         %if %superq(ctry) in %superq(ctrylist) %then %do;
 76            title "customers from &ctry";
 77            proc sgplot data=mc1.customers;
 78               vbar group;
 79               yaxis grid;
 80               where country="&ctry";
 81            run;
 82         %end;
 83         %else %do;
 84            %put ERROR: &ctry is an invalid country code.;
 85            %put ERROR: Valid country codes include &ctrylist..;
 86         %end;
 87         %mend customerlist;
 88         %customerlist(AU);
 NOTE: PROCEDURE SQL used (Total process time):
 69         %macro customerlist(ctry)/minoperator;
 70         proc sql noprint;
 71         select distinct country
 72            into :ctrylist separated by " "
 73            from mc1.customers;
 74         quit;
 75         %if %superq(ctry) in %superq(ctrylist) %then %do;
 76            title "customers from &ctry";
 77            proc sgplot data=mc1.customers;
 78               vbar group;
 79               yaxis grid;
 80               where country="&ctry";
 81            run;
 82         %end;
 83         %else %do;
 84            %put ERROR: &ctry is an invalid country code.;
 85            %put ERROR: Valid country codes include &ctrylist..;
 86         %end;
 87         %mend customerlist;
 88         %customerlist(AU);
 NOTE: PROCEDURE SQL used (Total process time):
 NOTE: PROCEDURE SGPLOT used (Total process time):
 NOTE: There were 90 observations read from the data set MC1.CUSTOMERS.
       WHERE country='AU';
 89         %customerlist(zz);
 ERROR: zz is an invalid country code.
 ERROR: Valid country codes include AT AU BE CA CH CI DE DK EG ES FI FR GB GR HR IE IL IN 
 IT LT LU MZ NL NO NZ PL PT SE SI TR US YU ZA.

It's a very brilliant point you said that "the macro processor generates code" and before writing a macro one should know what the code generated look like. I compared the log using macro debug options for the %let list=; macro and the proc sql &list macro, the logs are as follows. Without %superq(), SAS executed the proc sgplot step, whereas with the %superq(), SAS excuted the %put ERROR message step (see the part marked in red).

 69         %macro customerlist(ctry)/minoperator;
 70         proc sql noprint;
 71         select distinct country
 72            into :ctrylist separated by " "
 73            from mc1.customers;
 74         quit;
 75         %if &ctry in &ctrylist %then %do;
 76            title "customers from &ctry";
 77            proc sgplot data=mc1.customers;
 78               vbar group;
 79               yaxis grid;
 80               where country="&ctry";
 81            run;
 82         %end;
 83         %else %do;
 84            %put ERROR: &ctry is an invalid country code.;
 85            %put ERROR: Valid country codes include &ctrylist..;
 86         %end;
 87         %mend customerlist;
 88         /*%customerlist(AU);*/
 89         options symbolgen mprint mlogic;
 90         %customerlist(zz);
 MLOGIC(CUSTOMERLIST):  Beginning execution.
 MLOGIC(CUSTOMERLIST):  Parameter CTRY has value zz
 MPRINT(CUSTOMERLIST):   proc sql noprint;
 MPRINT(CUSTOMERLIST):   select distinct country into :ctrylist separated by " " from mc1.customers;
 MPRINT(CUSTOMERLIST):   quit;

 SYMBOLGEN:  Macro variable CTRY resolves to zz
 SYMBOLGEN:  Macro variable CTRYLIST resolves to AT AU BE CA CH CI DE DK EG ES FI FR GB GR HR IE IL IN 
 IT LT LU MZ NL NO NZ PL PT SE SI TR US YU ZA
 MLOGIC(CUSTOMERLIST):  %IF condition &ctry in &ctrylist is TRUE
 SYMBOLGEN:  Macro variable CTRY resolves to zz
 MPRINT(CUSTOMERLIST):   title "customers from zz";
 MPRINT(CUSTOMERLIST):   proc sgplot data=mc1.customers;
 MPRINT(CUSTOMERLIST):   vbar group;
 MPRINT(CUSTOMERLIST):   yaxis grid;
 SYMBOLGEN:  Macro variable CTRY resolves to zz
 MPRINT(CUSTOMERLIST):   where country="zz";
 MPRINT(CUSTOMERLIST):   run;

 MLOGIC(CUSTOMERLIST):  Ending execution.
 91         options nosymbolgen nomprint nomlogic;

 69         %macro customerlist(ctry)/minoperator;
 70         proc sql noprint;
 71         select distinct country
 72            into :ctrylist separated by " "
 73            from mc1.customers;
 74         quit;
 75         %if %superq(ctry) in %superq(ctrylist) %then %do;
 76            title "customers from &ctry";
 77            proc sgplot data=mc1.customers;
 78               vbar group;
 79               yaxis grid;
 80               where country="&ctry";
 81            run;
 82         %end;
 83         %else %do;
 84            %put ERROR: &ctry is an invalid country code.;
 85            %put ERROR: Valid country codes include &ctrylist..;
 86         %end;
 87         %mend customerlist;
 88         /*%customerlist(AU);*/
 89         options symbolgen mprint mlogic;
 90         %customerlist(zz);
 MLOGIC(CUSTOMERLIST):  Beginning execution.
 MLOGIC(CUSTOMERLIST):  Parameter CTRY has value zz
 MPRINT(CUSTOMERLIST):   proc sql noprint;
 MPRINT(CUSTOMERLIST):   select distinct country into :ctrylist separated by " " from mc1.customers;
 MPRINT(CUSTOMERLIST):   quit;

 MLOGIC(CUSTOMERLIST):  %IF condition %superq(ctry) in %superq(ctrylist) is FALSE
 MLOGIC(CUSTOMERLIST):  %PUT ERROR: &ctry is an invalid country code.
 SYMBOLGEN:  Macro variable CTRY resolves to zz
 ERROR: zz is an invalid country code.
 MLOGIC(CUSTOMERLIST):  %PUT ERROR: Valid country codes include &ctrylist..
 SYMBOLGEN:  Macro variable CTRYLIST resolves to AT AU BE CA CH CI DE DK EG ES FI FR GB GR HR IE IL IN IT 
 LT LU MZ NL NO NZ PL PT SE SI TR US YU ZA
 ERROR: Valid country codes include AT AU BE CA CH CI DE DK EG ES FI FR GB GR HR IE IL IN IT LT LU MZ NL 
 NO NZ PL PT SE SI TR US YU ZA.
 MLOGIC(CUSTOMERLIST):  Ending execution.
 91         options nosymbolgen nomprint nomlogic;

I agree with you that many of the "loop" type questions about macro can be solved with by group processing, but here according to my understanding so far, I do not think the requirements can be processed through by group, in that the error message cannot be generated through by group processing.

Thanks very much @ballardw again for your valuable input, which enables me learnt more!

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

dxiao2017 — Tue, 06 May 2025 16:58:07 GMT

Hi @svh thanks a lot for telling this! I have not learnt much about CALL EXECUTE yet, but from your comments I can see that when I am thinking write a macro to solve the problem, maybe I can consider use some CALL EXECUTE first. I will learn to use CALL EXECUTE more later on!

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

dxiao2017 — Wed, 07 May 2025 18:40:37 GMT

Hi @Tom although I cannot access github, thanks a lot for telling me this!

So the pre-debugged macro you mentioned was to use the &parmerr combined with the %parmv (which has two parameters, one is the parameter of the outside macro such as ctry1, the other is the list of values such as _val=AT AU CA CH), if the condition of &parmerr is matched then put error message, if not then execute the code to produce what I want. Does this pre-debugged macro need to be downloaded from github? Does SAS has any built-in macro or options (I guess not‌‌😀) I can use for macro debugging (aside from the handy and simple options such as mlogic, mprint, and symbolgen) or options like validate in proc sql (in fact I personally do not think using validate helps much because when there is syntax error the log will give me error message even if I do not use validate, but at least when my syntax is ok it helps confirm that I do not have syntax error. On the other hand, in fact, when my code does not run through, I am more inclined to inspect all the details of the code by myself, as using extra tools sometimes make things more complex):

 69         proc sql number;
 70         validate
 71         select make,origin,msrp
 72            from sashelp.cars
 73            where msrp<(select mean(msrp)+2*std(msrp)
 74                         from sashelp.cars);
 NOTE: PROC SQL statement has valid syntax.
 75         quit;

 76         proc sql number;
 77         validate
 78         select make,origin,msrp
 79            from sashelp.cars
 80            where msrp<(select mean(msrp)+2*std(msrp)
 81                         from sashelp.cars;
                                             _
                                             79
 ERROR 79-322: Expecting a ).
 
 NOTE: PROC SQL set option NOEXEC and will continue to check the syntax of statements.
 81                                           )
                                              _
                                              180
 ERROR 180-322: Statement is not valid or it is used out of proper order.
 
 82         quit;
 NOTE: The SAS System stopped processing this step because of errors.

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

Tom — Thu, 08 May 2025 03:06:08 GMT

Validation of the inputs to your macro program has little to do with whatever that SQL VALIDATE statement does. They just happen to be using the same verb, which is a common issue with computer terminology which picks (sometimes seemingly random) words and gives them special meanings.

I would assume that the VALIDATE statement you played with in SQL is of some value to someone that is writing code that programmatically generates SQL statements and wants to test if the generated syntax is valid before actually running them. But that is not something I have ever needed to do.

You can go look at the PARMV macro in GITHUB on some other computer (or your phone for that matter). Read the header to see if what it can do for you has any value for you now (or perhaps in the future for some other project.)

To learn more about how to COMPILE a macro definition so that you can use it in your program check the SAS documentation. You might want to look at the section on autocall macro libraries.

Re: Thoughts and questions: why this kind of macro is so difficult to debug.

dxiao2017 — Fri, 09 May 2025 16:50:56 GMT

Hi @Astounding thanks very much for telling me the usage of %index😀, I tested it on the code and it works brightly😀, saves a lot of headache😀. The materials did not insist on using IN operator, it was to let leaners practice the usage of MINOPERATOR. But I'll just use %index(&valuelist,&parametervalue) from now on, it's handy and simple. The code I tested is as follows:

%macro customerlist(ctry)/minoperator;
proc sql noprint;
select distinct country
   into :ctrylist separated by " "
   from mc1.customers;
quit;
%if %index(&ctrylist,&ctry) %then %do;
   title "customers from &ctry";
   proc sgplot data=mc1.customers;
      vbar group;
      yaxis grid;
      where country="&ctry";
   run;
%end;
%else %do;
   %put ERROR: &ctry is an invalid country code.;
   %put ERROR: Valid country codes include &ctrylist..;
%end;
%mend customerlist;
%customerlist(AU);
options symbolgen mprint mlogic;
%customerlist(zz);
options nosymbolgen nomprint nomlogic;

 71         %macro customerlist(ctry)/minoperator;
 72         proc sql noprint;
 73         select distinct country
 74            into :ctrylist separated by " "
 75            from mc1.customers;
 76         quit;
 77         %if %index(&ctrylist,&ctry) %then %do;
 78            title "customers from &ctry";
 79            proc sgplot data=mc1.customers;
 80               vbar group;
 81               yaxis grid;
 82               where country="&ctry";
 83            run;
 84         %end;
 85         %else %do;
 86            %put ERROR: &ctry is an invalid country code.;
 87            %put ERROR: Valid country codes include &ctrylist..;
 88         %end;
 89         %mend customerlist;
 90         %customerlist(AU);

 91         options symbolgen mprint mlogic;
 92         %customerlist(zz);
 MLOGIC(CUSTOMERLIST):  Beginning execution.
 MLOGIC(CUSTOMERLIST):  Parameter CTRY has value zz
 MPRINT(CUSTOMERLIST):   proc sql noprint;
 MPRINT(CUSTOMERLIST):   select distinct country into :ctrylist separated by " " 
 from mc1.customers;
 MPRINT(CUSTOMERLIST):   quit;

 SYMBOLGEN:  Macro variable CTRYLIST resolves to AT AU BE CA CH CI DE DK EG ES FI FR GB GR HR IE IL IN 
 IT LT LU MZ NL NO NZ PL PT SE SI TR US YU ZA
 SYMBOLGEN:  Macro variable CTRY resolves to zz
 MLOGIC(CUSTOMERLIST):  %IF condition %index(&ctrylist,&ctry) is FALSE
 MLOGIC(CUSTOMERLIST):  %PUT ERROR: &ctry is an invalid country code.
 SYMBOLGEN:  Macro variable CTRY resolves to zz
 ERROR: zz is an invalid country code.
 MLOGIC(CUSTOMERLIST):  %PUT ERROR: Valid country codes include &ctrylist..
 SYMBOLGEN:  Macro variable CTRYLIST resolves to AT AU BE CA CH CI DE DK EG ES FI FR GB GR HR IE IL 
 IN IT LT LU MZ NL NO NZ PL PT SE SI TR US YU ZA
 ERROR: Valid country codes include AT AU BE CA CH CI DE DK EG ES FI FR GB GR HR IE IL IN IT LT LU MZ 
 NL NO NZ PL PT SE SI TR US YU ZA.
 MLOGIC(CUSTOMERLIST):  Ending execution.
 93         options nosymbolgen nomprint nomlogic;