topic Re: Spanning Header Beneath Labels - proc report in SAS Programming

Spanning Header Beneath Labels - proc report

_Hopper — Fri, 21 Mar 2025 17:07:52 GMT

My base code is this:

data cars;

set sashelp.cars;

run;

ods rtf file = "C:\Users\XYZODQ\test.rtf" style = beaconrtf;

proc report data = cars;

column ("~S={borderbottomcolor=black borderbottomwidth=2}Parameter" make model) drivetrain;

define make / 'Make';

define model / 'Model';

define drivetrain/'Drive Train';

run;

ods rtf close;

RTF produces fine as below:

Additionally, I would like to put a spanning header beneath make and model that says "Make and Model". How can I do this?

Re: Spanning Header Beneath Labels - proc report

Ksharp — Sat, 22 Mar 2025 08:26:54 GMT

You want this ?

%let mypath=c:\temp;

ods rtf file="&mypath.\odsr_column_span.rtf" style=journal;
title "Complex Column Spanning";
data _null_; 
  set sashelp.cars(keep= make model drivetrain) end=last; 
  if _N_ = 1 then do; 
      dcl odsout obj(); 
      obj.table_start(); 
      obj.head_start(); 
	  ** Header row 1;
	  obj.row_start(type:"Header");
	  obj.format_cell(text: "Parameter", column_span:2,style_attr:"color=black backgroundcolor=white fontweight=bold  fontstyle=roman borderbottomcolor=black borderbottomwidth=2"); 
      obj.format_cell(text: "Drive Train", row_span:3, style_attr:"color=black backgroundcolor=white vjust=b fontweight=bold fontstyle=roman"); 
      obj.row_end(); 
	  ** Header row 2;
	  obj.row_start(type:"Header");
      obj.format_cell(text: "Make",  column_span:1, style_attr:"color=black backgroundcolor=white fontweight=bold  fontstyle=roman"); 
	  obj.format_cell(text: "Model", column_span:1, style_attr:"color=black backgroundcolor=white fontweight=bold  fontstyle=roman"); 
      obj.row_end(); 
	  ** Header row 3;
      obj.row_start(type: "Header"); 
      obj.format_cell(text: "Make and Model", column_span:2, style_attr:"color=black backgroundcolor=white fontweight=bold fontstyle=roman bordertopcolor=black bordertopwidth=2"); 
      obj.row_end(); 
      obj.head_end(); 
    end;
  ** row for every obs;
      obj.row_start(); 
      obj.format_cell(data: make, row_span:1); 
      obj.format_cell(data: model, row_span:1); 
      obj.format_cell(data: drivetrain, row_span:1); 
	  obj.row_end();
  if last then do; 
      obj.table_end(); 
  end; 
run; 
ods rtf close;
title; footnote;

Re: Spanning Header Beneath Labels - proc report

Ksharp — Sat, 22 Mar 2025 09:20:50 GMT

Another easy and simple way is using this:

ods rtf file='c:\temp\temp.rtf' style=journal;
ods escapechar='~';
proc report data=sashelp.cars(obs=20) nowd style(header)={fontstyle=roman};
columns ('~S={borderbottomcolor=black borderbottomwidth=2}Parameter'
('~S={borderbottomcolor=black borderbottomwidth=2}Make          Model' 
('Make and Model' make model)))  ('Drive Train' drivetrain);
define make/'' style={just=c};
define model/'' style={just=c};
define drivetrain/'' style={just=c};
run;
ods rtf close;