topic Re: Merge two rows without lines in SAS Programming

Merge two rows without lines

PSIOT2 — Thu, 20 Feb 2025 07:29:01 GMT

Dear all,

I would like to merge two rows withouy a line between the rows for AUC diff column:

I used order for having only one value for AUC diff but I have still a line under 1.6.

Please find the code:

proc report data=LROCResults nowd CONTENTS="Table 2.2: Confidence Interval for LROC Areas";
column index modality Cancer Benign Reader AUCValue ci_imrmc difference Objective pval conclusion;
define index / group noprint;
define Cancer / display style={cellwidth=7%} "Cancerous number" CENTER;
define Benign / display style={cellwidth=6%} "Benign number" CENTER ;
define Reader / display style={cellwidth=6%} "Reader number" CENTER ;
define difference / order style={cellwidth=5%} "AUC diff. (%)" CENTER ;
break before index/ contents="" page;
run;

Thank you

Re: Merge two rows without lines

PaigeMiller — Thu, 20 Feb 2025 11:16:18 GMT

Is the little table you show us the input, or the desired output? If it is the input, please show us the desired output. If it is the output, please show us the input SAS data set.

Re: Merge two rows without lines

FreelanceReinh — Thu, 20 Feb 2025 12:21:38 GMT

Hello @PSIOT2,

I think you can use the SPANROWS option of the PROC REPORT statement to get rid of the separating line and optionally, for vertically centered alignment, the VERTICALALIGN=M (alias: VJUST=M) style attribute, as suggested in Re: Proc Report, Merging cells when grouped and vertical center:

data myLROCresults;
infile cards dlm='|';
input modality :$20. Cancer Benign difference;
cards;
Only scan|140|300|1.6
With LCS report|160|320|1.6
;

ods rtf file='C:\Temp\LROC.rtf';
proc report data=myLROCResults spanrows;
column modality Cancer Benign difference;
define Cancer / display style={cellwidth=7%} "Cancerous number" CENTER;
define Benign / display style={cellwidth=6%} "Benign number" CENTER;
define difference / order style={cellwidth=7% vjust=m} "AUC diff. (%)" CENTER;
run;
ods rtf close;

Result:

Re: Merge two rows without lines

PSIOT2 — Mon, 24 Feb 2025 05:46:11 GMT

Thank you a lot