topic Re: Is there option in PROC COMPARE not to show difference in Lengths of Var (attributes) in SAS Programming

Is there option in PROC COMPARE not to show difference in Lengths of Var (attributes)

StudentSASLearn — Thu, 09 Jan 2025 02:06:30 GMT

I am using the follwing proc compare. But I am seeing the difference of Variable length in Result viewer, can we avoid with any option or statements. I tried this.

proc compare base=have comp=want listall ;
informat _all_;
format _all_;
attrib _all_
label=' ';
run;

Re: Is there option in PROC COMPARE not to show difference in Lengths of Var (attributes)

Ksharp — Thu, 09 Jan 2025 03:06:37 GMT

data have;
 length name $ 40;
 set sashelp.class;
run;


ods exclude CompareVariables;
proc compare base=sashelp.class comp=have listall ;
informat _all_;
format _all_;
attrib _all_
label=' ';
run;

Re: Is there option in PROC COMPARE not to show difference in Lengths of Var (attributes)

Tom — Thu, 09 Jan 2025 03:10:14 GMT

Why would you want that?

You could exclude that whole part of the output, but then you would miss other information that is printed there.

Example:

data have(drop=long) want(drop=name rename=(long=name));
  length long $20;
  set sashelp.class;
  long=name;
  output have;
  if _n_=1 then age=9;
  output want;
run;
ods trace on;
ods exclude CompareVariables ;
proc compare data=have compare=want;
run;
ods exclude none;
ods trace off;

Re: Is there option in PROC COMPARE not to show difference in Lengths of Var (attributes)

StudentSASLearn — Thu, 09 Jan 2025 05:02:19 GMT

I am comparing the table calculated values done by someone else, variable lengths are not important to compare. I was interested in actual values present in data. when I see so many variables with length differences, it kind of annoying ( I am aware sas presents it for a reason). In this case variable lengths are not important to compare.

Re: Is there option in PROC COMPARE not to show difference in Lengths of Var (attributes)

StudentSASLearn — Thu, 09 Jan 2025 05:05:47 GMT

Thank you Ksharp and Tom. Both given the same answers which worked for me. I don't know How I can accept both as solutions. So I selected first one. Sorry Tom🙏

Re: Is there option in PROC COMPARE not to show difference in Lengths of Var (attributes)

Tom — Thu, 09 Jan 2025 13:38:27 GMT

You could also just check the SYSINFO macro variable that PROC COMPARE generates and ignore the bits that indicate the variable attribute differences you don't care about.

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/proc/n1jbbrf1tztya8n1tju77t35dej9.htm