topic Extract specific word from a string/variable in SAS Programming

Extract specific word from a string/variable

kingCobra — Wed, 08 Jul 2015 21:07:02 GMT

Hello,

My variable looks like

Calcium (mmol/L) High

Creatinine Clearance (mL/min)

Albumin (g/L)

C-Reactive Protein (mg/L)

I want to create 2 variables as

Var1 Var 2

Calcium High mmol/L

Creatinine Clearance mL/min

Albumin g/L

C-Reactive Protein mg/L

Using SCAN function and then concatenating back looking cumbersome. Is there any function/ method which can extract the content within () without going through lot of manipulations?

Thanks in advance.

Re: Extract specific word from a string/variable

Astounding — Wed, 08 Jul 2015 21:21:17 GMT

Using SCAN shouldn't be too cumbersome. You could try, for example:

var1 = scan(var, 1, '()') || scan(var, 3, '()');

var2 = scan(var, 2, '()');

The difficulty would lie in the possibility that there might be nonconforming structures to the data. There might be two sets of values in parentheses, or a unit of measurement that is not in parentheses. So this is a quick and dirty method, where parsing functions might be safer but more complex.

Good luck.

Re: Extract specific word from a string/variable

KachiM — Wed, 08 Jul 2015 21:27:28 GMT

Try

@'('

Then adjust variables.

Re: Extract specific word from a string/variable

data_null__ — Wed, 08 Jul 2015 21:56:58 GMT

This looks about right.

data param;
   input desc $50.; 
   retain rx;
   if _n_ eq 1 then rx = prxparse('s/\((.*)\)//');
   m = prxmatch(rx,desc);
   if m then do; 
      unit = prxposn(rx,1,desc);
      call prxchange(rx,1,desc);
      desc = compbl(desc);
      end; 

   cards; 
Calcium (mmol/L) High
Creatinine Clearance (mL/min)
Albumin (g/L)
C-Reactive Protein (mg/L)
;;;;
   run; 
proc print; 
   run;

Re: Extract specific word from a string/variable

slchen — Wed, 08 Jul 2015 23:17:45 GMT

data have;

input string $50.;

var1=prxchange('s/$.*$//',-1,string);

var2=prxchange('s/.*$(.*)$.*/$1/',-1,string);

cards;

Calcium (mmol/L) High

Creatinine Clearance (mL/min)

Albumin (g/L)

C-Reactive Protein (mg/L)

;

run;

Re: Extract specific word from a string/variable

kingCobra — Mon, 13 Jul 2015 18:35:35 GMT

Thanks to everyone. I tried SLCHEN and DATA_NULL_; method and both worked.

Thank you for helping.

Re: Extract specific word from a string/variable

KrisDeng — Mon, 26 Nov 2018 19:07:18 GMT

The code you provided is so simple yet effective, I was able to solve the problem Im having immediately.

May I ask what is the role of the numbers "1" "2" and "3" is the middle? And the sign " | " too?

Thank you very much.

Re: Extract specific word from a string/variable

Astounding — Mon, 26 Nov 2018 21:07:36 GMT

The basics: the SCAN function extracts words from a string. The second parameter (1, 2, 3) indicates which word to extract. You can find all the details about SCAN in the online documentation.

Two vertical bars join character strings. There are many more modern functions that can accomplish all of that and more (CAT, CATT, CATS, CATX).