topic Re: Changing the text weight for 1 of 2 legend labels in Proc SGPLOT- SAS 9.4 in SAS Programming

Changing the text weight for 1 of 2 legend labels in Proc SGPLOT- SAS 9.4

Whitlea — Thu, 12 Dec 2024 16:56:15 GMT

I want to bold one of the legend labels in my proc sgplot.

Here are my current results, highlighted is what I want in bold ("A"):

Here is my code:

proc sgplot data=final noborder ;  

series x=date y=&y1/ datalabel=&y1 DATALABELATTRS=(family='Roboto' SIZE=10pt weight=bold color=black)DATALABELPOS=top
MARKERS MARKERATTRS=(SYMBOL=CircleFilled color=red size=8) LINEATTRS = (color=red pattern=solid THICKNESS=3) legendlabel= "A" ;

series x=date y=&y2 / datalabel=&y2 DATALABELATTRS=(family='Roboto' SIZE=10pt color=black)DATALABELPOS=bottom
MARKERS MARKERATTRS=(SYMBOL=CircleFilled color=blue size=8) LINEATTRS = (color=blue pattern=solid THICKNESS=3) legendlabel= "B";

yaxis  grid VALUES = (&values) display=(noline noticks) valueATTRS=(family='Roboto' size=10pt)
label=" " LABELATTRS=(family='Roboto' size=10pt);

XAXIS TYPE = LINEAR  display=( noline noticks)label=" "
LABELATTRS=(family='Roboto' size=10pt ) valueATTRS=(family='Roboto' size=10pt ) ;

keylegend / noborder location=outside position=bottom valueATTRS=(family='Roboto' size=10pt)  ;
title &TITLE1 ;

run;

Thanks!

Re: Changing the text weight for 1 of 2 legend labels in Proc SGPLOT- SAS 9.4

ballardw — Thu, 12 Dec 2024 17:32:03 GMT

To apply different legend appearance to different plots the steps are:

1) Provide a name to each plot you want to appear

2) Provide a different Keylegend statement referencing the name with the attributes.

Here is an example that sets one legend with green for the value text in bold text.

proc sgplot data=sashelp.class;
   scatter x=age y=height/name='h' ;
   scatter x=age y=weight/name='w' ;
   keylegend 'h'/ position=bottom  valueattrs=(color=green weight=bold);
   keylegend 'w'/  position=bottom  ;
run;

You do have to provide the second (or other) keylegend statements otherwise the names not references will not appear in the legend. There will be some interaction between positions and such to play with

Re: Changing the text weight for 1 of 2 legend labels in Proc SGPLOT- SAS 9.4

Ksharp — Fri, 13 Dec 2024 03:01:20 GMT

You could customize legend by LEGENDITE statement to make it happen.

But make sure the item of legend is consistent/same within GRAPH (you can PROC SORT it before).

data have;
set sashelp.heart(obs=1000);
run;

proc sort data=have ;by sex ;run;
proc sgplot data=have;
scatter x=weight y=height/group=sex ;
legenditem name='a' type=MARKERLINE / label='Female' labelattrs=(weight=bold) MARKERATTRS=(symbol=circlefilled color= blue) LINEATTRS=(color= blue);
legenditem name='b' type=MARKERLINE / label='Male' MARKERATTRS=(symbol=circlefilled color= red) LINEATTRS=(color= red);
keylegend 'a' 'b'/title='Sex:';
run;