topic Re: PROC LIFETEST makes unwanted entry in ods pdf TOC in SAS Programming

PROC LIFETEST makes unwanted entry in ods pdf TOC

RowIges — Mon, 23 Sep 2024 17:07:54 GMT

Hi all,

I'm struggling with my ods pdf TOC when using PROC LIFETEST along with ODS SELECT.

Beside the text defined in the ODS PROCLABEL statement, I get a second line in the TOC named "Survival Curves" which refers to the same graph. Can I get rid of it?

ods pdf output='mypath\filename.pdf' style = journal contents=on pdftoc = 1;

ods graphics on;

ods listing gpath='mypath';
ods graphics / imagename="g_tte_1" imagefmt=png;
ods noproctitle;
ods proclabel = 'Figure 14.2.2.59    Kaplan-Meier Plot of Time to XXX';
ods select survivalPlot;

proc lifetest data=mydat plots =(survival(atrisk(outside(0.15)) test));
time T*censor(0);
strata group;
run;

ods graphics off;

ods pdf close;

Re: PROC LIFETEST makes unwanted entry in ods pdf TOC

Quentin — Mon, 23 Sep 2024 17:41:17 GMT

Bari Lawhorn has a great paper on PDF TOC: https://support.sas.com/resources/papers/proceedings11/252-2011.pdf

She presented it as a webinar to BASUG last year.

The slides are: https://www.basug.org/_files/ugd/6fce8c_aba2be0893314fa3bb3ca2c22fc1fc90.pdf

The recoding is: https://www.basug.org/videos?wix-vod-video-id=a17c9abb623e4f64b2ef843b0589dad3&wix-vod-comp-id=comp-klv807gt

Re: PROC LIFETEST makes unwanted entry in ods pdf TOC

Ksharp — Tue, 24 Sep 2024 02:34:10 GMT

ods document name=testAW(write);
ods select survivalPlot;
proc lifetest data=sashelp.bmt ;
time T*status(0);
strata group;
run;
ods document close;
proc document name=testAW;
list/ levels=all; run;
quit;



proc document name=testAW2(write);
setlabel \work.testAW\Lifetest#1\SurvivalPlot#1  "Figure 14.2.2.59    Kaplan-Meier Plot of Time to XXX";
copy \work.testAW\Lifetest#1\SurvivalPlot#1 to ^;  /*copy to current directory*/
run;
list/ levels=all; run;
quit;

/*Create the desired PDF file*/
proc document name=work.testAW2;
ods pdf file="c:\temp\want.pdf" style = journal contents=on pdftoc = 1;
replay;
run;
ods pdf close;
quit;