topic Re: Remove ERROR generated from custom datetime format in SAS Programming

Remove ERROR generated from custom datetime format

mmm7 — Wed, 18 Sep 2024 14:00:48 GMT

I am using a custom datetime format. I'm looking for a solution to remove "ERROR" when the format is applied and missing data exists.

data example1;
	input id dttm anydtdtm.; 
	format dttm datetime14.;  
	datalines;
100  31OCT27:23:15 
101
;
run;
proc format;
   picture MyMSdt other='%0m/%0d/%0Y %0H:%0M' (datatype=datetime);
run;
data example2;
	set example1;
	format dttm MyMSdt.;
run;

Re: Remove ERROR generated from custom datetime format

PaigeMiller — Wed, 18 Sep 2024 14:06:43 GMT

proc format;
   picture MyMSdt other='%0m/%0d/%0Y %0H:%0M' (datatype=datetime);
   value mymsdtt .=' ' other=[mymsdt.];
run;
data example2;
	set example1;
	format dttm MyMSdtt.;
run;

Re: Remove ERROR generated from custom datetime format

salah1 — Wed, 18 Sep 2024 14:09:10 GMT

data example1;
input id dttm anydtdtm.;
format dttm datetime14.;
datalines;
100 31OCT27:23:15
101
102 3
;
run;
proc format;
picture MyMSdt LOW-HIGH='%0m/%0d/%0Y %0H:%0M' (datatype=datetime)
other= "NULL";
run;
data example2;
set example1;
format dttm MyMSdt.;
run;

Re: Remove ERROR generated from custom datetime format

mmm7 — Wed, 18 Sep 2024 14:09:38 GMT

@PaigeMiller Thank you so much for your solution!

Re: Remove ERROR generated from custom datetime format

Quentin — Wed, 18 Sep 2024 14:14:05 GMT

You could add missing values to your format, perhaps:

proc format;
   picture MyMSdt ._-.Z="Missing" other='%0m/%0d/%0Y %0H:%0M' (datatype=datetime);
run;

Re: Remove ERROR generated from custom datetime format

ballardw — Wed, 18 Sep 2024 14:52:56 GMT

Or a minor change to your format definition:

proc format;
   picture MyMSdt low-high='%0m/%0d/%0Y %0H:%0M' (datatype=datetime);
run;

Which does not attempt to apply any formatting to missing values.

More properly should use the earliest/latest SAS datetime values that are accepted but most people don't deal with dates that extreme.