Quoting issie while writing sas code files to a txt file

acordes — Mon, 02 Sep 2024 17:27:05 GMT

The table results has the correct code-line, but the txt file double or triple quotes when it encounters a double quote.

filename myfldr filesrvc folderPath='/Projects/Portugal/';

data filenames;
length  fname $200;
did = dopen('myfldr');
do i = 1 to dnum(did);
  fname = dread(did,i);
  output;
end;
did = dclose(did);
keep fname;
run;

%let myStr = ; /* string you are looking */

data _null_;
set filenames;
if index(lowcase(fname), '.sas') then 
call execute ('
filename search FILESRVC FOLDERPATH="/Projects/Portugal/" FILENAME=' || quote(strip(fname)) || ' ;

data temp;
length file $ 256 code_line $ 2048;
infile search filename = file end=end;
input;
lineNumber+1;
filename = file;
code_line= _infile_;
if find(_infile_, "&myStr.", "i") or length(_infile_) >=1 then output;
if end then lineNumber=0;
run;

proc append base=result data=temp;
run;
');
run;

filename outtxt FILESRVC FOLDERPATH='/Projects/Portugal'  FILENAME='_a_sas_code1.txt';

proc sort data=result;
by filename lineNumber;
run;

data _null_;
  file outtxt dsd   dlm='|'  ;
  set result ;
	by filename;
if first.filename then put filename;
  put %NRQUOTE(code_line);
if last.filename then put '0A'x;
run;

Re: Quoting issie while writing sas code files to a txt file

Kurt_Bremser — Mon, 02 Sep 2024 17:48:31 GMT

The DSD option causes this; since quotes might be used around the string, strings with quotes are also enclosed in quotes, and the quotes in the string are doubled.

You do not need the DSD option and the delimiter, as you only PUT one variable in every line.

topic Quoting issie while writing sas code files to a txt file in SAS Programming

Quoting issie while writing sas code files to a txt file

Re: Quoting issie while writing sas code files to a txt file