last second value for each group

pavank — Tue, 16 Jul 2024 09:52:43 GMT

Data b;
input cc swipe;
cards;
1 200
1 300
1 200
1 900
2 1300
2 1400
2 1500
;
run;




proc sort data=b;
by cc;
run;


data last_second;
  set b;
  by cc;
last_second_value = lag(swipe);
if last.cc then do;
    output;
  end;
  drop swipe;
run;

 How to get last second values using PROC SQL Method 
output 
cc swipe
1 200
2 1400

Re: last second value for each group

Kurt_Bremser — Tue, 16 Jul 2024 09:59:50 GMT

SQL does not have a concept of sequence, it works with sets. Stay with the DATA step, e.g.

data last_second;
do until (last.cc);
  set b;
  by cc;
  if not last.cc then last_second_value = swipe;
end;
drop swipe;
run;

Your code can be simplified by using a Subsetting IF:

data last_second;
set b;
by cc;
last_second_value = lag(swipe);
if last.cc and not first.cc;
drop swipe;
run;

The expanded condition takes care of cases where there's only one observation for a cc group.

topic last second value for each group in SAS Programming

last second value for each group

Re: last second value for each group