topic Re: only replacing exact string among slight variations? in SAS Programming

only replacing exact string among slight variations?

appleorange — Wed, 10 Jul 2024 15:59:58 GMT

data sample2;
 y='icc 1icc ic'; run;

 data sample3; set sample2;
 y2=tranwrd(compress(y, ' '), 'ic', '1icc');
y3=tranwrd(compress(y2, ' '), '1ic', '1icc');
run;

I need to correct the icc -> 1icc

and ic -> 1icc. The 1icc is correct as is, but if I try to use multiple steps of tranwrd to correct the slight variations, I get 1icccc11icccc1iccc as y3.

Is there a way to identify and correct the specific iterations only?

Re: only replacing exact string among slight variations?

procphysics — Wed, 10 Jul 2024 16:30:41 GMT

What do you want your final output y3 to look like?

Do you want it to be '1icc 1icc 1icc'?

Re: only replacing exact string among slight variations?

appleorange — Wed, 10 Jul 2024 16:32:41 GMT

Yes, correct.

Re: only replacing exact string among slight variations?

procphysics — Wed, 10 Jul 2024 16:53:23 GMT

The tranwrd function replaces all instances of a character pattern, so when you do

y2=tranwrd(compress(y, ' '), 'ic', '1icc');

all instances of 'ic' in the column are replaced with '1icc'.

Also, you are removing the spaces from y so SAS does the tranwrd function on 'icc1iccic'.

y='icc 1icc ic' becomes y2='1iccc11iccc1icc'.

If you want your final string to be '1icc 1icc 1icc' then you can do that by breaking up y into each word, then replacing the first and third words.

data sample2;
    y='icc 1icc ic';

    firstspace = find(y,' ');
    secondspace = find(y,' ',firstspace+1);

    firstword=substr(y,1,firstspace-1);
    secondword=substr(y,firstspace+1,secondspace-firstspace-1);
    thirdword=substr(y,secondspace+1);

    if firstword='icc' then firstword='1icc';
    if thirdword='ic' then thirdword='1icc';

    y2 = catx(' ',firstword,secondword,thirdword);

 run;

First use the find function to find the location of the first and second spaces in y. The secondspace looks for the next space after the firstspace.

 firstspace = find(y,' ');
 secondspace = find(y,' ',firstspace+1);

Then use the substr function to extract each word using spaces as delimiters.

    firstword=substr(y,1,firstspace-1);
    secondword=substr(y,firstspace+1,secondspace-firstspace-1);
    thirdword=substr(y,secondspace+1);

firstword starts at position 1 and ends right before the first space.

secondword is between the first and second spaces.

thirdword starts right after the second space.

Now replace the words 'icc' and 'ic' with '1icc'.

   if firstword='icc' then firstword='1icc';
   if thirdword='ic' then thirdword='1icc';

Your new string looks like:

y2 = catx(' ',firstword,secondword,thirdword);

Re: only replacing exact string among slight variations?

Tom — Wed, 10 Jul 2024 19:03:49 GMT

If you want to use tranwrd() the include the spaces. You will have to ensure there is both a leading and trailing space in the string to make sure you catch words at the start or end of the source string.

data test;
  y='ic icc 1icc 1ic';
  length y2 $40 ;
  y2=strip(tranwrd(cat(' ',y, ' '), ' ic ', ' 1icc '));
  y2=strip(tranwrd(cat(' ',y2,' '), ' icc ', ' 1icc '));
  y2=strip(tranwrd(cat(' ',y2,' '), ' 1ic ', ' 1icc '));
run;

Result:

Obs           y                   y2

 1     ic icc 1icc 1ic    1icc 1icc 1icc 1icc

Re: only replacing exact string among slight variations?

Ksharp — Thu, 11 Jul 2024 01:23:07 GMT

data test;
  y='ic icc 1icc 1ic';
  length y2 $40 ;
  y2=prxchange('s/\b(ic|icc)\b/1icc/i',-1,y);
run;