topic how to do a one-hot encoding process by using proc transpose? in SAS Programming

how to do a one-hot encoding process by using proc transpose?

duanzongran — Thu, 04 Jul 2024 08:39:32 GMT

dear all:

I know how to do one-hot encoding with data step.Is it possible to do it by using proc transpose?

data basic_info;
input name $ sex $;
datalines;
A Female
B Male
C Female
D Female
E Male
;
run;

Any sugesstion is welcome!

Re: how to do a one-hot encoding process by using proc transpose?

Ksharp — Thu, 04 Jul 2024 09:45:57 GMT

data basic_info;
input name $ sex $;
dummy=1;
datalines;
A Female
B Male
C Female
D Female
E Male
;
run;
proc glmselect data=basic_info outdesign(addinputvars)=want(drop=dummy);
class sex;
model dummy=sex/selection=none noint;
run;

Re: how to do a one-hot encoding process by using proc transpose?

Kurt_Bremser — Thu, 04 Jul 2024 12:24:36 GMT

You need to have a value which you can transpose.

data basic_info;
input name $ sex $;
val = 1;
datalines;
A Female
B Male
C Female
D Female
E Male
;

proc transpose data=basic_info out=want1 (drop=_name_);
by name;
var val;
id sex;
run;

data want;
merge
  basic_info
  want1
;
by name;
run;

Conversion of missing to 0 can be done manually in the MERGE step, or with PROC STDIZE.

Re: how to do a one-hot encoding process by using proc transpose?

Reeza — Thu, 04 Jul 2024 15:36:25 GMT

And just a note, though you may already be aware, that if using certain procedures this is unnecessary as param=ref will do the encoding automatically.

Re: how to do a one-hot encoding process by using proc transpose?

duanzongran — Tue, 06 Aug 2024 06:44:43 GMT

Thank you!
I didn't expect that there would be other processes that could also solve my problem.