topic Using proc report how can you generate a pdf with repeated columns and values in all pages in SAS Programming

Using proc report how can you generate a pdf with repeated columns and values in all pages

ANKH1 — Wed, 03 Jul 2024 15:09:08 GMT

The table produced has many columns. Is there a way to display a pdf where the first 4 columns are repeated in all pages? There are many more columns after position and many more rows. I have the following code but it is not working:

data sample;
input ID $ Name $ Age Salary Department $ Position $;
datalines;
1 John 30 50000 HR Manager
2 Jane 25 55000 Finance Analyst
3 Jack 40 60000 IT Developer
4 Jill 35 62000 Marketing Specialist
;
run;

ods pdf file='C:\path\to\your\output.pdf';

proc report data=sample nowd split='_';
    column ID Name Age Salary Department Position;
    define ID / 'ID' left;
    define Name / 'Name' left;
    define Age / 'Age' center;
    define Salary / 'Salary' right;
    define Department / 'Department' left;
    define Position / 'Position' left;
    
    /* Specify the columns to be repeated */
    compute after _page_;
        line ' ';
        line 'ID     Name     Age     Salary';
    endcomp;
run;

/* Close ODS PDF destination */
ods pdf close;

Re: Using proc report how can you generate a pdf with repeated columns and values in all pages

Ksharp — Thu, 04 Jul 2024 02:16:36 GMT

Using ID + PAGE option :

data sample;
input ID $ Name $ Age Salary Department $ Position $;
datalines;
1 John 30 50000 HR Manager
2 Jane 25 55000 Finance Analyst
3 Jack 40 60000 IT Developer
4 Jill 35 62000 Marketing Specialist
;
run;

ods pdf file='C:\temp\output.pdf';

proc report data=sample nowd split='_';
    column ID Name Age Salary Department Position;
    define ID / 'ID' left   ;
    define Name / 'Name' left  ID ;
    define Age / 'Age' center;
    define Salary / 'Salary' right;
    define Department / 'Department' left PAGE;
    define Position / 'Position' left;
    
    /* Specify the columns to be repeated */
    compute after _page_;
        line ' ';
        line 'ID     Name     Age     Salary';
    endcomp;
run;

/* Close ODS PDF destination */
ods pdf close;

Re: Using proc report how can you generate a pdf with repeated columns and values in all pages

ANKH1 — Thu, 04 Jul 2024 14:00:59 GMT

Thank you!