topic Re: format and lable statement in proc means in SAS Programming

format and lable statement in proc means

pavank — Thu, 20 Jun 2024 06:38:24 GMT

data sales;
    input Region $ Sales;
    datalines;
North 12345
South 67890
East  23456
West  78901
North 34567
South 89012
East  45678
West  12345
;
run;

/* Using PROC MEANS with LABEL and FORMAT */
proc means data=sales mean sum;
    var Sales;
    label Sales = 'Total Sales';
    format Sales comma10.;
    title 'Summary Statistics for Sales';
run;

How to apply label and format statments in proc means procedure

Re: format and lable statement in proc means

rudfaden — Thu, 20 Jun 2024 09:59:49 GMT

You cannot directly edit the format of sum and mean. You need to edit the base template.

data sales;
    input Region $ Sales;
    datalines;
North 12345
South 67890
East  23456
West  78901
North 34567
South 89012
East  45678
West  12345
;
run;
ods path(prepend) work.templat(update);
proc template;
 edit base.summary;
  edit mean;
   format=comma10.;
  end;
  edit sum;
   format=comma10.;
  end;
 end;
run;

proc means data=sales mean sum;
    var Sales;
    label Sales = 'Total Sales';
    title 'Summary Statistics for Sales';
run;


proc template;
 delete base.summary;
run;

Re: format and lable statement in proc means

ballardw — Thu, 20 Jun 2024 14:45:05 GMT

Perhaps a different procedure:

When appearance is an issue look to the report procedures where there are more appearance controls:

proc report data=sales;
   column region sales sales=salessum;
   define region / group;
   define sales/mean format=comma10.2 "Mean Sales";
   define salessum/ sum format=comma10. "Total Sales";
run;

proc tabulate data=sales;
   class region;
   var sales;
   table region=' ',
         Sales=' '*(mean='Mean Sales'*f=comma10. sum='Total Sales'*f=comma10.)
         /box='Region'
   ;
run;

or create an output set and us proc print.

Re: format and lable statement in proc means

pavank — Fri, 21 Jun 2024 05:38:11 GMT

Hi @ballardw

Thank you for your solution