Issue with latin characters coming from a txt file,

acordes — Tue, 11 Jun 2024 13:35:50 GMT

Is there any function that can do magic converting the string 'ComunicaciÃ³n 1 aÃ±o' back to its origin

'Comunicación 1 año'.

That does not work but looks promising.

data test;
   length instr $50;
   length str1 str2 str3 str4 str5 str6 str7 str8 $ 50;
   instr = "SAS" ||"ae"x || " ComunicaciÃ³n 1 aÃ±o";
   put instr;
   str1 = kpropdata(instr, 'UESC','utf-8');
   put str1= +2 str1= $hex34.;
   str2 = kpropdata(instr,'TRIM','utf-8');
   put str2= +2 str2= $hex26.;
   str3 = kpropdata(instr,'BLANK', 'utf-8');
   put str3= +2 str3= $hex26.;
   str4 = kpropdata(instr,'?', 'utf-8');
   put str4= +2 str4= $hex26.;
   str5 = kpropdata(instr,'hex', 'utf-8');
   put str5= +2 str5= $hex26.;
   str6 = kpropdata(instr,'TRUNC', 'utf-8');
   put str6= +2 str6= $hex26.;
   str7 = kpropdata(instr,'REMOVE', 'utf-8');
   put str7= +2 str7= $hex26.;
   str8 = kpropdata(instr,'NCR', 'utf-8');
   put str8= +2 str8= $hex26.;
run;

Re: Issue with latin characters coming from a txt file,

Tom — Tue, 11 Jun 2024 13:39:02 GMT

KCVT().

data test;
  have='ComunicaciÃ³n 1 aÃ±o';
  expect= 'Comunicación 1 año';
  want = kcvt(have,'utf-8','wlatin1');
  same=expect=want;
run;

topic Issue with latin characters coming from a txt file, in SAS Programming

Issue with latin characters coming from a txt file,

Re: Issue with latin characters coming from a txt file,