topic Re: Catolog exist or not in SAS Programming

Catolog exist or not

pavank — Wed, 22 May 2024 08:13:34 GMT

%macro sort (dname, new, svar) ;
proc sort data=&dname out=&new ;
by &svar;
run;
%Mend;

%sort(sashelp.class, demo1,sex);


data _null_;
   if cexist("WORK.SORT") then
   put "WORK.SORT exists";
   else
   put "WORK.SORT does not exist";
run;

Hi Experts,

here i am trying macro catolog exist or not but its giving wrong output please check where i did wrong

Re: Catolog exist or not

andreas_lds — Wed, 22 May 2024 08:16:18 GMT

There aren't any statements in the code shown creating work.sort, so why should it exist?

Re: Catolog exist or not

pavank — Wed, 22 May 2024 08:40:58 GMT

in log it shows work.sort does not exist

here i am using CEXIST function to check macro catolog SORT exist or not

Re: Catolog exist or not

Ksharp — Wed, 22 May 2024 09:21:25 GMT

1) You could use dictionary CATALOGS to check if the macro is exist.

proc sql;
create table catalog as
select * from dictionary.catalogs;
quit;

2)You also could use function fileexist() to check .

Re: Catolog exist or not

pavank — Wed, 22 May 2024 09:54:45 GMT

%macro sort (dname, new, svar) ;
proc sort data=&dname out=&new ;
by &svar;
run;
%Mend;

%sort(sashelp.class, demo1,sex);


data _NULL_;
if cexist('work.sasmacr.sort.macro') then
    put "work.sort exists" ;
    else put "work.sort does not exist";
run;


%put %sysfunc(ifc(%sysmacexist(sort), Yes %nrstr("&dname") Exists, %nrstr("&dname") Does not Exist));

please check syntax %put %sysfunc(ifc(%sysmacexist(sort), Yes %nrstr("&dname") Exists, %nrstr("&dname") Does not Exist));

Re: Catolog exist or not

Tom — Wed, 22 May 2024 13:54:17 GMT

@pavank wrote:
%macro sort (dname, new, svar) ;
proc sort data=&dname out=&new ;
by &svar;
run;
%Mend;

%sort(sashelp.class, demo1,sex);


data _null_;
   if cexist("WORK.SORT") then
   put "WORK.SORT exists";
   else
   put "WORK.SORT does not exist";
run;
Hi Experts,

here i am trying macro catolog exist or not but its giving wrong output please check where i did wrong

I cannot tell what you are trying to find.

Are you trying to find out of the macro SORT exists in some catalog somewhere? If so you are not looking for the right catalog. Normally compiled macros will be placed in WORK.SASMACR catalog. But if you are using tools like SAS/Studio to launch SAS then they will be placed in the WORK.SASMAC1 catalog instead.

Re: Catolog exist or not

Ksharp — Thu, 23 May 2024 00:07:04 GMT

It looks like %sysmacexist() only check the user defined macro ,not built-in system macro .

34 %put %sysfunc(ifc(%sysmacexist(scan), Yes Exists, Does not Exist));
Does not Exist

Re: Catolog exist or not

Patrick — Thu, 23 May 2024 02:20:40 GMT

@pavank wrote:

in log it shows work.sort does not exist

here i am using CEXIST function to check macro catolog SORT exist or not

I'm a bit confused if you want to check for existence of a SAS table or for existence of a compiled macro in the macro catalog under WORK.

Below code run in a fresh new session to demonstrate the different ways to query hopefully giving you sufficient pointers for what you need.

data check_step_1;
  /* does TABLE work.demo1 exist? */
  table_exist_flg=exist('work.demo1','data');
  /* does compiled macro %sort exist as member in referenced catalog (here: work.sasmacr)? */
  macro_compiled_flg_1=cexist('work.sasmacr.sort.macro');
  /* does compiled macro %sort exist as member in catalog under WORK? */
  macro_compiled_flg_2=%sysmacexist(sort);
run;
title 'check_step_1';
proc print data=check_step_1;
run;

/* execution of the macro definition compiles the macro into the catalog under WORK */
%macro sort (dname, new, svar);
  proc sort data=&dname out=&new;
    by &svar;
  run;
%mend;

data check_step_2;
  /* does TABLE work.demo1 exist? */
  table_exist_flg=exist('work.demo1','data');
  /* does compiled macro %sort exist as member in referenced catalog (here: work.sasmacr)? */
  macro_compiled_flg_1=cexist('work.sasmacr.sort.macro');
  /* does compiled macro %sort exist as member in catalog under WORK? */
  macro_compiled_flg_2=%sysmacexist(sort);
run;
title 'check_step_2';
proc print data=check_step_2;
run;

/* calling the macro creates the the table as requested via parameter &new */
%sort(sashelp.class, demo1,sex);
data check_step_3;
  /* does TABLE work.demo1 exist? */
  table_exist_flg=exist('work.demo1','data');
  /* does compiled macro %sort exist as member in referenced catalog (here: work.sasmacr)? */
  macro_compiled_flg_1=cexist('work.sasmacr.sort.macro');
  /* does compiled macro %sort exist as member in catalog under WORK? */
  macro_compiled_flg_2=%sysmacexist(sort);
run;
title 'check_step_3';
proc print data=check_step_3;
run;
title;

Re: Catolog exist or not

Patrick — Thu, 23 May 2024 05:30:47 GMT

@Ksharp wrote:
It looks like %sysmacexist() only check the user defined macro ,not built-in system macro .

34 %put %sysfunc(ifc(%sysmacexist(scan), Yes Exists, Does not Exist));
Does not Exist

@Ksharp

It looks like %scan() is not a traditional macro. At least I can't find it as a member of any macro catalog under SASROOT.

According to the documentation %sysmacexist() only searches through work.sasmacr. It would still find SAS supplied macros like %tslit() or %lowcase() that only get compiled into work.sasmacr when called the first time in a session.

Re: Catolog exist or not

Ksharp — Thu, 23 May 2024 05:48:11 GMT

"According to the documentation %sysmacexist() only searches through work.sasmacr."
That is bad new. If I stored my compiled macro at other path, %sysmacexist() does not work ?

Re: Catolog exist or not

Patrick — Thu, 23 May 2024 11:39:00 GMT

That’s how I read the docu, yes.

Re: Catolog exist or not

Tom — Thu, 23 May 2024 12:04:13 GMT

@Ksharp wrote:
It looks like %sysmacexist() only check the user defined macro ,not built-in system macro .

34 %put %sysfunc(ifc(%sysmacexist(scan), Yes Exists, Does not Exist));
Does not Exist

%SCAN() is NOT a macro at all. It is a built in macro function. Just like %LENGTH() and the others.

Re: Catolog exist or not

Tom — Thu, 23 May 2024 12:18:17 GMT

@Ksharp wrote:
"According to the documentation %sysmacexist() only searches through work.sasmacr."
That is bad new. If I stored my compiled macro at other path, %sysmacexist() does not work ?

Did you actually test whether %SYSMACEXIST() does not check in the catalog you told it to search for pre-compiled macros? Because the documentation is wrong about only search WORK.SASMACR. Because when you launch SAS via SAS/Studio (or other methods that spawn a new SAS session) then the compiled macros are default placed into WORK.SASMAC1 instead and the %SYSMACEXIST() macro function can find them. Try this code:

%macro mymac; 
%put &=sysmacroname; 
%mend; 
%mymac; 
%put %sysmacexist(mymac); 
data _null_; 
  set sashelp.vcatalg; 
  where objname='MYMAC'; 
  put (_all_) (=/); 
run;

Re: Catolog exist or not

Ksharp — Fri, 24 May 2024 00:36:06 GMT

Tom,

I am using stand-alone PC version SAS, and not SAS Studio.

I means if I store the complied macro at other path (not WORK library), %sysmacexist() would not work.

Check the following example to see what I mean.

libname x 'c:\temp';
option mstored sasmstore=x;
%macro mymac/store; 
%put &=sysmacroname; 
%mend; 
%mymac; 

%put NOTE: %sysmacexist(mymac);

Re: Catolog exist or not

Ksharp — Fri, 24 May 2024 00:53:59 GMT

Tom,

And more ,using the code I suggested, I could get right result.

Re: Catolog exist or not

Tom — Fri, 24 May 2024 02:18:56 GMT

So another good reason to not use stored compiled macro catalogs and instead just stick with autocall libraries.

Re: Catolog exist or not

Ksharp — Fri, 24 May 2024 06:26:25 GMT

Tom,
But sometime we need to distribute my macro to other sas programmer,and not want to let others to see raw code,usually would secure these macro.
like:
%macro mymac/store secure;

Re: Catolog exist or not

Patrick — Fri, 24 May 2024 08:59:57 GMT

@Ksharp wrote:
Tom,
But sometime we need to distribute my macro to other sas programmer,and not want to let others to see raw code,usually would secure these macro.
like:
%macro mymac/store secure;

@Ksharp I don't believe you're someone who has to hide his code for job security so really interested why you can't share it. The only very few times I had to use secure compiled macros was for situations where I couldn't avoid having a password in the code.

The only other reason I'm currently aware of for pre-compiling: Depending on the environment it can take a bit until a .sas file is found for compilation so for some interactive web application the reason for pre-compiling could be performance. I personally was never in such a situation but I also mostly implement backend processes.

Re: Catolog exist or not

Ksharp — Fri, 24 May 2024 08:56:32 GMT

"so really interested why you can't share it."
It is BOSS 's requirement.
But in reallity, It haven't been done yet.

Re: Catolog exist or not

Patrick — Fri, 24 May 2024 09:14:03 GMT

@Ksharp wrote:
"so really interested why you can't share it."
It is BOSS 's requirement.
But in reallity, It haven't been done yet.

Ah, yes, one of these requirements....

Another personal opinion: I don't like the mstore, especially in a Dev environment. It needs another library that you can't hide in EG/Studio and once assigned it's really hard to change anything in the macro catalog under mstore. What I've done last time: Compile the macros into a catalog in a read only location, create an %init macro that copies the secure compiled macros into the catalog under WORK.

The macro code itself was also in a read only folder with tokens for user and password. And then a macro that can be called passing user and password as parameters that then compiles all the other macros and stores them in the read only catalog (for the unlikely but certainly rare case the PW needs to change; and this process fully documented in a run book).