topic Re: size of tables in CAS libraries in SAS Programming

size of tables in CAS libraries

AnnLyn — Mon, 29 Apr 2024 13:02:45 GMT

How can I easy create storage/size in memeory information of all tables in a specific cas lib.

I use this:

proc cas;
table.tabledetails /name="%" caslib="XXXX";

quit;

but it fails. it seems that I can not use a wildcards in that manner?

Do you have some code which could help me?

Re: size of tables in CAS libraries

Mazi — Mon, 29 Apr 2024 13:14:12 GMT

proc casutil;
	load data=sashelp.cars
		 outcaslib="casuser"
		 casOut="cars"
		 replace;

	load data=sashelp.class
		 outcaslib="casuser"
		 casOut="class"
		 replace;

	load data=sashelp.baseball
		 outcaslib="casuser"
		 casOut="baseball"
		 replace;
run;

proc cas;
	table.tableinfo result=rc /caslib="casuser";
	do table over rc["TableInfo"][,"Name"];
		table.tabledetails /name=table caslib="casuser";
	end;
quit;

Can you try this?

Re: size of tables in CAS libraries

AnnLyn — Mon, 29 Apr 2024 15:45:51 GMT

It works perfectly - thanks a lot. Is it possible to output the results in a table? thanks in advance.

Re: size of tables in CAS libraries

Mazi — Mon, 29 Apr 2024 15:48:59 GMT

Hi, Yes -

We can use the saveresult statement to do this.

Do you want them appended to one table or a different table for each?

Re: size of tables in CAS libraries

AnnLyn — Mon, 29 Apr 2024 15:51:52 GMT

I would prefer one table as it can be used for a report afterwards. Thanks in advance.

Re: size of tables in CAS libraries

Mazi — Mon, 29 Apr 2024 16:57:51 GMT

cas mycas;

libname casuser cas caslib=casuser;

proc casutil;
	load data=sashelp.cars
		 outcaslib="casuser"
		 casOut="cars"
		 replace;

	load data=sashelp.class
		 outcaslib="casuser"
		 casOut="class"
		 replace;

	load data=sashelp.baseball
		 outcaslib="casuser"
		 casOut="baseball"
		 replace;
run;

proc cas;
	table.tableinfo result=rc /caslib="casuser";
	fragment=';';
	do table over rc["TableInfo"][,"Name"];
		table.tabledetails result=result/name=table caslib="casuser";
		saveresult result caslib="casuser" casout=table;
		code="data casuser.allResults"||fragment|| "set casuser."||table||";length Data varchar(100);Data='"||table||"';run;";
		datastep.runcode/code=code;
		fragment='(append=yes);';
	end;
quit;

Give this a try

Re: size of tables in CAS libraries

AnnLyn — Tue, 30 Apr 2024 07:51:18 GMT

it works great. Thank you so much for your help. I am very happy with your solution.