topic Re: How to make macro pass special character in SAS Programming

How to make macro pass special character

lichee — Wed, 17 Apr 2024 16:14:33 GMT

Hi all,

I'm using a data set to create labels as guided in the Stack Overflow thread, https://stackoverflow.com/questions/46407959/how-can-i-set-the-variable-labels-in-sas-using-a-table. How should the code be modified to make it allow special characters in the labels? Thanks a lot!

%macro label_it (var=, label=);
label &var. = "&label.";
%mend label_it;

proc sql;
select cats('%label_it(var=',var,',label=',description,')')
into :labellist separated by ' '
from varlabels;
quit;

data want;
set have;
&labellist.;
run;

Re: How to make macro pass special character

Tom — Wed, 17 Apr 2024 19:27:25 GMT

That is easy.

Change the macro to expect a quoted string. Then pass it a quoted string. While you are at it make it compatible with VALIDVARNAME=ANY option by using NLITERAL() function.

%macro label_it (var=, label=);
label &var. = &label.;
%mend label_it;

proc sql;
select cats('%label_it'
  ,'(var=',nliteral(var)
  ,',label=',quote(trim(description),"'")
  ,')')
  into :labellist separated by ' '
  from varlabels;
quit;

data want;
  set have;
&labellist.;
run;

Re: How to make macro pass special character

lichee — Thu, 18 Apr 2024 19:30:11 GMT

This works. However, there are unnecessary single quote marks in the labels.

Re: How to make macro pass special character

Tom — Thu, 18 Apr 2024 20:07:00 GMT

Sounds like you only implement HALF of the suggested fix.

If you set the parameter LABEL to the value of

'My Label'

and then use

"&LABEL"

in the code you get

"'My Label'"

But if instead the macro code just uses

&LABEL

then you will get

'My Label'

in the code, which is exactly what you want.