topic Re: How to identify the records in the column other than alpha numeric and hypen in SAS Programming

How to identify the records in the column other than alpha numeric and hypen

learn_SAS_23 — Tue, 09 Apr 2024 13:37:22 GMT

data have;
    input column $20.;
    datalines;
abc-def1
(123-456
xyz789
!@#$%^&*
;
run;
data check_special_chars;
    set have;

    /* Use PRXMATCH to search for characters that are not alphanumeric or hyphen */
    if prxmatch('/[^[:alnum:]-]/', column) > 0 then
        special_chars_found = 1;
    else
        special_chars_found = 0;
run;

am expecting :

column special_chars_found

abc-def1 0
(123-456 1
xyz789 0
!@#$%^&* 1

Re: How to identify the records in the column other than alpha numeric and hypen

learn_SAS_23 — Tue, 09 Apr 2024 13:37:53 GMT

The above prxmatch is not working as expected

Re: How to identify the records in the column other than alpha numeric and hypen

yabwon — Tue, 09 Apr 2024 13:45:02 GMT

keep it simple:

data have;
    input column $20.;
    datalines;
abc-def1
(123-456
xyz789
!@#$%^&*
;
run;
data want;
set have;
check = 1 & lengthn(compress(column,"-","AD"));
run;

Bart

Re: How to identify the records in the column other than alpha numeric and hypen

PaigeMiller — Tue, 09 Apr 2024 13:48:14 GMT

I would let the FINDC function do the work.

data want;
    set have;
    z=findc(column,'-','adkt')>0;
run;

Re: How to identify the records in the column other than alpha numeric and hypen

learn_SAS_23 — Tue, 09 Apr 2024 13:59:23 GMT

Perfect , thanks so much
Both solutions working as perfect
can you share what does keyword 'adkt' mean ? in below function
findc(column,'-','adkt')

Re: How to identify the records in the column other than alpha numeric and hypen

learn_SAS_23 — Tue, 09 Apr 2024 14:03:35 GMT

Thanks for your tip , what does this AD mean here ? lengthn(compress(column,"-","AD"));

Re: How to identify the records in the column other than alpha numeric and hypen

PaigeMiller — Tue, 09 Apr 2024 14:10:06 GMT

From the FINDC documentation, there are many "modifiers" that alter the search based upon many different criteria.

Letter a "adds alphabetic characters to the list of characters" that are in the search.

You can look up the other modifiers at that link.

Re: How to identify the records in the column other than alpha numeric and hypen

learn_SAS_23 — Tue, 09 Apr 2024 14:10:23 GMT

Thanks so much for the details

Re: How to identify the records in the column other than alpha numeric and hypen

ballardw — Tue, 09 Apr 2024 14:12:46 GMT

@learn_SAS_23 wrote:
Perfect , thanks so much
Both solutions working as perfect
can you share what does keyword 'adkt' mean ? in below function
findc(column,'-','adkt')

Not a keyword, that is a list of modifiers to the function. 'a' or 'A' adds all alphabetic characters to the list to search for, 'd' or 'D' adds all digits to the list. So Findc(column,'-','ad') searches for the dash and all letters or digits. The 'k' says 'find characters not in the list. Findc(column,'-','adk') finds all characters not in the list dash, letter or digit. The 't' removes any trailing spaces from the string and the character list. Many of the search functions in SAS will include trailing spaces if the length of a given variable is longer than is "used". The reason T is added to the modifiers is demonstrated with this:

data example;
   length str1  $ 6;
   str1='a1-';
   result1 =findc(str1,'-','adk');
   result2 =findc(str1,'-','adkt');
run;

Result 1 is 4 because the full length of the variable str1 has been "padded" to the length of 6 characters with trailing spaces and is found by the function at position 4 to have something other than dash, letter or digit.

Re: How to identify the records in the column other than alpha numeric and hypen

yabwon — Tue, 09 Apr 2024 14:32:43 GMT

compress(column,"-","AD") means: delete hyphen, Alphabet letters, and Digits 😉

[EDIT:] If there is a space in your text, e.g., "AB CD" and you don't want it too this code won't be enough. But @PaigeMiller 's code with FINDC() will work.

Bart

Re: How to identify the records in the column other than alpha numeric and hypen

Ksharp — Wed, 10 Apr 2024 02:41:56 GMT

You need to strip the blanks at end of string.
if prxmatch('/[^[:alnum:]-]/', column) > 0 then
---->
if prxmatch('/[^[:alnum:]-]/', strip(column)) > 0 then

Re: How to identify the records in the column other than alpha numeric and hypen

learn_SAS_23 — Wed, 10 Apr 2024 06:56:55 GMT

Thanks ,

data check_special_chars;
set have;

/* Use PRXMATCH to search for characters that are not alphanumeric or hyphen */
if prxmatch('/[^[:alnum:]-]/', strip(column)) > 0 then
special_chars_found = 1;
else
special_chars_found = 0;
run;

Now this method also works

Re: How to identify the records in the column other than alpha numeric and hypen

learn_SAS_23 — Wed, 10 Apr 2024 06:57:21 GMT

Thanks for clear details !!, it helps